commit: a679e09e7c47831b881d94d23ad74de43d78ca1f
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon May 20 19:24:46 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon May 20 19:42:08 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a679e09e
dev-python/pylint: Bump to 3.2.2
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/pylint/Manifest | 1 +
dev-python/pylint/pylint-3.2.2.ebuild | 93 +++++++++++++++++++++++++++++++++++
2 files changed, 94 insertions(+)
diff --git a/dev-python/pylint/Manifest b/dev-python/pylint/Manifest
index 8de3771373e6..cc47b2181713 100644
--- a/dev-python/pylint/Manifest
+++ b/dev-python/pylint/Manifest
@@ -2,3 +2,4 @@ DIST pylint-3.1.0.gh.tar.gz 1433040 BLAKE2B
a224af608fa5ccb256c18073a70f82c399ad
DIST pylint-3.1.1.gh.tar.gz 1433456 BLAKE2B
f51e253228b9bb2bddd2edac76c11ae1e5c712e755665bf3f808da832af313626037aded39eeb75941b7462a87668ea2de307740bd6a736d3130aa10850b5c9f
SHA512
66a30a45a1ac816a1e2ff16ea774fb5b5d646f89645c8f551ab4a65feea3076e6bc1b54ff1b71e5d8586f344c02b0e85c9b34d2c5b0afba115fd92cb7cb0a3f1
DIST pylint-3.2.0.gh.tar.gz 1440470 BLAKE2B
428222378bdcf48ab05792144548a8d050115ecac84be72922839702a11247198a959098f3aa94b5c688671ce846386de35c4d870598912be26900d98c188f7d
SHA512
14368efe598d074394effc5d90764d49b8680dfafea0837568e22ab9783de664e0d7c02491bf8c94c1b2bbe8d48018063f45a25ebd04c7813ac8e6bba7786109
DIST pylint-3.2.1.gh.tar.gz 1443199 BLAKE2B
0b6a066971f963ebf69665c5e343456c482bdcfa788d08c267d225d1a6aa54f58bc9731cc686a38f85b6a4f9b030c9b39103e9929e8265cdfa434a38d7e3a07a
SHA512
a7b22cab97e50f358d4aa3d2d1da50608e50cb13b6db433eb877007c32803b7151ef141a9741d7849e4ef7707ff5d4e5501174a5376418489bc0565148303f61
+DIST pylint-3.2.2.gh.tar.gz 1443983 BLAKE2B
aeff52756e03278da1db7478d0c95ca0d5fa0c8a15203ada4b30fe5fb2fa56bfc2fc60e020bee9b2e242339214cf383838c93cbf1369a82655bedd62e3b2634f
SHA512
84d625b0cd1ea0c308ff4381a9f553663af52fec534856a258ee50f00ec7238cf9af98d1e2c851522a8bd440c55e318d5c89035652d872cbd812d19ff14a0698
diff --git a/dev-python/pylint/pylint-3.2.2.ebuild
b/dev-python/pylint/pylint-3.2.2.ebuild
new file mode 100644
index 000000000000..0a91ce1ceb1a
--- /dev/null
+++ b/dev-python/pylint/pylint-3.2.2.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+MY_P=${P/_beta/b}
+DESCRIPTION="Python code static checker"
+HOMEPAGE="
+ https://pypi.org/project/pylint/
+ https://github.com/pylint-dev/pylint/
+"
+SRC_URI="
+ https://github.com/pylint-dev/pylint/archive/v${PV/_beta/b}.tar.gz
+ -> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86"
+IUSE="examples"
+
+RDEPEND="
+ <dev-python/astroid-3.3[${PYTHON_USEDEP}]
+ >=dev-python/astroid-3.2.2[${PYTHON_USEDEP}]
+ >=dev-python/dill-0.3.7[${PYTHON_USEDEP}]
+ >=dev-python/isort-4.2.5[${PYTHON_USEDEP}]
+ <dev-python/isort-6[${PYTHON_USEDEP}]
+ >=dev-python/mccabe-0.6[${PYTHON_USEDEP}]
+ <dev-python/mccabe-0.8[${PYTHON_USEDEP}]
+ >=dev-python/platformdirs-2.2.0[${PYTHON_USEDEP}]
+ >=dev-python/tomlkit-0.10.1[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/tomli-1.1.0[${PYTHON_USEDEP}]
+ ' 3.10)
+"
+BDEPEND="
+ test? (
+ $(python_gen_cond_dep '
+ >=dev-python/GitPython-3[${PYTHON_USEDEP}]
+ ' 'python*' )
+ <dev-python/pytest-8[${PYTHON_USEDEP}]
+ dev-python/pytest-timeout[${PYTHON_USEDEP}]
+ dev-python/typing-extensions[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # TODO
+
'tests/test_functional.py::test_functional[dataclass_with_field]'
+ 'tests/test_functional.py::test_functional[no_name_in_module]'
+
'tests/test_functional.py::test_functional[recursion_error_3159]'
+ 'tests/test_functional.py::test_functional[shadowed_import]'
+ 'tests/test_functional.py::test_functional[use_yield_from]'
+ 'tests/test_functional.py::test_functional[wrong_import_order]'
+ )
+ local EPYTEST_IGNORE=(
+ # No need to run the benchmarks
+ tests/benchmark/test_baseline_benchmarks.py
+ )
+
+ if ! has_version "dev-python/GitPython[${PYTHON_USEDEP}]"; then
+ EPYTEST_IGNORE+=(
+ tests/profile/test_profile_against_externals.py
+ tests/testutils/_primer/test_package_to_lint.py
+ tests/testutils/_primer/test_primer.py
+ )
+ fi
+
+ rm -rf pylint || die
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest -p timeout
+}
+
+python_install_all() {
+ if use examples ; then
+ docompress -x "/usr/share/doc/${PF}/examples"
+ docinto examples
+ dodoc -r examples/.
+ fi
+
+ distutils-r1_python_install_all
+}
