commit: 4bdd038102888b6709631472a43fcc363652d943
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Oct 5 14:28:06 2023 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Oct 5 14:59:27 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4bdd0381
dev-python/tables: Bump to 3.9.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/tables/Manifest | 1 +
dev-python/tables/tables-3.9.0.ebuild | 73 +++++++++++++++++++++++++++++++++++
2 files changed, 74 insertions(+)
diff --git a/dev-python/tables/Manifest b/dev-python/tables/Manifest
index 63cd4acb139e..aadcf6e8c633 100644
--- a/dev-python/tables/Manifest
+++ b/dev-python/tables/Manifest
@@ -1 +1,2 @@
DIST tables-3.8.0.tar.gz 8014052 BLAKE2B
28d120ad609ebc9ae8cd97286bb3fb9c484bd8a179edcf0de1b96e4400b7a21b4db835d94fae3aaee84924bd46b84b84da12c538b39517362d805651e7aa3aef
SHA512
1616c00787a2e88ff3dc2aebe3a1b2ad428b5a8ea48fc94058b49c509f1c040b540b3f62551b16b3246d2fed58e0b33443cbdaaf1dfcba5a6eead5f3e8028029
+DIST tables-3.9.0.tar.gz 4682294 BLAKE2B
a4ff5a67c0376e90ca4f1f405878ead3bbb807b2fc972ba17a1026782adb473a26e15561ba13fb3c477defe3157ead20cf672d7150735fd5555821d1091d9b3f
SHA512
2f7e14af6a1759c16a3d79c6b26276aed49ddfcb60f8e157646f0e59f1b9abc405961dab48b55ddfaf046e69b39552a2d003d5ff7734edb195027f9cd6dab684
diff --git a/dev-python/tables/tables-3.9.0.ebuild
b/dev-python/tables/tables-3.9.0.ebuild
new file mode 100644
index 000000000000..ea12b00212a9
--- /dev/null
+++ b/dev-python/tables/tables-3.9.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 prefix pypi
+
+DESCRIPTION="Hierarchical datasets for Python"
+HOMEPAGE="
+ https://www.pytables.org/
+ https://github.com/PyTables/PyTables/
+ https://pypi.org/project/tables/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86
~amd64-linux ~x86-linux"
+IUSE="+cpudetection examples test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+ app-arch/bzip2:0=
+ app-arch/lz4:0=
+ >=app-arch/zstd-1.0.0:=
+ >=dev-libs/c-blosc-1.11.1:0=
+ dev-libs/c-blosc2:=
+ dev-libs/lzo:2=
+ >=dev-python/numpy-1.19.0[${PYTHON_USEDEP}]
+ >=sci-libs/hdf5-1.8.4:=
+"
+RDEPEND="
+ ${DEPEND}
+ >=dev-python/numexpr-2.6.2[${PYTHON_USEDEP}]
+ dev-python/packaging[${PYTHON_USEDEP}]
+ cpudetection? ( dev-python/py-cpuinfo[${PYTHON_USEDEP}] )
+"
+BDEPEND="
+ >=dev-python/cython-0.21[${PYTHON_USEDEP}]
+ virtual/pkgconfig
+ cpudetection? ( dev-python/py-cpuinfo[${PYTHON_USEDEP}] )
+ test? (
+ ${RDEPEND}
+ )
+"
+
+python_prepare_all() {
+ export PYTABLES_NO_EMBEDDED_LIBS=1
+ export USE_PKGCONFIG=TRUE
+
+ rm -r c-blosc/{blosc,internal-complibs} || die
+ sed -i -e '/blosc2/d' requirements.txt || die
+ hprefixify -w '/prefixes =/' setup.py
+ distutils-r1_python_prepare_all
+}
+
+python_test() {
+ cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+ "${EPYTHON}" tables/tests/test_all.py -v || die
+}
+
+python_install_all() {
+ distutils-r1_python_install_all
+
+ if use examples; then
+ dodoc -r contrib examples
+ docompress -x /usr/share/doc/${PF}/{contrib,examples}
+ fi
+}
