commit: 6538cb47a9db7d9fd5e8343e14405f32a50c3edc
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Apr 20 10:25:43 2022 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Apr 20 12:18:28 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6538cb47
dev-python/sphinxcontrib-websupport: EAPI 8, PEP517, rm namespace dep
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
.../sphinxcontrib-websupport-1.2.4-r1.ebuild | 60 ++++++++++++++++++++++
1 file changed, 60 insertions(+)
diff --git
a/dev-python/sphinxcontrib-websupport/sphinxcontrib-websupport-1.2.4-r1.ebuild
b/dev-python/sphinxcontrib-websupport/sphinxcontrib-websupport-1.2.4-r1.ebuild
new file mode 100644
index 000000000000..47d812297ed2
--- /dev/null
+++
b/dev-python/sphinxcontrib-websupport/sphinxcontrib-websupport-1.2.4-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Sphinx websupport extension"
+HOMEPAGE="
+ https://www.sphinx-doc.org/
+ https://github.com/sphinx-doc/sphinxcontrib-websupport/
+ https://pypi.org/project/sphinxcontrib-websupport/
+"
+# pypi tarball is missing templates
+SRC_URI="
+
https://github.com/sphinx-doc/sphinxcontrib-websupport/archive/${PV}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv
~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-solaris"
+
+RDEPEND="
+ >=dev-python/six-1.5[${PYTHON_USEDEP}]
+ dev-python/sphinxcontrib-serializinghtml[${PYTHON_USEDEP}]
+"
+# avoid circular dependency with sphinx
+PDEPEND="
+ >=dev-python/sphinx-1.5.3[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ ${PDEPEND}
+ >=dev-python/sqlalchemy-0.9[${PYTHON_USEDEP}]
+ >=dev-python/whoosh-2.0[${PYTHON_USEDEP}]
+ )"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+ # breaks tests
+ sed -i -e '/pkg_resources/d' \
+ sphinxcontrib/websupport/__init__.py || die
+ distutils-r1_src_prepare
+}
+
+python_compile() {
+ distutils-r1_python_compile
+ find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+python_test() {
+ distutils_write_namespace sphinxcontrib
+ cd "${T}" || die
+ epytest "${S}"/tests
+}
