commit: d2030d481cb68cbc3f8eed16300e1cad32cbe5b8
Author: Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Mon Oct 21 10:46:37 2024 +0000
Commit: Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Mon Oct 21 10:46:37 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d2030d48
dev-libs/libjcat: add 0.2.2
Signed-off-by: Sam James <sam <AT> gentoo.org>
dev-libs/libjcat/Manifest | 1 +
dev-libs/libjcat/libjcat-0.2.2.ebuild | 85 +++++++++++++++++++++++++++++++++++
2 files changed, 86 insertions(+)
diff --git a/dev-libs/libjcat/Manifest b/dev-libs/libjcat/Manifest
index 662daac1f93a..0be7cda0401e 100644
--- a/dev-libs/libjcat/Manifest
+++ b/dev-libs/libjcat/Manifest
@@ -1 +1,2 @@
DIST libjcat-0.2.1.tar.gz 76698 BLAKE2B
62f77c993e47843dddacc9a67b9daac9bd29bef7363ce62125ecd22f9649b8a5ce2de07d74ea6900e9a45feb141caa19761bcffd337530d86a31b6ed94cab164
SHA512
e29fdaae38ade2960ffa7ac3cd41224ccab5fdb351d2ae420ffe0cf0ddb948bba37e9e040cc3046c8593be4622bf018779dfa80f173873b79582061f12c02373
+DIST libjcat-0.2.2.tar.xz 66128 BLAKE2B
30e855ec626616adf8326832dbb6e5c9266ffd41d14d1ef2a230f72e0a339d4c8ed83adacd0253faf242b065736dca7f25bd4ce04d30605998d39cacf01beac0
SHA512
91d4d9761e7de3ae312d9ef7b92fbbb82be262cdc4259ee9dad7abef8912abb047b2db51886b3d323565cb2d9a3175a56161b4879d27b36d4d318ad4419ab594
diff --git a/dev-libs/libjcat/libjcat-0.2.2.ebuild
b/dev-libs/libjcat/libjcat-0.2.2.ebuild
new file mode 100644
index 000000000000..fb70f6741cec
--- /dev/null
+++ b/dev-libs/libjcat/libjcat-0.2.2.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit meson python-any-r1 vala xdg-utils
+
+DESCRIPTION="Library and tool for reading and writing Jcat files"
+HOMEPAGE="https://github.com/hughsie/libjcat";
+SRC_URI="https://github.com/hughsie/libjcat/releases/download/${PV}/${P}.tar.xz";
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="+ed25519 +gpg gtk-doc +introspection +man +pkcs7 test vala"
+
+RDEPEND="
+ dev-libs/glib:2
+ dev-libs/json-glib:=
+ ed25519? (
+ net-libs/gnutls:=
+ )
+ gpg? (
+ app-crypt/gpgme:=
+ dev-libs/libgpg-error
+ )
+ introspection? ( dev-libs/gobject-introspection:= )
+ pkcs7? ( net-libs/gnutls:= )
+ vala? ( dev-lang/vala:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+ virtual/pkgconfig
+ $(python_gen_any_dep '
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ ')
+ gtk-doc? ( dev-util/gtk-doc )
+ man? ( sys-apps/help2man )
+ test? ( net-libs/gnutls[tools] )
+"
+
+RESTRICT="!test? ( test )"
+
+python_check_deps() {
+ python_has_version -b "dev-python/setuptools[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+ use vala && vala_setup
+}
+
+src_prepare() {
+ xdg_environment_reset
+ default
+}
+
+src_configure() {
+ local emesonargs=(
+ $(meson_use ed25519)
+ $(meson_use gtk-doc gtkdoc)
+ $(meson_use gpg)
+ $(meson_use introspection)
+ $(meson_use man)
+ $(meson_use pkcs7)
+ $(meson_use test tests)
+ $(meson_use vala vapi)
+ )
+ meson_src_configure
+}
+
+src_install() {
+ meson_src_install
+
+ if use test; then
+ # Preventing tests from being installed in the first place is a
moving target,
+ # just axe them all afterwards.
+ rm -rf \
+ "${ED}"/usr/libexec/installed-tests \
+ "${ED}"/usr/share/installed-tests \
+ || die
+ fi
+}
