commit: b364e62ed496c30fbbcabebd0992c6d0d35a8e5c
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Apr 20 10:15:02 2022 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Apr 20 12:18:24 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b364e62e
dev-python/sphinxcontrib-programoutput: PEP517, rm namespace dep
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
.../sphinxcontrib-programoutput-0.17-r1.ebuild | 42 ++++++++++++++++++++++
1 file changed, 42 insertions(+)
diff --git
a/dev-python/sphinxcontrib-programoutput/sphinxcontrib-programoutput-0.17-r1.ebuild
b/dev-python/sphinxcontrib-programoutput/sphinxcontrib-programoutput-0.17-r1.ebuild
new file mode 100644
index 000000000000..9b63ff722c17
--- /dev/null
+++
b/dev-python/sphinxcontrib-programoutput/sphinxcontrib-programoutput-0.17-r1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Extension to sphinx to include program output"
+HOMEPAGE="
+ https://github.com/NextThought/sphinxcontrib-programoutput/
+ https://pypi.org/project/sphinxcontrib-programoutput/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86
~amd64-linux ~x86-linux"
+
+RDEPEND="
+ dev-python/sphinx[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ dev-python/mock[${PYTHON_USEDEP}]
+ )
+"
+distutils_enable_tests pytest
+distutils_enable_sphinx doc
+
+python_compile() {
+ distutils-r1_python_compile
+ find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+python_test() {
+ distutils_write_namespace sphinxcontrib
+ cd "${T}" || die
+ epytest --pyargs sphinxcontrib.programoutput.tests
+}
