commit: 204198253b6ee20f27f8534eabfd6f240b16ad5c
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Oct 22 14:04:03 2023 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Oct 22 17:31:51 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=20419825
dev-python/PySDL2: Bump to 0.9.16
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/PySDL2/Manifest | 1 +
dev-python/PySDL2/PySDL2-0.9.16.ebuild | 68 ++++++++++++++++++++++++++++++++++
2 files changed, 69 insertions(+)
diff --git a/dev-python/PySDL2/Manifest b/dev-python/PySDL2/Manifest
index 9255809946ef..50a3d0c6876c 100644
--- a/dev-python/PySDL2/Manifest
+++ b/dev-python/PySDL2/Manifest
@@ -1 +1,2 @@
DIST PySDL2-0.9.13.tar.gz 754811 BLAKE2B
fe9d3fb32cac104303d67741c3b9e0d78d3d03198ed512464bbdf5bc487a5f4c9a92aafb100c53c02d8be87bb107034f67ebb72294ad67cc0a8b42ab7a678a31
SHA512
f866e7ed35e3ccfbb5b98f797e87d5b20c6f7dadbc3396b297cbb6c2d83a7f3290fde63940a4d8f190e40a4a9269d2df9efc1932d9578d3df1617e5fcbe6ecad
+DIST PySDL2-0.9.16.tar.gz 773537 BLAKE2B
5cfe4ab3981a665fc7f7606c07a3252e58c2706e45ab41d0d6444b4d3fb1c8805b5fd67e770a8a64538d305be0013a4d599ee81f5de0c5370146edc9d4d858df
SHA512
ffe7abe8e828926934677c81a42c9af794c4817144eba50c40430c150d476dea40f0b36e639b2c270cbd8e00ab5bf5b032a4c0e514255cceef8161c8d76f8cb2
diff --git a/dev-python/PySDL2/PySDL2-0.9.16.ebuild
b/dev-python/PySDL2/PySDL2-0.9.16.ebuild
new file mode 100644
index 000000000000..76ccec4c0b4b
--- /dev/null
+++ b/dev-python/PySDL2/PySDL2-0.9.16.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python (ctypes) bindings for SDL2 libraries"
+HOMEPAGE="
+ https://github.com/py-sdl/py-sdl2/
+ https://pypi.org/project/PySDL2/
+"
+
+LICENSE="|| ( public-domain CC0-1.0 ZLIB )"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+# Optional deps:
+# - dev-python/numpy,
+# - dev-python/pillow,
+# - media-libs/sdl2-* (loaded dynamically via ctypes).
+#
+# If a reverse dependency needs the specific module, it should
+# explicitly depend on the optional module in question. You also
+# probably need to explicitly require some media-libs/libsdl2 flags.
+RDEPEND="media-libs/libsdl2"
+
+# Require all of SDL2 libraries and at least the most common subsystems
+# for better test coverage.
+DEPEND="
+ test? (
+ dev-python/numpy[${PYTHON_USEDEP}]
+ dev-python/pillow[${PYTHON_USEDEP}]
+ media-libs/libsdl2[joystick,sound,video]
+ media-libs/sdl2-gfx
+ media-libs/sdl2-image[gif,jpeg,png,tiff,webp]
+ || (
+ media-libs/sdl2-mixer[flac]
+ media-libs/sdl2-mixer[midi]
+ media-libs/sdl2-mixer[mod]
+ media-libs/sdl2-mixer[mp3]
+ media-libs/sdl2-mixer[opus]
+ )
+ media-libs/sdl2-ttf
+ )"
+
+distutils_enable_tests pytest
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # libsdl2 itself is broken in numerous ways
+ # https://bugs.gentoo.org/916120
+ sdl2/test/gamecontroller_test.py
+ # https://bugs.gentoo.org/916118
+ sdl2/test/hidapi_test.py::test_SDL_hid_enumerate
+ )
+
+ local -x SDL_VIDEODRIVER=dummy
+ local -x SDL_AUDIODRIVER=dummy
+ local -x SDL_RENDER_DRIVER=software
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ epytest -x
+}
