[gentoo-commits] repo/gentoo:master commit in: media-radio/xastir/

[Thomas Beierlein]

commit:     66a55bd7ca1a76434eaa165ecb5576e5719acc8d
Author:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
AuthorDate: Thu Nov 16 18:40:40 2023 +0000
Commit:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
CommitDate: Thu Nov 16 18:43:24 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=66a55bd7

media-radio/xastir: add 2.2.0

Signed-off-by: Thomas Beierlein <tomjbe <AT> gentoo.org>

 media-radio/xastir/Manifest            |  1 +
 media-radio/xastir/xastir-2.2.0.ebuild | 79 ++++++++++++++++++++++++++++++++++
 2 files changed, 80 insertions(+)

diff --git a/media-radio/xastir/Manifest b/media-radio/xastir/Manifest
index db413c009cbb..eedf37811bbc 100644
--- a/media-radio/xastir/Manifest
+++ b/media-radio/xastir/Manifest
@@ -1 +1,2 @@
 DIST xastir-2.1.8.tar.gz 2222586 BLAKE2B 
4cd623c2db7a06c2499bf73a0df8c8f07b6a3072d177d370b76f54cb4caa4cf03f2b5c511149eaefc26f1aa7e8fe3a89e1c42e26a20066dd3337ad41dd5300b6
 SHA512 
361c92381b385035af160578dcfc4c800edcfabdbaebc5eda1c4fd9a78e934f289a54813577d5b765bbed6eae50cb772735defec6f489dc65326941d2492850d
+DIST xastir-2.2.0.tar.gz 2232411 BLAKE2B 
901a22ee9db6f2c416807dd11f532975bbaf38314224327a43acff0d7164200456e373cefd852b4022187a6c0c4d2182c2088c12bac93d0fc6ed6771c957c11f
 SHA512 
d420118e9118ff837d72f17e78563c7e9d39cfcaf05fe12cbf51b50ed36b9307e4b33b0e8a0d056c504a280683c6eb97637e9c4fec3bf1f0d920cb46f6e2cc0b

diff --git a/media-radio/xastir/xastir-2.2.0.ebuild 
b/media-radio/xastir/xastir-2.2.0.ebuild
new file mode 100644
index 000000000000..9cf4649e7f13
--- /dev/null
+++ b/media-radio/xastir/xastir-2.2.0.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit autotools flag-o-matic toolchain-funcs
+
+MY_P=${PN/x/X}-Release-${PV}
+
+DESCRIPTION="X Amateur Station Tracking and Information Reporting"
+HOMEPAGE="https://xastir.org/";
+SRC_URI="https://github.com/Xastir/Xastir/archive/Release-${PV}.tar.gz
+                       -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="geotiff"
+
+DEPEND=">=x11-libs/motif-2.3:0
+       x11-libs/libXt
+       x11-libs/libX11
+       x11-libs/libXpm
+       x11-apps/xfontsel
+       dev-libs/libpcre
+       net-misc/curl
+       sys-libs/db:=
+       sci-libs/shapelib
+       media-gfx/graphicsmagick:=[-q32]
+       geotiff? ( sci-libs/proj
+               sci-libs/libgeotiff:=
+               media-libs/tiff:= )"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}"/${MY_P}
+
+src_prepare() {
+       eapply_user
+
+       # fix script location (bug #407185)
+       eapply  "${FILESDIR}"/${PN}-2.1.8-scripts.diff
+
+       # do not filter duplicate flags (see bug #411095)
+       eapply -p0 "${FILESDIR}"/${PN}-2.0.0-dont-filter-flags.diff
+
+       eautoreconf
+}
+
+src_configure() {
+       # provide include path to GraphicsMagic for configure stage
+       append-cflags -I/usr/include/GraphicsMagick
+       econf \
+               --with-shapelib \
+               --without-ax25 \
+               --without-festival \
+               --without-gpsman \
+               --without-imagemagick \
+               --with-graphicsmagick \
+               $(use_with geotiff libproj) \
+               $(use_with geotiff)
+}
+
+src_compile() {
+       emake AR="$(tc-getAR)"
+}
+
+src_install() {
+       emake DESTDIR="${D}" install
+
+       rm -rf "${D}"/usr/share/doc/${PN}
+       dodoc AUTHORS ChangeLog CONTRIBUTING.md FAQ README \
+               README.MAPS README.OSM_maps
+}
+
+pkg_postinst() {
+       elog "Kernel mode AX.25 and GPSman library not supported."
+       elog
+       elog "Remember you have to be root to add addditional scripts,"
+       elog "maps and other configuration data under /usr/share/xastir."
+}