commit: afb56285dcd564a4c2cef517ddaa0537e1ac7ce6
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Mar 28 05:37:06 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Mar 28 05:55:34 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=afb56285
dev-python/tavern: Bump to 2.10.1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/tavern/Manifest | 1 +
dev-python/tavern/tavern-2.10.1.ebuild | 65 ++++++++++++++++++++++++++++++++++
2 files changed, 66 insertions(+)
diff --git a/dev-python/tavern/Manifest b/dev-python/tavern/Manifest
index 263285d0faf7..82e7ab2a2912 100644
--- a/dev-python/tavern/Manifest
+++ b/dev-python/tavern/Manifest
@@ -1 +1,2 @@
+DIST tavern-2.10.1.gh.tar.gz 239917 BLAKE2B
836f4940ba7b9a17455e757a7bdec578effc6753162d0ff0b05c46d293cad840924f3e8d66aac08553478d63eb0edb61ad39f53e4e36d9a7681bae303e71a614
SHA512
a09e55e2fa71d2601833137e51fc94cb8bd65086fc21e6c26055406a6be3dce44b57f89d91d7a766aa88c0b5b4214f28eeda69812f1f623ed60f45f57dcf2ded
DIST tavern-2.9.3.gh.tar.gz 248368 BLAKE2B
feccd1c8e50db6def318553186f0dbfc9643c3942e060bb1950305c4e93fac15550b06d7ba5c2c6008175ef5a701f211408da3607ffcf3429d5542c97029cc7b
SHA512
525a0b3f2c63fe4a9991ace7e27287898cbcd423e915e9ff4585eb85e0e42f06e499f653b2615b3f98998206b48c6c8f42468fae174ca4d7e7a38bf171b6feda
diff --git a/dev-python/tavern/tavern-2.10.1.ebuild
b/dev-python/tavern/tavern-2.10.1.ebuild
new file mode 100644
index 000000000000..74fcee9d1337
--- /dev/null
+++ b/dev-python/tavern/tavern-2.10.1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="A tool, library, and Pytest plugin for testing RESTful APIs"
+HOMEPAGE="
+ https://github.com/taverntesting/tavern/
+ https://pypi.org/project/tavern/
+"
+SRC_URI="
+ https://github.com/taverntesting/tavern/archive/${PV}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+ >=dev-python/jmespath-1[${PYTHON_USEDEP}]
+ >=dev-python/jsonschema-4[${PYTHON_USEDEP}]
+ >=dev-python/paho-mqtt-1.3.1[${PYTHON_USEDEP}]
+ >=dev-python/pyjwt-2.5.0[${PYTHON_USEDEP}]
+ >=dev-python/pykwalify-1.8.0[${PYTHON_USEDEP}]
+ >=dev-python/pytest-7[${PYTHON_USEDEP}]
+ >=dev-python/python-box-6[${PYTHON_USEDEP}]
+ >=dev-python/pyyaml-6.0.1[${PYTHON_USEDEP}]
+ >=dev-python/requests-2.22.0[${PYTHON_USEDEP}]
+ >=dev-python/stevedore-4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ dev-python/colorlog[${PYTHON_USEDEP}]
+ dev-python/Faker[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+ # strip unnecessary pins, upstream doesn't update them a lot
+ sed -i -E -e 's:,?<=?[0-9.]+::' pyproject.toml || die
+ distutils-r1_src_prepare
+}
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # requires grpc
+ tests/unit/test_extensions.py::TestGrpcCodes
+ )
+ local EPYTEST_IGNORE=(
+ # require grpc*
+ tavern/_plugins/grpc
+ tests/unit/tavern_grpc
+ )
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest -p tavern
+}
