commit: 75d18fc104f98f695ec34b25f0885bfcc4604f6b
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Oct 30 16:27:02 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Oct 30 16:41:50 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=75d18fc1
dev-python/weasyprint: Bump to 63.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/weasyprint/Manifest | 1 +
dev-python/weasyprint/weasyprint-63.0.ebuild | 54 ++++++++++++++++++++++++++++
2 files changed, 55 insertions(+)
diff --git a/dev-python/weasyprint/Manifest b/dev-python/weasyprint/Manifest
index 76db9b8fcb2d..7af3bbd7ec46 100644
--- a/dev-python/weasyprint/Manifest
+++ b/dev-python/weasyprint/Manifest
@@ -1 +1,2 @@
DIST weasyprint-62.3.tar.gz 477181 BLAKE2B
144b531e36c0e66fb715d2b1db20affb489e90dc7545435e2d2d5e5e89a0b77e03b5f08166a5ac6f488ed5e2ff5d268408d94edaf66a3327895f719e9329ff60
SHA512
c563019aac075d0f55a153483719a5ea1dd4dced8bf281aeb1c5ccb65b8591e883ea09ca86757073b10a4dd9dc2d718df83ff5913cd5b9ed703fb5cf71bf7fbf
+DIST weasyprint-63.0.tar.gz 491295 BLAKE2B
f25a777a5057502f5a056417037411325c7600db2f1609c854c43ade98a1d7bda6a5c4663e7221e3b8002dfa763aff1b104541ee4cb55b0079cf973f256efe6d
SHA512
79384ead532dbcfc561d2c490fbc04d7d0d11ed3c589fe375e9b2bb43e57a28c5bcfeaa7a6fb8daa1b031ce56720775e7b558c0a6ac5d195dee4310a3a3cab8d
diff --git a/dev-python/weasyprint/weasyprint-63.0.ebuild
b/dev-python/weasyprint/weasyprint-63.0.ebuild
new file mode 100644
index 000000000000..df924259c9a5
--- /dev/null
+++ b/dev-python/weasyprint/weasyprint-63.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Visual rendering engine for HTML and CSS that can export to PDF"
+HOMEPAGE="
+ https://weasyprint.org/
+ https://github.com/Kozea/WeasyPrint/
+ https://pypi.org/project/weasyprint/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+ >=dev-python/cffi-0.6:=[${PYTHON_USEDEP}]
+ >=dev-python/cssselect2-0.1[${PYTHON_USEDEP}]
+ >=dev-python/fonttools-4.0.0[${PYTHON_USEDEP}]
+ >=dev-python/pillow-9.1.0[jpeg,jpeg2k,${PYTHON_USEDEP}]
+ >=dev-python/pydyf-0.11.0[${PYTHON_USEDEP}]
+ >=dev-python/pyphen-0.9.1[${PYTHON_USEDEP}]
+ >=dev-python/tinycss2-1.4.0[${PYTHON_USEDEP}]
+ >=dev-python/tinyhtml5-2.0.0[${PYTHON_USEDEP}]
+ media-fonts/dejavu
+ x11-libs/pango
+"
+
+BDEPEND="
+ test? (
+ >=app-text/ghostscript-gpl-9.56.1-r3
+ media-fonts/ahem
+ )
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+ distutils-r1_src_prepare
+
+ # unpin deps
+ sed -i -e 's:,<[0-9.]*::' pyproject.toml || die
+}
+
+python_test() {
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest
+}
