commit: 72b7a0afb49d1f24fdf26f8cd8b715ca2b982532
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Nov 11 12:22:04 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Nov 11 12:34:11 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=72b7a0af
dev-python/inline-snapshot: Bump to 0.14.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/inline-snapshot/Manifest | 1 +
.../inline-snapshot/inline-snapshot-0.14.0.ebuild | 59 ++++++++++++++++++++++
2 files changed, 60 insertions(+)
diff --git a/dev-python/inline-snapshot/Manifest
b/dev-python/inline-snapshot/Manifest
index 6389c2c92573..4078aa545a63 100644
--- a/dev-python/inline-snapshot/Manifest
+++ b/dev-python/inline-snapshot/Manifest
@@ -1 +1,2 @@
DIST inline_snapshot-0.13.4.tar.gz 215264 BLAKE2B
911bb7007fd35c68e0e42fb915e284394e45b7b510de875827282fc6dadf7f467a6da1efa626e9b2c348750709aea0399bcd7869dc181ab7a2121f76206404a8
SHA512
724d72984399712611c0eea5129b86b6650bdce1a4331255cf30b806ae6f03a33aa51de9f6353e84ae09ec8f6738372964f380a622481b5bf1db1e9baaa5bf00
+DIST inline_snapshot-0.14.0.tar.gz 209662 BLAKE2B
9bea11df88aab049af61146cb40c8afaa7607f8812c800ee7dffc7de94403029e4ae1d1ed49921f624e5327171650210744962559786e45586ae929830f81819
SHA512
32855dcd098c3e9b6a046752a3fc03c18b0df85e2cf338a928eadcd0e63bb784bdaca6855c954974ec7561e602ff3dd95ccdadb0c4f7dd1075d9d84245c171ef
diff --git a/dev-python/inline-snapshot/inline-snapshot-0.14.0.ebuild
b/dev-python/inline-snapshot/inline-snapshot-0.14.0.ebuild
new file mode 100644
index 000000000000..62d796d87b09
--- /dev/null
+++ b/dev-python/inline-snapshot/inline-snapshot-0.14.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Create and update inline snapshots in your Python tests"
+HOMEPAGE="
+ https://15r10nk.github.io/inline-snapshot/
+ https://github.com/15r10nk/inline-snapshot/
+ https://pypi.org/project/inline-snapshot/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+ >=dev-python/asttokens-2.0.5[${PYTHON_USEDEP}]
+ >=dev-python/black-23.3.0[${PYTHON_USEDEP}]
+ >=dev-python/click-8.1.4[${PYTHON_USEDEP}]
+ >=dev-python/executing-2.1.0[${PYTHON_USEDEP}]
+ >=dev-python/rich-13.7.1[${PYTHON_USEDEP}]
+ dev-python/typing-extensions[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/tomli-2.0.0[${PYTHON_USEDEP}]
+ ' 3.10)
+"
+BDEPEND="
+ test? (
+ >=dev-python/dirty-equals-0.7.0[${PYTHON_USEDEP}]
+ >=dev-python/hypothesis-6.75.5[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ dev-python/mypy[${PYTHON_USEDEP}]
+ ' 'python*')
+ dev-python/pydantic[${PYTHON_USEDEP}]
+ >=dev-python/pytest-freezer-0.4.8[${PYTHON_USEDEP}]
+ >=dev-python/pytest-subtests-0.11.0[${PYTHON_USEDEP}]
+ )
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # requires pyright
+ 'tests/test_typing.py::test_typing[pyright]'
+ )
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ local -x
PYTEST_PLUGINS=inline_snapshot.pytest_plugin,pytest_freezer,pytest_subtests.plugin,xdist.plugin
+ local -x PYTHONPATH=${S}/src
+ epytest
+}
