commit: 8e48f86b405e2a90bdda8c80181f94ef520a1685
Author: David Michael <fedora.dm0 <AT> gmail <DOT> com>
AuthorDate: Sat Nov 7 19:10:31 2020 +0000
Commit: David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Sat Nov 7 19:10:31 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8e48f86b
media-libs/speexdsp: EAPI 7, drop static-libs
Package-Manager: Portage-3.0.8, Repoman-3.0.2
Signed-off-by: David Michael <fedora.dm0 <AT> gmail.com>
Signed-off-by: David Seifert <soap <AT> gentoo.org>
media-libs/speexdsp/speexdsp-1.2_rc3-r3.ebuild | 59 ++++++++++++++++++++++++++
1 file changed, 59 insertions(+)
diff --git a/media-libs/speexdsp/speexdsp-1.2_rc3-r3.ebuild
b/media-libs/speexdsp/speexdsp-1.2_rc3-r3.ebuild
new file mode 100644
index 00000000000..4e88346d061
--- /dev/null
+++ b/media-libs/speexdsp/speexdsp-1.2_rc3-r3.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools flag-o-matic multilib-minimal
+
+MY_P=${P/_}
+MY_P=${MY_P/_p/.}
+
+DESCRIPTION="Audio compression format designed for speech -- DSP"
+HOMEPAGE="https://www.speex.org/";
+SRC_URI="https://downloads.xiph.org/releases/speex/${MY_P}.tar.gz";
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86
~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris
~x86-solaris"
+IUSE="cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_arm_neon"
+
+RDEPEND="!<media-libs/speex-1.2.0"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+ "${FILESDIR}"/${P}-configure.patch
+ "${FILESDIR}"/${P}-config_types.h.patch
+ "${FILESDIR}"/${P}-overflow.patch
+)
+
+src_prepare() {
+ default
+
+ sed -i \
+ -e 's:noinst_PROGRAMS:check_PROGRAMS:' \
+ libspeexdsp/Makefile.am || die
+
+ eautoreconf
+
+ append-lfs-flags
+}
+
+multilib_src_configure() {
+ # Can also be configured with one of:
+ # --enable-fixed-point (no floating point)
+ # --with-fft=proprietary-intel-mkl (mkl)
+ # --with-fft=gpl-fftw3 (fftw)
+ ECONF_SOURCE="${S}" econf \
+ --disable-static \
+ $(use_enable cpu_flags_x86_sse sse) \
+ $(use_enable cpu_flags_x86_sse2 sse2) \
+ $(use_enable cpu_flags_arm_neon neon)
+}
+
+multilib_src_install_all() {
+ einstalldocs
+ find "${ED}" -name '*.la' -type f -delete || die
+}
