[gentoo-commits] repo/gentoo:master commit in: net-vpn/eduvpn-common/

[Florian Schmaus]

commit:     0d7192305fe7e5f191e01a07be7623dcbb1c5e46
Author:     Mario Haustein <mario.haustein <AT> hrz <DOT> tu-chemnitz <DOT> de>
AuthorDate: Mon Mar 11 18:45:32 2024 +0000
Commit:     Florian Schmaus <flow <AT> gentoo <DOT> org>
CommitDate: Fri Apr 19 10:05:16 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0d719230

net-vpn/eduvpn-common: add 1.99.1

Signed-off-by: Mario Haustein <mario.haustein <AT> hrz.tu-chemnitz.de>
Signed-off-by: Florian Schmaus <flow <AT> gentoo.org>

 net-vpn/eduvpn-common/Manifest                    |  3 +
 net-vpn/eduvpn-common/eduvpn-common-1.99.1.ebuild | 96 +++++++++++++++++++++++
 2 files changed, 99 insertions(+)

diff --git a/net-vpn/eduvpn-common/Manifest b/net-vpn/eduvpn-common/Manifest
index 333e74870bcb..463017f63e86 100644
--- a/net-vpn/eduvpn-common/Manifest
+++ b/net-vpn/eduvpn-common/Manifest
@@ -3,3 +3,6 @@ DIST eduvpn-common-1.1.2.gh.tar.gz 208300 BLAKE2B 
8cb7e96d4a6a5032a1696aa57a6322
 DIST eduvpn-common-1.2.0-deps.tar.xz 7583176 BLAKE2B 
af35dd134a77753448fc9e7f91bde9d52fe05c20339eea637d0d0c5e9564f19cae6e294723adf1ef6c516ae05bc0495be2f316b2560b9d1860d9ce509517e04b
 SHA512 
83e88038a6b5cb39917f9b892ac8783ef273c9e606173aad68125702a70a70dc9c61f54f0078d92214d6e1ec3e92cbdff3d10f18caf889cd603a2d75fa70c209
 DIST eduvpn-common-1.2.0.tar.xz 738836 BLAKE2B 
85a10cee1a18e88a8f19bae8c8273cc2993b4dfa29106804342079739c5549e517194f2f4b52225e7f557cce45cffbc74b110f82c4cfd9d8141096d97445938d
 SHA512 
8858e85b1422340a87ee8df2a8392bdf910fb282c6a80c171a89cd535bb119958c46576a17c57cf9a02bf9946ed749e01bacdbd9c45fa8623c7d6dfa9272aa36
 DIST eduvpn-common-1.2.0.tar.xz.asc 228 BLAKE2B 
6b9de0767b9f755235556ab15447a639930447bea91c7880b9248844eac7600ad22ff2828a3e73176c65fb824a0b870604d53e68964850b5e8239dbd5ffd1fff
 SHA512 
6d54112f22ba6272ca56cea3ad82d0de1b24365a9d61f8ac9f1708741d491ff3184b47bc86845f8ace0a5f44fb5ad7614535ce665b71dd56510445c1d4777d34
+DIST eduvpn-common-1.99.1-deps.tar.xz 24548260 BLAKE2B 
59065c553899cbabd1a867e77d907489deecaea4c279c24e0390ce7cf9e8b067ab972e390d9df3d7fb85a6057319002db20c7a3b2370835fb24994691ef803e3
 SHA512 
d1cbc8ab1823b51d5e1ea8ebe24cf94efcd431cc068569dd9dbf27e649e790662374600fdb9144fa4321c655d96ee3260de37edaa3870049c508630cc3208aa0
+DIST eduvpn-common-1.99.1.tar.xz 843316 BLAKE2B 
53ff3518d7450f8c414d94291c22479464dbe810de4d5971aca61462782a615a82133e461f688b2975763f867464eac6a70bd946a75ab4085322ba5289717571
 SHA512 
