commit: 7db8834b2ea2aa89e2a28c911eb294b750941d80
Author: David Michael <fedora.dm0 <AT> gmail <DOT> com>
AuthorDate: Sat Nov 7 19:10:28 2020 +0000
Commit: David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Sat Nov 7 19:10:28 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7db8834b
media-libs/speex: EAPI 7, drop static-libs
Package-Manager: Portage-3.0.8, Repoman-3.0.2
Signed-off-by: David Michael <fedora.dm0 <AT> gmail.com>
Signed-off-by: David Seifert <soap <AT> gentoo.org>
media-libs/speex/speex-1.2.0-r2.ebuild | 71 ++++++++++++++++++++++++++++++++++
1 file changed, 71 insertions(+)
diff --git a/media-libs/speex/speex-1.2.0-r2.ebuild
b/media-libs/speex/speex-1.2.0-r2.ebuild
new file mode 100644
index 00000000000..a1aeaecbc05
--- /dev/null
+++ b/media-libs/speex/speex-1.2.0-r2.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools flag-o-matic multilib-minimal
+
+MY_P=${P/_}
+MY_P=${MY_P/_p/.}
+
+DESCRIPTION="Audio compression format designed for speech"
+HOMEPAGE="https://www.speex.org/";
+SRC_URI="https://downloads.xiph.org/releases/speex/${MY_P}.tar.gz";
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86
~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris
~x86-solaris"
+IUSE="cpu_flags_arm_v4 cpu_flags_arm_v5 cpu_flags_arm_v6 cpu_flags_x86_sse
utils +vbr"
+
+RDEPEND="
+ utils? (
+ media-libs/libogg:=
+ media-libs/speexdsp[${MULTILIB_USEDEP}]
+ )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=( "${FILESDIR}"/${P}-configure.patch )
+
+src_prepare() {
+ default
+
+ sed -i \
+ -e 's:noinst_PROGRAMS:check_PROGRAMS:' \
+ libspeex/Makefile.am || die
+
+ eautoreconf
+}
+
+multilib_src_configure() {
+ append-lfs-flags
+
+ local FIXED_ARG="--disable-fixed-point"
+ local ARM4_ARG="--disable-arm4-asm"
+ local ARM5_ARG="--disable-arm5e-asm"
+
+ if use arm && ! use cpu_flags_arm_v6; then
+ FIXED_ARG="--enable-fixed-point"
+
+ if use cpu_flags_arm_v5; then
+ ARM5_ARG="--enable-arm5e-asm"
+ elif use cpu_flags_arm_v4; then
+ ARM4_ARG="--enable-arm4-asm"
+ fi
+ fi
+
+ ECONF_SOURCE="${S}" econf \
+ --disable-static \
+ $(use_enable cpu_flags_x86_sse sse) \
+ $(use_enable vbr) \
+ $(use_with utils speexdsp) \
+ $(use_enable utils binaries) \
+ ${FIXED_ARG} ${ARM4_ARG} ${ARM5_ARG}
+}
+
+multilib_src_install_all() {
+ einstalldocs
+ find "${ED}" -name '*.la' -type f -delete || die
+}
