On Thu, Sep 07, 2000 at 09:53:38AM +1000, Andrew Tridgell wrote:
> > I've cc'd Paul Eggert on this email, the author of
> > AC_SYS_LARGEFILE. As far as I know, LFS only matters to programs
> > *not* using the 64-bit data types, like off64_t
>
> not quite. You also need open64() and a few others. I handled most of
> these previously in rsync but I thought that using getconf would get
> things working on a wider range of systems.
>
> I wasn't aware of AC_SYS_LARGEFILE. Can you give me a pointer to it?
Attached. Remove your getconf stuff and replace with AC_SYS_LARGEFILE,
copy the attachment to acinclude.m4, and run autoconf.
> > Now, because of the addition above, in 2.4.6 on the same host we have:
> > checking for off64_t... no
>
> yep, but as off_t should now be 64 bits it shouldn't matter. Are you
> saying that 2.4.6 doesn't give large file support on Solaris 2.7? I
> don't have a 2.7 machine so I didn't test on that particular OS (I did
> test on Solaris8 though).
Things still work on Solaris. As you indicated, off_t is now 64-bits
as a result of using the LFS stuff.
> > I'm including a patch below to do two things to 2.4.6:
> > 1. redirect getconf to 2>/dev/null on systems such as HP-UX where
> > % getconf LFS_CFLAGS
> > getconf LFS_CFLAGS: Invalid argument
>
> yep, that's worth doing (purely cosmetic of course)
>
> If possible I'd like to delete all the off64_t code in rsync (both in
> configure.in and syscall.c) and just use the OS provides mechanisms
> for LFS. Essentially rsync has been reproducing the macros that the C
> library authors have taken a lot of time to get right which just seems
> silly.
Agreed! And in Samba too :)
--
albert chin ([EMAIL PROTECTED])
-- snip snip (largefile.m4)
#serial 12
dnl By default, many hosts won't let programs access large files;
dnl one must use special compiler options to get large-file access to work.
dnl For more details about this brain damage please see:
dnl http://www.sas.com/standards/large.file/x_open.20Mar96.html
dnl Written by Paul Eggert <[EMAIL PROTECTED]>.
dnl Internal subroutine of AC_SYS_LARGEFILE.
dnl AC_SYS_LARGEFILE_TEST_INCLUDES
AC_DEFUN(AC_SYS_LARGEFILE_TEST_INCLUDES,
[[#include <sys/types.h>
int a[(off_t) 9223372036854775807 == 9223372036854775807 ? 1 : -1];
]])
dnl Internal subroutine of AC_SYS_LARGEFILE.
dnl AC_SYS_LARGEFILE_MACRO_VALUE(C-MACRO, VALUE, CACHE-VAR, COMMENT, INCLUDES,
FUNCTION-BODY)
AC_DEFUN(AC_SYS_LARGEFILE_MACRO_VALUE,
[AC_CACHE_CHECK([for $1 value needed for large files], $3,
[$3=no
AC_TRY_COMPILE(AC_SYS_LARGEFILE_TEST_INCLUDES
$5
,
[$6],
,
[AC_TRY_COMPILE([#define $1 $2]
AC_SYS_LARGEFILE_TEST_INCLUDES
$5
,
[$6],
[$3=$2])])])
if test "[$]$3" != no; then
AC_DEFINE_UNQUOTED([$1], [$]$3, [$4])
fi])
AC_DEFUN(AC_SYS_LARGEFILE,
[AC_ARG_ENABLE(largefile,
[ --disable-largefile omit support for large files])
if test "$enable_largefile" != no; then
AC_CACHE_CHECK([for special C compiler options needed for large files],
ac_cv_sys_largefile_CC,
[ac_cv_sys_largefile_CC=no
if test "$GCC" != yes; then
# IRIX 6.2 and later do not support large files by default,
# so use the C compiler's -n32 option if that helps.
AC_TRY_COMPILE(AC_SYS_LARGEFILE_TEST_INCLUDES, , ,
[ac_save_CC="$CC"
CC="$CC -n32"
AC_TRY_COMPILE(AC_SYS_LARGEFILE_TEST_INCLUDES, ,
ac_cv_sys_largefile_CC=' -n32')
CC="$ac_save_CC"])
fi])
if test "$ac_cv_sys_largefile_CC" != no; then
CC="$CC$ac_cv_sys_largefile_CC"
fi
AC_SYS_LARGEFILE_MACRO_VALUE(_FILE_OFFSET_BITS, 64,
ac_cv_sys_file_offset_bits,
[Number of bits in a file offset, on hosts where this is settable.])
AC_SYS_LARGEFILE_MACRO_VALUE(_LARGEFILE_SOURCE, 1,
ac_cv_sys_largefile_source,
[Define to make ftello visible on some hosts (e.g. HP-UX 10.20).],
[#include <stdio.h>], [return !ftello;])
AC_SYS_LARGEFILE_MACRO_VALUE(_LARGE_FILES, 1,
ac_cv_sys_large_files,
[Define for large files, on AIX-style hosts.])
dnl lftp does not need ftello, and _XOPEN_SOURCE=500 makes resolv.h fail.
dnl AC_SYS_LARGEFILE_MACRO_VALUE(_XOPEN_SOURCE, 500,
dnl ac_cv_sys_xopen_source,
dnl [Define to make ftello visible on some hosts (e.g. glibc 2.1.3).],
dnl [#include <stdio.h>], [return !ftello;])
fi
])
