commit: 22072364b5463aefe5243fbfa3aa1eb231fed9a0
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Dec 20 15:22:11 2023 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Dec 20 15:29:10 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=22072364
dev-python/httpx: Bump to 0.26.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/httpx/Manifest | 1 +
dev-python/httpx/httpx-0.26.0.ebuild | 83 ++++++++++++++++++++++++++++++++++++
2 files changed, 84 insertions(+)
diff --git a/dev-python/httpx/Manifest b/dev-python/httpx/Manifest
index 9b9521261fc8..44594bd67da0 100644
--- a/dev-python/httpx/Manifest
+++ b/dev-python/httpx/Manifest
@@ -1 +1,2 @@
DIST httpx-0.25.2.gh.tar.gz 2162693 BLAKE2B
8ae9fd692341ae3224c73c1f6837489819df1a00e13702a7af72143bf291cfcae23807fd51a6e1092672d0b5595f9557084151f3d07fbdd4e7fce8f5860a879f
SHA512
7e62fcea55b7d0710f6d50581c8dd1ff5ae594a673a9b1cea5c03487eb3402ca96d44c311a9bcef14f20a7faa03462a3fab07edfe1ce2b11ecd66e4f7e1a06d5
+DIST httpx-0.26.0.gh.tar.gz 2164373 BLAKE2B
1de507dd1a0a4f5c87187645f7928f37f29e9a6cdcaacfbefe0e324cda5ad7f86a29efe99b496629a2e2f14851b8a6312d8be4595cfc61a97ce302b284dd1939
SHA512
76838d5c191700f5fd4c6afcc9d129f3809811f6ce40d45edf89518457a9497cdd94c11a68a9c42494780c579eaa43760a8bd85313d7864a8f5ae1c1b9912d61
diff --git a/dev-python/httpx/httpx-0.26.0.ebuild
b/dev-python/httpx/httpx-0.26.0.ebuild
new file mode 100644
index 000000000000..c6d702cbd883
--- /dev/null
+++ b/dev-python/httpx/httpx-0.26.0.ebuild
@@ -0,0 +1,83 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Fully-featured HTTP client which provides sync and async APIs"
+HOMEPAGE="
+ https://www.python-httpx.org/
+ https://github.com/encode/httpx/
+ https://pypi.org/project/httpx/
+"
+SRC_URI="
+ https://github.com/encode/httpx/archive/${PV}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+ dev-python/anyio[${PYTHON_USEDEP}]
+ dev-python/certifi[${PYTHON_USEDEP}]
+ =dev-python/httpcore-1*[${PYTHON_USEDEP}]
+ dev-python/idna[${PYTHON_USEDEP}]
+ dev-python/sniffio[${PYTHON_USEDEP}]
+ cli? (
+ =dev-python/click-8*[${PYTHON_USEDEP}]
+ =dev-python/pygments-2*[${PYTHON_USEDEP}]
+ dev-python/rich[${PYTHON_USEDEP}]
+ )
+"
+BDEPEND="
+ dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
+ test? (
+ dev-python/brotlicffi[${PYTHON_USEDEP}]
+ dev-python/chardet[${PYTHON_USEDEP}]
+ dev-python/cryptography[${PYTHON_USEDEP}]
+ dev-python/h2[${PYTHON_USEDEP}]
+ dev-python/socksio[${PYTHON_USEDEP}]
+ dev-python/trio[${PYTHON_USEDEP}]
+ dev-python/trustme[${PYTHON_USEDEP}]
+ dev-python/typing-extensions[${PYTHON_USEDEP}]
+ dev-python/uvicorn[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+ if ! use cli; then
+ sed -i -e '/^httpx =/d' pyproject.toml || die
+ fi
+ sed -i -e '/rich/s:,<14::' pyproject.toml || die
+
+ distutils-r1_src_prepare
+}
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # Internet
+ tests/client/test_proxies.py::test_async_proxy_close
+ tests/client/test_proxies.py::test_sync_proxy_close
+ )
+
+ use cli || EPYTEST_IGNORE+=(
+ tests/test_main.py
+ )
+
+ epytest
+}
+
+pkg_postinst() {
+ optfeature "HTTP/2 support" dev-python/h2
+ optfeature "SOCKS proxy support" dev-python/socksio
+ optfeature "Decoding for brotli compressed responses"
dev-python/brotlicffi
+}
