commit: 59573e91ba02f148b89af4e29ab0596fa660cc66
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Feb 26 16:41:52 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Feb 26 17:48:16 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=59573e91
dev-python/pylint: Bump to 3.1.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/pylint/Manifest | 1 +
dev-python/pylint/pylint-3.1.0.ebuild | 92 +++++++++++++++++++++++++++++++++++
2 files changed, 93 insertions(+)
diff --git a/dev-python/pylint/Manifest b/dev-python/pylint/Manifest
index eca9d753e387..387165119571 100644
--- a/dev-python/pylint/Manifest
+++ b/dev-python/pylint/Manifest
@@ -1,2 +1,3 @@
DIST pylint-3.0.3.gh.tar.gz 1422200 BLAKE2B
999afa1a26cc9fdc8f88bc7a1173c4621f608321b09798de7dd30ef3f5fa295b354ae17acf52009dc340a527f2414f350777ea5893a522f44a31baa466242c63
SHA512
ac5fe236bab08cdacdf9fb78cbf444348bfaa4a359dabd17bfdef5d8a7d9b72a794fd5e7483ea326d1c006668fbd6c37d0aa1f8e7c9963bc75265eb9ced6d43b
DIST pylint-3.0.4.gh.tar.gz 1423538 BLAKE2B
a7ca336831266202f32699b17785fc671222738bdefc2b03dba2a27dde81a193c7d4b51c09d6f6bd61bacaf743dade3ca681c396d64149e1ddd25a897da43952
SHA512
ad674c86a2d52e68e913a92e9e24195c7af185d551b225b6b12b604ca3d9c2e9e3570cff423577dfac66e7af17f48aee2b1807e3973d2e0abba566a85d11e112
+DIST pylint-3.1.0.gh.tar.gz 1433040 BLAKE2B
a224af608fa5ccb256c18073a70f82c399ad23ff6df65f7ae3504c67060f5ba1cd36022c7d53a42f0f93bd4648340433601d2f479bef41a4281e8041a9d15715
SHA512
bb7f09fa8b2c6f218c0e4d74ec2d7bbcb5e9d9fa8c2aeae5a1bf899f25080251609f284959fab14dd93cc5dd911688e25d3d4e1e030a1790578bc78ef1ce2bf7
diff --git a/dev-python/pylint/pylint-3.1.0.ebuild
b/dev-python/pylint/pylint-3.1.0.ebuild
new file mode 100644
index 000000000000..f546e777fcd7
--- /dev/null
+++ b/dev-python/pylint/pylint-3.1.0.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+MY_P=${P/_beta/b}
+DESCRIPTION="Python code static checker"
+HOMEPAGE="
+ https://pypi.org/project/pylint/
+ https://github.com/pylint-dev/pylint/
+"
+SRC_URI="
+ https://github.com/pylint-dev/pylint/archive/v${PV/_beta/b}.tar.gz
+ -> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86"
+IUSE="examples"
+
+RDEPEND="
+ <dev-python/astroid-3.2[${PYTHON_USEDEP}]
+ >=dev-python/astroid-3.1.0[${PYTHON_USEDEP}]
+ >=dev-python/dill-0.3.7[${PYTHON_USEDEP}]
+ >=dev-python/isort-4.2.5[${PYTHON_USEDEP}]
+ <dev-python/isort-6[${PYTHON_USEDEP}]
+ >=dev-python/mccabe-0.6[${PYTHON_USEDEP}]
+ <dev-python/mccabe-0.8[${PYTHON_USEDEP}]
+ >=dev-python/platformdirs-2.2.0[${PYTHON_USEDEP}]
+ >=dev-python/tomlkit-0.10.1[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/tomli-1.1.0[${PYTHON_USEDEP}]
+ ' 3.10)
+"
+BDEPEND="
+ test? (
+ $(python_gen_cond_dep '
+ >=dev-python/GitPython-3[${PYTHON_USEDEP}]
+ ' 'python*' )
+ <dev-python/pytest-8[${PYTHON_USEDEP}]
+ dev-python/pytest-timeout[${PYTHON_USEDEP}]
+ dev-python/typing-extensions[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # TODO
+
'tests/test_functional.py::test_functional[dataclass_with_field]'
+ 'tests/test_functional.py::test_functional[no_name_in_module]'
+ 'tests/test_functional.py::test_functional[shadowed_import]'
+ 'tests/test_functional.py::test_functional[use_yield_from]'
+ 'tests/test_functional.py::test_functional[wrong_import_order]'
+ )
+ local EPYTEST_IGNORE=(
+ # No need to run the benchmarks
+ tests/benchmark/test_baseline_benchmarks.py
+ )
+
+ if ! has_version "dev-python/GitPython[${PYTHON_USEDEP}]"; then
+ EPYTEST_IGNORE+=(
+ tests/profile/test_profile_against_externals.py
+ tests/testutils/_primer/test_package_to_lint.py
+ tests/testutils/_primer/test_primer.py
+ )
+ fi
+
+ rm -rf pylint || die
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest -p timeout
+}
+
+python_install_all() {
+ if use examples ; then
+ docompress -x "/usr/share/doc/${PF}/examples"
+ docinto examples
+ dodoc -r examples/.
+ fi
+
+ distutils-r1_python_install_all
+}
