commit: ec793217ccf47f98366a2168f0bace624d2a516a
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Mar 4 05:37:18 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Mar 4 06:31:16 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ec793217
dev-python/nox: Bump to 2024.03.02
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/nox/Manifest | 1 +
dev-python/nox/nox-2024.03.02.ebuild | 64 ++++++++++++++++++++++++++++++++++++
2 files changed, 65 insertions(+)
diff --git a/dev-python/nox/Manifest b/dev-python/nox/Manifest
index ed0a28875abd..00392e4cdf40 100644
--- a/dev-python/nox/Manifest
+++ b/dev-python/nox/Manifest
@@ -1 +1,2 @@
DIST nox-2023.04.22.gh.tar.gz 3985377 BLAKE2B
7365141bf1c299f6e560dbf42a2927f98e5bf7121ed0dc1dbdc739de847caafdc0834fdc2f2473f20b97d25a4d1d01aced8400e85ec6c027494b8d93077d9a0b
SHA512
7425588b0ae87d66211a4fec1d204122a2adb114ddca866d2e66e1caff930f593af1540e5c88806894400ea8aba92037d3f458a98df05d6ac70662705426ee6e
+DIST nox-2024.03.02.gh.tar.gz 3995248 BLAKE2B
3dc1ad8764fb1f849d15b7613999e2a9480f4b072d1b3ceb1d4316a8a97eaad418dc0d151b5477bf807e0f8b983fd53ca73a29cae3faed4f93a015f5b1d253ad
SHA512
7b76d62ced6d6968fab489223fbe2af1270b19fe2f2376c2fef375c47ca1bce7de23a5686b7c8dc617cb0cd331a90b9806bf3b478c28e61294aa4ea453635dcb
diff --git a/dev-python/nox/nox-2024.03.02.ebuild
b/dev-python/nox/nox-2024.03.02.ebuild
new file mode 100644
index 000000000000..a6a145b1df10
--- /dev/null
+++ b/dev-python/nox/nox-2024.03.02.ebuild
@@ -0,0 +1,64 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Flexible test automation for Python"
+HOMEPAGE="
+ https://github.com/wntrblm/nox/
+ https://pypi.org/project/nox/
+"
+SRC_URI="
+ https://github.com/wntrblm/nox/archive/${PV}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+ >=dev-python/argcomplete-1.9.4[${PYTHON_USEDEP}]
+ >=dev-python/colorlog-2.6.1[${PYTHON_USEDEP}]
+ >=dev-python/packaging-20.9[${PYTHON_USEDEP}]
+ >=dev-python/virtualenv-20.14.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ dev-python/py[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+ # remove upper bounds from dependencies
+ sed -i -e 's:<[0-9.]*,::' pyproject.toml || die
+ distutils-r1_src_prepare
+}
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # TODO: conda?
+
'tests/test_sessions.py::TestSessionRunner::test__create_venv_options[nox.virtualenv.CondaEnv.create-conda-CondaEnv]'
+ )
+
+ case ${EPYTHON} in
+ pypy3)
+ EPYTEST_DESELECT+=(
+ # hardcoded CPython assumption
+ tests/test_tox_to_nox.py::test_skipinstall
+ tests/test_tox_to_nox.py::test_trivial
+ tests/test_tox_to_nox.py::test_usedevelop
+ )
+ ;;
+ esac
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest -o tmp_path_retention_policy=all
+}
