commit: 0980e26052c1234328082da5ab680fbfe336954c
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Nov 3 17:44:10 2023 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Nov 3 18:35:10 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0980e260
dev-python/httpx: Bump to 0.25.1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/httpx/Manifest | 1 +
dev-python/httpx/httpx-0.25.1.ebuild | 87 ++++++++++++++++++++++++++++++++++++
2 files changed, 88 insertions(+)
diff --git a/dev-python/httpx/Manifest b/dev-python/httpx/Manifest
index 19716de6ae86..e045ea7d010f 100644
--- a/dev-python/httpx/Manifest
+++ b/dev-python/httpx/Manifest
@@ -1 +1,2 @@
DIST httpx-0.25.0.gh.tar.gz 2169337 BLAKE2B
632a11917c35150be4aa9a946ae90493ba19b37697f97f82c36334a1004c57e9c256af54bcd0afbc2d5a67bd48f28c578285dd48473c8ccfd4b1c11e2c6bc069
SHA512
0be0f7ed53061d1dd9e0010d5a10adc6508bd49bf51e5ccf44f0aa2f54bdd067e3a7d1f37dfab80d3d374984aca2f20c346e46b8bc518826ce3371abc7291ee3
+DIST httpx-0.25.1.gh.tar.gz 2162706 BLAKE2B
f13340d5b051fa2020c12825c31df8f5566c3900baa54267cf0718eaff35b600186cfee5a0db5d7fd1a86fbb94bb0d164c7c9be3d6508cd30fc2fbc75cc0c833
SHA512
ad67f45162e328dba3d74abc75cdae02cc4da1605e21456fbb2023f9f515efa6ec6c5799927a4a4557cf439819f9b05dc2805002e29b97102dadcf934cbd0e2b
diff --git a/dev-python/httpx/httpx-0.25.1.ebuild
b/dev-python/httpx/httpx-0.25.1.ebuild
new file mode 100644
index 000000000000..347658370c43
--- /dev/null
+++ b/dev-python/httpx/httpx-0.25.1.ebuild
@@ -0,0 +1,87 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Fully-featured HTTP client which provides sync and async APIs"
+HOMEPAGE="
+ https://www.python-httpx.org/
+ https://github.com/encode/httpx/
+ https://pypi.org/project/httpx/
+"
+SRC_URI="
+ https://github.com/encode/httpx/archive/${PV}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+ dev-python/anyio[${PYTHON_USEDEP}]
+ dev-python/certifi[${PYTHON_USEDEP}]
+ dev-python/httpcore[${PYTHON_USEDEP}]
+ dev-python/idna[${PYTHON_USEDEP}]
+ dev-python/sniffio[${PYTHON_USEDEP}]
+ cli? (
+ =dev-python/click-8*[${PYTHON_USEDEP}]
+ =dev-python/pygments-2*[${PYTHON_USEDEP}]
+ dev-python/rich[${PYTHON_USEDEP}]
+ )
+"
+BDEPEND="
+ dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
+ test? (
+ dev-python/brotlicffi[${PYTHON_USEDEP}]
+ dev-python/chardet[${PYTHON_USEDEP}]
+ dev-python/cryptography[${PYTHON_USEDEP}]
+ dev-python/h2[${PYTHON_USEDEP}]
+ dev-python/socksio[${PYTHON_USEDEP}]
+ dev-python/trio[${PYTHON_USEDEP}]
+ dev-python/trustme[${PYTHON_USEDEP}]
+ dev-python/typing-extensions[${PYTHON_USEDEP}]
+ dev-python/uvicorn[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+ if ! use cli; then
+ sed -i -e '/^httpx =/d' pyproject.toml || die
+ fi
+ sed -i -e '/rich/s:,<14::' pyproject.toml || die
+
+ # use brotlicffi instead of brotli in tests
+ sed -i -e 's:import brotli:import brotlicffi as brotli:' \
+ tests/test_decoders.py || die
+
+ distutils-r1_src_prepare
+}
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # Internet
+ tests/client/test_proxies.py::test_async_proxy_close
+ tests/client/test_proxies.py::test_sync_proxy_close
+ )
+
+ use cli || EPYTEST_IGNORE+=(
+ tests/test_main.py
+ )
+
+ epytest
+}
+
+pkg_postinst() {
+ optfeature "HTTP/2 support" dev-python/h2
+ optfeature "SOCKS proxy support" dev-python/socksio
+ optfeature "Decoding for brotli compressed responses"
dev-python/brotlicffi
+}
