[gentoo-commits] repo/gentoo:master commit in: dev-python/transitions/

[Michał Górny]

commit:     d2824e37a6a569d27799dbf0bbef3a190bb06a8c
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu May 16 15:25:21 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu May 16 15:28:28 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d2824e37

dev-python/transitions: Bump to 0.9.1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/transitions/Manifest                 |  1 +
 dev-python/transitions/transitions-0.9.1.ebuild | 59 +++++++++++++++++++++++++
 2 files changed, 60 insertions(+)

diff --git a/dev-python/transitions/Manifest b/dev-python/transitions/Manifest
index d5f65b9bde9e..058ca9298996 100644
--- a/dev-python/transitions/Manifest
+++ b/dev-python/transitions/Manifest
@@ -1 +1,2 @@
 DIST transitions-0.9.0.gh.tar.gz 1116052 BLAKE2B 
3c3f0f70029fac11b89741c17b4f8223ffff7b1f4120dbacf9047c7c9d8063df00449e7ceb378aeb6263d4f55245bb89f08f6eaa0a74948368bd0eb0227fea40
 SHA512 
805894ba772e4a31f1fd567d3765f8ee3f3498ca5b9dd4d5b94224722d48347a2feee284dab577eca97a748dc6f810dedf1cbc3b50f41f0ab5b65d84241b9638
+DIST transitions-0.9.1.gh.tar.gz 1124905 BLAKE2B 
6d8700c9b2b2d200c8377e698f4057caa78908ee7156daa3fce1f49d86c6bc9afd45fe7af4122c2e124681c3c581e98f657e39444595f97ed7fb3c64f57d70fd
 SHA512 
8e946ee9b8e3ed0629381514b4af4446625de0cea7cc8780326829ad987b4c0f9402484ed98ca66b12e95c8da79f77c62aba9f000dbe42779f158529cde3f279

diff --git a/dev-python/transitions/transitions-0.9.1.ebuild 
b/dev-python/transitions/transitions-0.9.1.ebuild
new file mode 100644
index 000000000000..eadff084d9b8
--- /dev/null
+++ b/dev-python/transitions/transitions-0.9.1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517="setuptools"
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="A lightweight, object-oriented state machine implementation in 
Python"
+HOMEPAGE="https://github.com/pytransitions/transitions";
+SRC_URI="
+       https://github.com/pytransitions/${PN}/archive/${PV}.tar.gz
+               -> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="examples"
+
+RDEPEND="
+       || (
+               dev-python/pygraphviz[${PYTHON_USEDEP}]
+               dev-python/graphviz[${PYTHON_USEDEP}]
+       )
+       dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+       test? (
+               dev-python/dill[${PYTHON_USEDEP}]
+               dev-python/mock[${PYTHON_USEDEP}]
+       )
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+       distutils-r1_src_prepare
+
+       # magic to ignore async tests sometimes, breaks EPYTEST_IGNORE
+       rm conftest.py || die
+}
+
+python_test() {
+       local EPYTEST_IGNORE=(
+               # pycodestyle, mypy, etc.
+               tests/test_codestyle.py
+       )
+
+       local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+       epytest
+}
+
+src_install() {
+       distutils-r1_src_install
+       use examples && dodoc examples/*.ipynb
+}