commit: 0c7f75e87067c82703836b199ed04a1868e35c15
Author: Sebastian Pipping <sping <AT> gentoo <DOT> org>
AuthorDate: Tue Nov 7 00:00:17 2023 +0000
Commit: Sebastian Pipping <sping <AT> gentoo <DOT> org>
CommitDate: Tue Nov 7 00:00:17 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0c7f75e8
dev-vcs/git-big-picture: Python 3.12
Signed-off-by: Sebastian Pipping <sping <AT> gentoo.org>
.../git-big-picture-1.2.2-r3.ebuild | 41 ++++++++++++++++++++++
1 file changed, 41 insertions(+)
diff --git a/dev-vcs/git-big-picture/git-big-picture-1.2.2-r3.ebuild
b/dev-vcs/git-big-picture/git-big-picture-1.2.2-r3.ebuild
new file mode 100644
index 000000000000..36aa2df82403
--- /dev/null
+++ b/dev-vcs/git-big-picture/git-big-picture-1.2.2-r3.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{9..12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Visualization tool for Git repositories"
+HOMEPAGE="https://github.com/git-big-picture/git-big-picture";
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+# NOTE: dev-util/cram explictly does not need [${PYTHON_USEDEP}]
+# since test.cram is a shell session and not Python code
+DEPEND="
+ test? (
+ dev-python/parameterized[${PYTHON_USEDEP}]
+ dev-python/pytest[${PYTHON_USEDEP}]
+ dev-util/cram
+ )
+"
+# No need for "[python]" or "[${PYTHON_USEDEP}]" with any of these
+# since they are invoked using subprocess
+RDEPEND="
+ dev-vcs/git
+ media-gfx/graphviz[svg]
+"
+
+RESTRICT="!test? ( test )"
+
+python_test() {
+ pytest -vv test.py || die "Tests fail with ${EPYTHON}"
+ cram test.cram || die "Tests fail with ${EPYTHON}"
+}
