commit: 41046439729d438183951b05a9a65daca9d9bade
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun May 12 02:29:07 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun May 12 02:29:07 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=41046439
dev-python/tavern: Bump to 2.11.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/tavern/Manifest | 1 +
dev-python/tavern/tavern-2.11.0.ebuild | 66 ++++++++++++++++++++++++++++++++++
2 files changed, 67 insertions(+)
diff --git a/dev-python/tavern/Manifest b/dev-python/tavern/Manifest
index 435e5d4429f1..ae307dbd49df 100644
--- a/dev-python/tavern/Manifest
+++ b/dev-python/tavern/Manifest
@@ -1 +1,2 @@
DIST tavern-2.10.3.gh.tar.gz 240386 BLAKE2B
eb01cdabb171de101784c4fecf99c59fad892e9819e4b047e9d6f30a27b742ac49eb1840a66225466f2de09f8e0883941de92a4051898fe479e35ee06151a0d4
SHA512
e27da0da1d9eb8302ba34191bb9e157a28335c90012569218709f65b761c2f01d47c2e60a4a72df320cb7a2575ee3e890c3dc37027fb91fc90d97305d2afe277
+DIST tavern-2.11.0.gh.tar.gz 233387 BLAKE2B
b1b26e7d9fc4069c7056072ab01c9937245304982f78df236e9bcaa795feec6a1db7192532dba6d17d362af874bffce601bb9652b5f1ecda99c59387f717bb15
SHA512
456fa6ebfc6f47ff9a473e3f416aff9f88b1f9b25c898786d15472072859e1659c089a9c668e6ddc4ecfc0cc8c233417d4768e0f7228800995509a5a34294faf
diff --git a/dev-python/tavern/tavern-2.11.0.ebuild
b/dev-python/tavern/tavern-2.11.0.ebuild
new file mode 100644
index 000000000000..20ce5fc3aaf2
--- /dev/null
+++ b/dev-python/tavern/tavern-2.11.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="A tool, library, and Pytest plugin for testing RESTful APIs"
+HOMEPAGE="
+ https://github.com/taverntesting/tavern/
+ https://pypi.org/project/tavern/
+"
+SRC_URI="
+ https://github.com/taverntesting/tavern/archive/${PV}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+ >=dev-python/jmespath-1[${PYTHON_USEDEP}]
+ >=dev-python/jsonschema-4[${PYTHON_USEDEP}]
+ <dev-python/paho-mqtt-2[${PYTHON_USEDEP}]
+ >=dev-python/paho-mqtt-1.3.1[${PYTHON_USEDEP}]
+ >=dev-python/pyjwt-2.5.0[${PYTHON_USEDEP}]
+ >=dev-python/pykwalify-1.8.0[${PYTHON_USEDEP}]
+ >=dev-python/pytest-7[${PYTHON_USEDEP}]
+ >=dev-python/python-box-6[${PYTHON_USEDEP}]
+ >=dev-python/pyyaml-6.0.1[${PYTHON_USEDEP}]
+ >=dev-python/requests-2.22.0[${PYTHON_USEDEP}]
+ >=dev-python/stevedore-4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ dev-python/colorlog[${PYTHON_USEDEP}]
+ dev-python/Faker[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+ # strip unnecessary pins, upstream doesn't update them a lot
+ sed -i -E -e 's:,?<=?[0-9.]+::' pyproject.toml || die
+ distutils-r1_src_prepare
+}
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # requires grpc
+ tests/unit/test_extensions.py::TestGrpcCodes
+ )
+ local EPYTEST_IGNORE=(
+ # require grpc*
+ tavern/_plugins/grpc
+ tests/unit/tavern_grpc
+ )
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest -p tavern
+}
