commit: 806db3e75b18c38969819f3913202fcfbcdd30d5
Author: Patrick McLean <chutzpah <AT> gentoo <DOT> org>
AuthorDate: Wed Mar 6 22:59:12 2024 +0000
Commit: Patrick McLean <chutzpah <AT> gentoo <DOT> org>
CommitDate: Tue Mar 12 21:39:20 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=806db3e7
dev-python/raet: Revbump, minor cleanups, py312
Signed-off-by: Patrick McLean <chutzpah <AT> gentoo.org>
dev-python/raet/raet-0.6.8-r6.ebuild | 48 ++++++++++++++++++++++++++++++++++++
1 file changed, 48 insertions(+)
diff --git a/dev-python/raet/raet-0.6.8-r6.ebuild
b/dev-python/raet/raet-0.6.8-r6.ebuild
new file mode 100644
index 000000000000..94a1bee2724e
--- /dev/null
+++ b/dev-python/raet/raet-0.6.8-r6.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Reliable Asynchronous Event Transport Protocol"
+HOMEPAGE="
+ https://github.com/RaetProtocol/raet/
+ https://pypi.org/project/raet/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ >=dev-python/six-1.6.1[${PYTHON_USEDEP}]
+ >=dev-python/libnacl-1.4.3[${PYTHON_USEDEP}]
+ >=dev-python/ioflo-2.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ >=dev-python/msgpack-1.0.0[${PYTHON_USEDEP}]
+ )
+"
+
+PATCHES=(
+ "${FILESDIR}/raet-0.6.8-msgpack-1.0.patch"
+ "${FILESDIR}/raet-0.6.8-py310.patch"
+)
+
+python_prepare_all() {
+ distutils-r1_python_prepare_all
+ sed -e "/setuptools_git/d" -i setup.py || die
+}
+
+python_test() {
+ pushd "${BUILD_DIR}/install$(python_get_sitedir)" >/dev/null || die
+ "${EPYTHON}" raet/test/__init__.py || die "tests failed for ${EPYTHON}"
+ popd >/dev/null || die
+}
