commit: ada49419f2eb82dc4c03c25a3d8794879231a10e
Author: Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Wed May 22 17:38:42 2024 +0000
Commit: Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Wed May 22 17:42:19 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ada49419
dev-util/intel_clc: Version bump to 24.0.8
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>
dev-util/intel_clc/Manifest | 1 +
dev-util/intel_clc/intel_clc-24.0.8.ebuild | 86 ++++++++++++++++++++++++++++++
2 files changed, 87 insertions(+)
diff --git a/dev-util/intel_clc/Manifest b/dev-util/intel_clc/Manifest
index 46fc77ae2eec..63319d9711e1 100644
--- a/dev-util/intel_clc/Manifest
+++ b/dev-util/intel_clc/Manifest
@@ -1,2 +1,3 @@
DIST mesa-24.0.7.tar.xz 20144724 BLAKE2B
d9438e533b471445b2403e01e1fd593d83c0013b0991585f718122f1cadc6ac6bb1fb913f0fb257354ae21ddd9fe1f970ad9ac46f05d756c223ed56a11b9c9ce
SHA512
77b0fae80ab0a07e2e528c113eadef0e3004b8df3e6e98fffe6fc2d8ac39f5ce7fa38ebe5c2ae32bfbac993dd7cbe288ace18ebb03cf2fb445fe7114f74dd45c
+DIST mesa-24.0.8.tar.xz 20170168 BLAKE2B
1919e99e6ccbd51c8e74e55985ea9a3f47bf49c7e4260a195a609ce175eeded9fc5a56970ae35d21bc650e4bb802df484d2088b29ef3861d13942bd495891a9a
SHA512
1e1be9b50c2a404a96960db87d2ba4cd1c602445f9ab8acfb6a8a023410063620c2ef891fe516afec3d830756e0b0f4309ef50c6caeefa44e164b414c4708b10
DIST mesa-24.1.0-rc4.tar.xz 28911444 BLAKE2B
66c09358acc3fa27ff74ae71a999777b93d28b0cc0f34f43c36710994b73fdc6f922977ab6062a6b46c34a29a5276896ff2e6393fa12af1312ae5cba1b1deaa3
SHA512
8c31ea253543b1f8d1329eef9e20243ca7d6eb8c9645960bc53314de85ea8e3255d72816faa94935ba92e4802351c9a29e221d7e72048681de0a490bf4c52119
diff --git a/dev-util/intel_clc/intel_clc-24.0.8.ebuild
b/dev-util/intel_clc/intel_clc-24.0.8.ebuild
new file mode 100644
index 000000000000..8bc3bb53f6ba
--- /dev/null
+++ b/dev-util/intel_clc/intel_clc-24.0.8.ebuild
@@ -0,0 +1,86 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LLVM_COMPAT=( 16 17 )
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit llvm-r1 meson python-any-r1
+
+MY_PV="${PV/_/-}"
+
+DESCRIPTION="intel_clc tool used for building OpenCL C to SPIR-V"
+HOMEPAGE="https://mesa3d.org/";
+
+if [[ ${PV} == 9999 ]]; then
+ S="${WORKDIR}/intel_clc-${MY_PV}"
+ EGIT_REPO_URI="https://gitlab.freedesktop.org/mesa/mesa.git";
+ inherit git-r3
+else
+ S="${WORKDIR}/mesa-${MY_PV}"
+ SRC_URI="https://archive.mesa3d.org/mesa-${MY_PV}.tar.xz";
+ KEYWORDS="~amd64"
+fi
+
+LICENSE="MIT SGI-B-2.0"
+SLOT="0"
+IUSE="debug"
+
+RDEPEND="
+ dev-libs/libclc
+ dev-util/spirv-tools
+ >=sys-libs/zlib-1.2.8:=
+ x11-libs/libdrm
+ $(llvm_gen_dep '
+ dev-util/spirv-llvm-translator:${LLVM_SLOT}
+ sys-devel/clang:${LLVM_SLOT}
+ sys-devel/llvm:${LLVM_SLOT}
+ ')
+"
+DEPEND="${RDEPEND}
+ dev-libs/expat
+"
+BDEPEND="
+ ${PYTHON_DEPS}
+ $(python_gen_any_dep ">=dev-python/mako-0.8.0[\${PYTHON_USEDEP}]")
+ virtual/pkgconfig
+"
+
+python_check_deps() {
+ python_has_version -b ">=dev-python/mako-0.8.0[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+ llvm-r1_pkg_setup
+ python-any-r1_pkg_setup
+}
+
+src_configure() {
+ PKG_CONFIG_PATH="$(get_llvm_prefix)/$(get_libdir)/pkgconfig"
+
+ local emesonargs=(
+ -Dllvm=enabled
+ -Dshared-llvm=enabled
+ -Dintel-clc=enabled
+
+ -Dgallium-drivers=''
+ -Dvulkan-drivers=''
+
+ # Set platforms empty to avoid the default "auto" setting. If
+ # platforms is empty meson.build will add surfaceless.
+ -Dplatforms=''
+
+ -Dglx=disabled
+ -Dlibunwind=disabled
+ -Dzstd=disabled
+
+ -Dbuildtype=$(usex debug debug plain)
+ -Db_ndebug=$(usex debug false true)
+ )
+ meson_src_configure
+}
+
+src_install() {
+ dobin "${BUILD_DIR}"/src/intel/compiler/intel_clc
+}
