[gentoo-commits] repo/proj/guru:dev commit in: dev-util/find-work/

[Anna Vyalkova]

commit:     9db8622bdf539e5ee6a20addbb76f29e8e95cb12
Author:     Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
AuthorDate: Tue Jan  9 02:56:32 2024 +0000
Commit:     Anna Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
CommitDate: Tue Jan  9 02:56:32 2024 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=9db8622b

dev-util/find-work: add 0.2.0

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq.in>

 dev-util/find-work/Manifest               |  1 +
 dev-util/find-work/find-work-0.2.0.ebuild | 65 +++++++++++++++++++++++++++++++
 2 files changed, 66 insertions(+)

diff --git a/dev-util/find-work/Manifest b/dev-util/find-work/Manifest
index d6adf0550e..68899d84c7 100644
--- a/dev-util/find-work/Manifest
+++ b/dev-util/find-work/Manifest
@@ -1 +1,2 @@
 DIST find_work-0.1.1.tar.gz 10530 BLAKE2B 
51294e6b9e21c72fcd2da77c4ecd0c0cb3614d631b7d4840dbc3d774d83aa910a5b83277c7be2c16adb3f0827b5841e5ad24107ac7a546380d4c056e9a8e275a
 SHA512 
b0f06689554ec2a8d27da270874c89fc31683c0f211d0bacbbe7fee8482a0115107f21836c7ebdaf13ea297030d0870bc53919a90e68ccf10da615eeb9111c5f
+DIST find_work-0.2.0.tar.gz 11440 BLAKE2B 
507da062ca3a30885fedf49831be2454ea2012aabab052599fd3d2740d3a30b602c5b0eb2e7e69699dc5858f279d7dc041481f1fd9c7403b19f18c3953d32d76
 SHA512 
ad38a464bb682c18e5ae49f15e00041909bc6104ba59efb21a2447b7da84872b2ec191071a60721d50e6eacfeecbbe46d790faffe1e4232a49d8da31bce40e5d

diff --git a/dev-util/find-work/find-work-0.2.0.ebuild 
b/dev-util/find-work/find-work-0.2.0.ebuild
new file mode 100644
index 0000000000..134d677904
--- /dev/null
+++ b/dev-util/find-work/find-work-0.2.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+DISTUTILS_USE_PEP517=hatchling
+inherit distutils-r1 pypi shell-completion
+
+DESCRIPTION="Personal advice utility for Gentoo package maintainers"
+HOMEPAGE="
+       https://find-work.sysrq.in/
+       https://pypi.org/project/find-work/
+"
+
+LICENSE="WTFPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+       <app-portage/gentoopm-2[${PYTHON_USEDEP}]
+       >=dev-python/aiohttp-3[${PYTHON_USEDEP}]
+       <dev-python/aiohttp-4[${PYTHON_USEDEP}]
+       dev-python/click[${PYTHON_USEDEP}]
+       dev-python/click-aliases[${PYTHON_USEDEP}]
+       >=dev-python/pydantic-2[${PYTHON_USEDEP}]
+       <dev-python/pydantic-3[${PYTHON_USEDEP}]
+       >=dev-python/repology-client-0.0.2[${PYTHON_USEDEP}]
+       <dev-python/repology-client-2[${PYTHON_USEDEP}]
+       dev-python/sortedcontainers[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+distutils_enable_sphinx docs \
+       dev-python/insipid-sphinx-theme \
+       dev-python/sphinx-prompt
+
+src_prepare() {
+       distutils-r1_src_prepare
+       mkdir completions || die
+}
+
+python_compile() {
+       distutils-r1_python_compile
+
+       local -x PATH="${BUILD_DIR}/install${EPREFIX}/usr/bin:${PATH}"
+       local -x PYTHONPATH="${BUILD_DIR}/lib:${PYTHONPATH}"
+       emake completions/find-work.{bash,zsh,fish}
+}
+
+src_install() {
+       distutils-r1_src_install
+
+       local mymakeargs=(
+               DESTDIR="${D}"
+               PREFIX="${EPREFIX}"/usr
+
+               BASHCOMPDIR="$(get_bashcompdir)"
+               ZSHCOMPDIR="$(get_zshcompdir)"
+               FISHCOMPDIR="$(get_fishcompdir)"
+       )
+
+       emake "${mymakeargs[@]}" install-data
+}