commit: f239a5157f4937ced28eae3ea7bb115ebf1573a0
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Feb 26 16:34:03 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Feb 26 17:48:16 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f239a515
dev-python/astroid: Bump to 3.1.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/astroid/Manifest | 1 +
dev-python/astroid/astroid-3.1.0.ebuild | 73 +++++++++++++++++++++++++++++++++
2 files changed, 74 insertions(+)
diff --git a/dev-python/astroid/Manifest b/dev-python/astroid/Manifest
index eb575f023ab8..8b37755acb8c 100644
--- a/dev-python/astroid/Manifest
+++ b/dev-python/astroid/Manifest
@@ -1 +1,2 @@
DIST astroid-3.0.3.gh.tar.gz 461982 BLAKE2B
a41d29b69dc0b0098a449ca0d93934edb5cad56017776971f0982b97b742472bcc731b409c582ca8ab9daabf20d9a84b950a70b08d830bc42ef90ba922fafbcd
SHA512
88164dcefa4136c53450d228128c0bb317218fbceb39c4889a7e313691fa0f0b04fed5fb5e25c6a46883d432f11289a4cd3306757a109d314e62580db0261289
+DIST astroid-3.1.0.gh.tar.gz 463675 BLAKE2B
363ca82814c170c89beb39118109e8a8488f5b5a43bb4a0fdb6d88a24842789ebfb3bb9ed6ebd00f1cd90dfc2d1c7d9730c8c2fe17eadb8f52f53add47cd5089
SHA512
7b2cd6270d1a9219d32e69e1a9c9eeffd2c5fcf575bc53df4a8c2d8df97b019e3e4e60768286a757a7390effcb454c7997f1f0f677c2b6370a2c3a9d46519057
diff --git a/dev-python/astroid/astroid-3.1.0.ebuild
b/dev-python/astroid/astroid-3.1.0.ebuild
new file mode 100644
index 000000000000..ff44524a497b
--- /dev/null
+++ b/dev-python/astroid/astroid-3.1.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Abstract Syntax Tree for logilab packages"
+HOMEPAGE="
+ https://github.com/pylint-dev/astroid/
+ https://pypi.org/project/astroid/
+"
+SRC_URI="
+ https://github.com/pylint-dev/astroid/archive/v${PV}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86"
+
+# Version specified in pyproject.toml
+RDEPEND="
+ $(python_gen_cond_dep '
+ >=dev-python/typing-extensions-4.0.0[${PYTHON_USEDEP}]
+ ' 3.10)
+"
+# dev-python/regex isn't available for pypy
+BDEPEND="
+ dev-python/setuptools-scm[${PYTHON_USEDEP}]
+ test? (
+ dev-python/attrs[${PYTHON_USEDEP}]
+ >=dev-python/numpy-1.17.0[${PYTHON_USEDEP}]
+ dev-python/python-dateutil[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ dev-python/regex[${PYTHON_USEDEP}]
+ ' 'python*')
+ )
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # no clue why they're broken
+
tests/test_modutils.py::GetModulePartTest::test_known_values_get_builtin_module_part
+ tests/test_regrtest.py::NonRegressionTests::test_numpy_distutils
+ # pydantic-2?
+ tests/brain/test_dataclasses.py::test_pydantic_field
+ # requires urllib3 with bundled six (skipped with urllib3>=2)
+
tests/test_modutils.py::test_file_info_from_modpath__SixMetaPathImporter
+ # hangs
+ tests/test_nodes.py::AsStringTest::test_recursion_error_trapped
+ # TODO
+
tests/test_builder.py::BuilderTest::test_data_build_error_filename
+ )
+
+ case ${EPYTHON} in
+ pypy3)
+ EPYTEST_DESELECT+=(
+
tests/test_transforms.py::TestTransforms::test_transform_aborted_if_recursion_limited
+ )
+ ;;
+ esac
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest
+}
