[gentoo-commits] repo/gentoo:master commit in: dev-python/pdm-backend/

[Michał Górny]

commit:     42c6c1e67fbc51e354fad5fcf368981822305d78
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Dec 27 12:58:57 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Dec 27 12:58:57 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=42c6c1e6

dev-python/pdm-backend: Bump to 2.1.8

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pdm-backend/Manifest                 |  1 +
 dev-python/pdm-backend/pdm-backend-2.1.8.ebuild | 68 +++++++++++++++++++++++++
 2 files changed, 69 insertions(+)

diff --git a/dev-python/pdm-backend/Manifest b/dev-python/pdm-backend/Manifest
index 8c6aacc7d967..aadb91223560 100644
--- a/dev-python/pdm-backend/Manifest
+++ b/dev-python/pdm-backend/Manifest
@@ -1 +1,2 @@
 DIST pdm-backend-2.1.7.gh.tar.gz 134479 BLAKE2B 
e559792b53310d6c159ed0cfae6fd9332bbdebfe0efaa9aae7e149b4800b7231e1561723b6aebb4cd722bc47c5a8c9f13180dfe96607a08a9a5c0fba530c9098
 SHA512 
d47b814b427799d8b2d106b4721c770fd703143cac5de819d74c47d4808f9130bd5835d5fafe41ab3bb17abfedeb770c8863a9cb9a7c8aba0ef9315f5308e6b3
+DIST pdm-backend-2.1.8.gh.tar.gz 134738 BLAKE2B 
5baf6db7193f27de5aa89e41852c714de7d2aa7fd9f75de9b1f1ebd455052bc9d9d47d95dbbed3436e9e9dae79c9a1d0ec54d71a4437036869de38aa035f0642
 SHA512 
975dad24d128a01b5484f62aece3b209eb3dddf3800c75e422ed1dd0d4cbe15ce60a155d6ed0cec4104eef47cad822e56a2379c877e3f5c8c719dfa86d8800c7

diff --git a/dev-python/pdm-backend/pdm-backend-2.1.8.ebuild 
b/dev-python/pdm-backend/pdm-backend-2.1.8.ebuild
new file mode 100644
index 000000000000..8f4cf7b5dcd5
--- /dev/null
+++ b/dev-python/pdm-backend/pdm-backend-2.1.8.ebuild
@@ -0,0 +1,68 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A PEP 517 backend for PDM that supports PEP 621 metadata"
+HOMEPAGE="
+       https://pypi.org/project/pdm-backend/
+       https://github.com/pdm-project/pdm-backend/
+"
+SRC_URI="
+       https://github.com/pdm-project/pdm-backend/archive/${PV}.tar.gz
+               -> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv 
~s390 ~sparc ~x86"
+
+RDEPEND="
+       >=dev-python/packaging-22.0[${PYTHON_USEDEP}]
+       >=dev-python/pyproject-metadata-0.7.1[${PYTHON_USEDEP}]
+       >=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+
+       $(python_gen_cond_dep '
+               >=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+       ' 3.10)
+"
+BDEPEND="
+       ${RDEPEND}
+       test? (
+               dev-python/setuptools[${PYTHON_USEDEP}]
+               dev-vcs/git
+       )
+"
+# setuptools are used to build C extensions
+RDEPEND+="
+       dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+       rm -r src/pdm/backend/_vendor || die
+       find -name '*.py' -exec sed \
+               -e 's:from pdm\.backend\._vendor\.:from :' \
+               -e 's:from pdm\.backend\._vendor ::' \
+               -e 's:import pdm\.backend\._vendor\.:import :' \
+               -i {} + || die
+       distutils-r1_src_prepare
+}
+
+src_compile() {
+       # this must not be set during src_test()
+       local -x PDM_BUILD_SCM_VERSION=${PV}
+       distutils-r1_src_compile
+}
+
+src_test() {
+       git config --global user.email "t...@example.com" || die
+       git config --global user.name "Test User" || die
+       distutils-r1_src_test
+}