commit: 775272e4fc51b1488ef2a3d83af0271f4a531612
Author: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Fri Oct 4 18:52:56 2024 +0000
Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Fri Oct 4 21:03:15 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=775272e4
net-libs/signon-oauth2: Drop IUSE qt5,qt6, fixing src_configure()
- in src_configure() it was either qt5 or qt6, no multibuild
- There are no Qt5-based revdeps
- Prepare for IUSE qt6 USEdep droppage in net-libs/signond
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
.../signon-oauth2-0.25_p20210102-r2.ebuild | 72 ++++++++++++++++++++++
1 file changed, 72 insertions(+)
diff --git a/net-libs/signon-oauth2/signon-oauth2-0.25_p20210102-r2.ebuild
b/net-libs/signon-oauth2/signon-oauth2-0.25_p20210102-r2.ebuild
new file mode 100644
index 000000000000..1f6af000813d
--- /dev/null
+++ b/net-libs/signon-oauth2/signon-oauth2-0.25_p20210102-r2.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN=signon-plugin-oauth2
+MY_PV=VERSION_${PV}
+MY_P=${MY_PN}-${MY_PV}
+inherit qmake-utils
+
+if [[ ${PV} = *9999* ]] ; then
+ EGIT_REPO_URI="https://gitlab.com/nicolasfella/${MY_PN}.git/";
+ EGIT_BRANCH="qt6"
+ inherit git-r3
+else
+ COMMIT=d759439066f0a34e5ad352ebab0b3bb2790d429e
+ if [[ -n ${COMMIT} ]] ; then
+
SRC_URI="https://gitlab.com/accounts-sso/${MY_PN}/-/archive/${COMMIT}/${MY_PN}-${COMMIT}.tar.bz2
-> ${P}.tar.bz2"
+ S="${WORKDIR}/${MY_PN}-${COMMIT}"
+ else
+
SRC_URI="https://gitlab.com/accounts-sso/${MY_PN}/-/archive/${MY_PV}/${MY_P}.tar.bz2
-> ${P}.tar.bz2"
+ S="${WORKDIR}/${MY_P}"
+ fi
+ KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+fi
+
+DESCRIPTION="OAuth2 plugin for Signon daemon"
+HOMEPAGE="https://gitlab.com/accounts-sso/signon-plugin-oauth2";
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ dev-qt/qtbase:6[network,ssl]
+ >=net-libs/signond-8.61-r100[qt6(+)]
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+ "${FILESDIR}"/0001-Port-QSignalSpys-to-PMF-syntax.patch
+ "${FILESDIR}"/0002-Port-to-new-connection-syntax.patch
+ "${FILESDIR}"/0003-Port-away-from-deprecated-error-signal.patch
+ "${FILESDIR}"/0004-Port-away-from-deprecated-qrand.patch
+ "${FILESDIR}"/0005-Fix-string-concatenation-in-Qt6.patch
+ "${FILESDIR}"/0006-Port-away-from-deprecated-QRegExp.patch
+ "${FILESDIR}"/0007-Build-with-C-17.patch
+ "${FILESDIR}"/0008-Use-correct-signon-in-example.patch
+ "${FILESDIR}"/0009-Port-away-from-deprecated-QString-SplitBehavior.patch
+ "${FILESDIR}"/0010-Port-away-from-deprecated-QList-toSet.patch
+ # downstream patches
+ "${FILESDIR}/${PN}-0.24-dont-install-tests.patch"
+ "${FILESDIR}/${PN}-0.25-pkgconfig-libdir.patch"
+ "${FILESDIR}/${PN}-0.25-drop-fno-rtti.patch"
+)
+
+src_prepare() {
+ default
+ sed -i "s|@LIBDIR@|$(get_libdir)|g" src/signon-oauth2plugin.pc || die
+}
+
+src_configure() {
+ local myqmakeargs=( LIBDIR=/usr/$(get_libdir) )
+ use test || myqmakeargs+=( CONFIG+=nomake_tests )
+
+ eqmake6 "${myqmakeargs[@]}"
+}
+
+src_install() {
+ emake INSTALL_ROOT="${D}" install
+}
