[gentoo-commits] repo/gentoo:master commit in: dev-python/nbdime/

[Michał Górny]

commit:     526c0066d1e40aed5493292cb0f33d974dc49310
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Sep  6 02:48:45 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Sep  6 09:25:03 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=526c0066

dev-python/nbdime: Bump to 4.0.2

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/nbdime/Manifest            |  1 +
 dev-python/nbdime/nbdime-4.0.2.ebuild | 63 +++++++++++++++++++++++++++++++++++
 2 files changed, 64 insertions(+)

diff --git a/dev-python/nbdime/Manifest b/dev-python/nbdime/Manifest
index c47739c63c17..d4135e471c52 100644
--- a/dev-python/nbdime/Manifest
+++ b/dev-python/nbdime/Manifest
@@ -1 +1,2 @@
 DIST nbdime-4.0.1.tar.gz 9414125 BLAKE2B 
bf2581cec0f71ef8949c9cf19e21aa47302b6c71bbb9861e8c6f3a4b1921e9f73460ee5059e5bc92c7789d8f0695329125725c10e10763dd6e4d388bfaee53d1
 SHA512 
df14dfe9df296d71eb4a98140fe15703ca277063a153c3159cc883c99ce98b76f5f4dae24d32b048a18d2530e52535e3d89523d7a1c54a8654d2d54c8812ded3
+DIST nbdime-4.0.2.tar.gz 9452967 BLAKE2B 
c9c390f9165d0b8b3277c7bd93e5a90f4ac23cf0d084ed8ba166254bfbfe9cc0e9f0bc35c2a86b39d84167e78639cb2ed69f6cda5da02bb113f7323a86d745a6
 SHA512 
1e923b7f719d6a33f1dc06e06511a6d48bb8bfef7d8f7676da2520edd2914014eb88f70eaaeec27af6b03f1cefbd9a3e6854a7c0dec7f76f211d750b3fd90894

diff --git a/dev-python/nbdime/nbdime-4.0.2.ebuild 
b/dev-python/nbdime/nbdime-4.0.2.ebuild
new file mode 100644
index 000000000000..db11041f30e0
--- /dev/null
+++ b/dev-python/nbdime/nbdime-4.0.2.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Diff and merge of Jupyter Notebooks"
+HOMEPAGE="
+       https://jupyter.org/
+       https://github.com/jupyter/nbdime/
+       https://pypi.org/project/nbdime/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+       dev-python/colorama[${PYTHON_USEDEP}]
+       dev-python/GitPython[${PYTHON_USEDEP}]
+       dev-python/jinja[${PYTHON_USEDEP}]
+       dev-python/jupyter-server[${PYTHON_USEDEP}]
+       dev-python/jupyter-server-mathjax[${PYTHON_USEDEP}]
+       dev-python/nbformat[${PYTHON_USEDEP}]
+       dev-python/pygments[${PYTHON_USEDEP}]
+       dev-python/requests[${PYTHON_USEDEP}]
+       dev-python/tornado[${PYTHON_USEDEP}]
+"
+BDEPEND="
+       test? (
+               dev-python/jsonschema[${PYTHON_USEDEP}]
+               dev-python/notebook[${PYTHON_USEDEP}]
+               dev-python/pytest-timeout[${PYTHON_USEDEP}]
+               dev-python/tabulate[${PYTHON_USEDEP}]
+       )
+"
+
+distutils_enable_sphinx docs/source \
+       dev-python/recommonmark \
+       dev-python/sphinx-rtd-theme
+distutils_enable_tests pytest
+
+src_test() {
+       # user.email and user.name are not configured in the sandbox
+       git config --global user.email "la...@gentoo.org" || die
+       git config --global user.name "Larry the Cow" || die
+
+       distutils-r1_src_test
+}
+
+python_test() {
+       local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+       epytest -p timeout -o tmp_path_retention_policy=all
+}
+
+src_install() {
+       distutils-r1_src_install
+       mv "${ED}"{/usr,}/etc || die
+}