commit: d20487df5102dd0b029e3346e9c31001125e3100
Author: Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 12 14:29:28 2023 +0000
Commit: Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Tue Dec 12 21:23:49 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d20487df
dev-qt/qtwayland: add 6.7.9999
Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>
dev-qt/qtwayland/qtwayland-6.7.9999.ebuild | 47 ++++++++++++++++++++++++++++++
1 file changed, 47 insertions(+)
diff --git a/dev-qt/qtwayland/qtwayland-6.7.9999.ebuild
b/dev-qt/qtwayland/qtwayland-6.7.9999.ebuild
new file mode 100644
index 000000000000..a9b9291aca02
--- /dev/null
+++ b/dev-qt/qtwayland/qtwayland-6.7.9999.ebuild
@@ -0,0 +1,47 @@
+# Copyright 2021-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Wayland platform plugin for Qt"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+ KEYWORDS="~amd64 ~arm ~arm64 ~loong ~x86"
+fi
+
+IUSE="compositor qml vulkan"
+
+RDEPEND="
+ dev-libs/wayland
+ ~dev-qt/qtbase-${PV}:6[gui,opengl,vulkan=,wayland]
+ media-libs/libglvnd
+ x11-libs/libxkbcommon
+ compositor? (
+ qml? ( ~dev-qt/qtdeclarative-${PV}:6 )
+ )
+"
+DEPEND="
+ ${RDEPEND}
+ vulkan? ( dev-util/vulkan-headers )
+"
+BDEPEND="dev-util/wayland-scanner"
+
+CMAKE_SKIP_TESTS=(
+ # segfaults for not-looked-into reasons, but not considered
+ # an issue given >=seatv5 exists since wayland-1.10 (2016)
+ tst_seatv4
+ # needs a compositor/opengl, skip the extra trouble
+ tst_surface
+ tst_xdgdecorationv1
+)
+
+src_configure() {
+ local mycmakeargs=(
+ $(cmake_use_find_package qml Qt6Quick)
+ $(qt_feature compositor wayland_server)
+ )
+
+ qt6-build_src_configure
+}
