[gentoo-commits] repo/gentoo:master commit in: dev-python/pydantic/

[Michał Górny]

commit:     ace44bbeb83b0b6a6afbd4873af35bb0f8aaf455
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Sep 26 04:34:59 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Sep 26 04:42:15 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ace44bbe

dev-python/pydantic: Bump to 2.4.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pydantic/Manifest              |  1 +
 dev-python/pydantic/pydantic-2.4.0.ebuild | 54 +++++++++++++++++++++++++++++++
 2 files changed, 55 insertions(+)

diff --git a/dev-python/pydantic/Manifest b/dev-python/pydantic/Manifest
index aba534cf09fe..95fa91740d2e 100644
--- a/dev-python/pydantic/Manifest
+++ b/dev-python/pydantic/Manifest
@@ -1,2 +1,3 @@
 DIST pydantic-1.10.12.gh.tar.gz 766366 BLAKE2B 
b00885b86ef331f3f8531d1514f4e3e1ef10d009b35453c6d5a6295ecfe2d2b842f66c7ea2a79ca1d235d54fa38b42432e14804163f944c4455f05c06869815a
 SHA512 
413d433decfa3bb7173d6f4e6e06f746cfbf95f6d27c6a17098216ba81d64d7f8bb956cda195d0676559f96278f3800c77be53ecf46496ac009f130120642cc2
 DIST pydantic-2.3.0.tar.gz 623866 BLAKE2B 
77fe2d9ce385946e13ffeb5827c29bc7473667af6b53b7b3ec2432380dc792f9ce54b1cb5af68f0a548880516c763ac8c29b129d821da074b63a9a50f9ebc5c3
 SHA512 
19c9c066a69c8406ccf5537e62b4b5112a5cf1c32bb68498bb73b739c4525fe115348c4c4e5ef9c074dc46fd2b51ca09bcb1d4fa792dbdd2387e51aadae9e528
+DIST pydantic-2.4.0.tar.gz 651740 BLAKE2B 
03d849f7aaf40799a821d1c79e1a1eab30f61b6948bd6d9ec1f50ced7e42270025eb42de76e419f1dd4a99f5e73e53d9c7beedcdc637e542e3c29bb90ead35d8
 SHA512 
bc49390e83e0ccc1ff73a624ad6c7c40b889ea615a62cfdf24e6dad3d861863a7ce999749855c5817978793089e573db8aff8fab5bdc38f931ba1bcfa9106fe1

diff --git a/dev-python/pydantic/pydantic-2.4.0.ebuild 
b/dev-python/pydantic/pydantic-2.4.0.ebuild
new file mode 100644
index 000000000000..ac29ed9cb2fb
--- /dev/null
+++ b/dev-python/pydantic/pydantic-2.4.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Data parsing and validation using Python type hints"
+HOMEPAGE="
+       https://github.com/pydantic/pydantic/
+       https://pypi.org/project/pydantic/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
+
+RDEPEND="
+       >=dev-python/annotated-types-0.4.0[${PYTHON_USEDEP}]
+       =dev-python/pydantic-core-2.10*[${PYTHON_USEDEP}]
+       >=dev-python/typing-extensions-4.6.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+       >=dev-python/hatch-fancy-pypi-readme-22.5.0[${PYTHON_USEDEP}]
+       test? (
+               dev-python/dirty-equals[${PYTHON_USEDEP}]
+               >=dev-python/email-validator-2.0.0[${PYTHON_USEDEP}]
+               >=dev-python/Faker-18.13.0[${PYTHON_USEDEP}]
+               dev-python/pytest-mock[${PYTHON_USEDEP}]
+       )
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+       sed -i -e '/benchmark/d' pyproject.toml || die
+       distutils-r1_src_prepare
+}
+
+python_test() {
+       local EPYTEST_DESELECT=()
+       local EPYTEST_IGNORE=(
+               # require pytest-examples
+               tests/test_docs.py
+               # benchmarks
+               tests/benchmarks
+       )
+
+       local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+       epytest -p pytest_mock
+}