757f05f391bde1be0b1d57a92d21138d96659052bee2922814d612950b0d3e8c8ebf21178b8d8d27263765870328057b69ca58db7629c5c092b3637957060be7
+DIST eduvpn-common-1.99.1.tar.xz.asc 228 BLAKE2B 
9af5f284ca4e096cd291e7b387be302282e841fb9beb0b0715d781f38ebb5dc66f23b98f502610dcc23dc4faf24cf158a8e9ebb90ad06113fc83b8756cf70452
 SHA512 
24561e484fd3b66e2bb2ce4e275db9a125370dbd7113f2c8a1a6a267b016c2d793701b2e89f6c8835e662cec6a2ceb11e5d287312b30c93e57d2104b67beb2ed

diff --git a/net-vpn/eduvpn-common/eduvpn-common-1.99.1.ebuild 
b/net-vpn/eduvpn-common/eduvpn-common-1.99.1.ebuild
new file mode 100644
index 000000000000..c7b72cbd8d60
--- /dev/null
+++ b/net-vpn/eduvpn-common/eduvpn-common-1.99.1.ebuild
@@ -0,0 +1,96 @@
+# Copyright 2021-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+DISTUTILS_USE_PEP517=setuptools
+DISTUTILS_EXT=1
+inherit distutils-r1 go-module linux-info
+
+DESCRIPTION="Linux client and Python client API for eduVPN"
+HOMEPAGE="https://www.eduvpn.org/";
+
+if [[ ${PV} == "9999" ]] ; then
+       inherit git-r3
+       EGIT_REPO_URI="https://github.com/eduvpn/eduvpn-common.git";
+else
+       # Development Versions use a different release signing key
+       if [[ $(ver_cut 2) == 99 || $(ver_cut 3) == 99 ]] ; then
+               
VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/eduvpn-dev.asc
+       else
+               VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/eduvpn.asc
+       fi
+       inherit verify-sig
+       SRC_URI="
+               
https://github.com/eduvpn/eduvpn-common/releases/download/${PV}/eduvpn-common-${PV}.tar.xz
+               verify-sig? ( 
https://github.com/eduvpn/eduvpn-common/releases/download/${PV}/eduvpn-common-${PV}.tar.xz.asc
 )
+               https://www-user.tu-chemnitz.de/~hamari/eduvpn/${P}-deps.tar.xz
+       "
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="openvpn wireguard"
+RESTRICT="test"
+
+RDEPEND="
+       openvpn? ( net-vpn/openvpn )
+"
+
+if [[ ${PV} != *9999* ]] ; then
+       BDEPEND="verify-sig? ( >=sec-keys/openpgp-keys-eduvpn-20240307 )"
+fi
+
+wrap_python() {
+       local phase=$1
+       shift
+
+       pushd wrappers/python >/dev/null || die
+       distutils-r1_${phase} "$@"
+       popd >/dev/null || die
+}
+
+pkg_pretend() {
+       if use wireguard; then
+               CONFIG_CHECK="~WIREGUARD"
+               WARNING_WIREGUARD="You must enable WIREGUARD to use wireguard."
+               check_extra_config
+       fi
+}
+
+src_unpack() {
+       # go dependencies are not signed
+       if use verify-sig; then
+               pushd "${DISTDIR}" > /dev/null || die
+               verify-sig_verify_detached \
+                       ${P}.tar.xz{,.asc}
+               popd > /dev/null || die
+       fi
+       default_src_unpack
+}
+
+src_prepare() {
+       default
+
+       mkdir -p wrappers/python/eduvpn_common/lib || die
+
+       wrap_python ${FUNCNAME}
+}
+
+src_compile() {
+       default
+       wrap_python ${FUNCNAME}
+}
+
+src_test() {
+       default
+       wrap_python ${FUNCNAME}
+}
+
+src_install() {
+       # The shared library is installed within the python package. There is no
+       # need to call the default routine.
+       wrap_python ${FUNCNAME}
+}