commit: ee72f651850489d7801b85a2fe30f4f7f4529293
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Sep 12 05:30:43 2023 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Sep 12 05:50:31 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ee72f651
dev-python/httpx: Bump to 0.25.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/httpx/Manifest | 1 +
dev-python/httpx/httpx-0.25.0.ebuild | 84 ++++++++++++++++++++++++++++++++++++
2 files changed, 85 insertions(+)
diff --git a/dev-python/httpx/Manifest b/dev-python/httpx/Manifest
index 480247117b33..f5968d203444 100644
--- a/dev-python/httpx/Manifest
+++ b/dev-python/httpx/Manifest
@@ -1 +1,2 @@
DIST httpx-0.24.1.gh.tar.gz 2168238 BLAKE2B
97a23e14635e8863b8f6fe80691ac4ae1706e0ce426d7cf9efa26ab54bb026d4a230a072bc16ec2f7edc08c768107ee00443626be1734d566bca8a190daa5ed0
SHA512
056741ef4e356f13adfcb66766489b39e79dbf4264d9780b8788c0934f7f3ff1a9b6bcb396a9f146e88315831f5399cebdd537c5a39c86b9b6bac3600d5560b6
+DIST httpx-0.25.0.gh.tar.gz 2169337 BLAKE2B
632a11917c35150be4aa9a946ae90493ba19b37697f97f82c36334a1004c57e9c256af54bcd0afbc2d5a67bd48f28c578285dd48473c8ccfd4b1c11e2c6bc069
SHA512
0be0f7ed53061d1dd9e0010d5a10adc6508bd49bf51e5ccf44f0aa2f54bdd067e3a7d1f37dfab80d3d374984aca2f20c346e46b8bc518826ce3371abc7291ee3
diff --git a/dev-python/httpx/httpx-0.25.0.ebuild
b/dev-python/httpx/httpx-0.25.0.ebuild
new file mode 100644
index 000000000000..c837a35550bc
--- /dev/null
+++ b/dev-python/httpx/httpx-0.25.0.ebuild
@@ -0,0 +1,84 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Fully-featured HTTP client which provides sync and async APIs"
+HOMEPAGE="
+ https://www.python-httpx.org/
+ https://github.com/encode/httpx/
+ https://pypi.org/project/httpx/
+"
+SRC_URI="
+ https://github.com/encode/httpx/archive/${PV}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+ dev-python/certifi[${PYTHON_USEDEP}]
+ <dev-python/httpcore-0.19[${PYTHON_USEDEP}]
+ >=dev-python/httpcore-0.18[${PYTHON_USEDEP}]
+ dev-python/idna[${PYTHON_USEDEP}]
+ dev-python/sniffio[${PYTHON_USEDEP}]
+ cli? (
+ =dev-python/click-8*[${PYTHON_USEDEP}]
+ =dev-python/pygments-2*[${PYTHON_USEDEP}]
+ dev-python/rich[${PYTHON_USEDEP}]
+ )
+"
+BDEPEND="
+ dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
+ test? (
+ app-arch/brotli[python,${PYTHON_USEDEP}]
+ dev-python/anyio[${PYTHON_USEDEP}]
+ dev-python/brotlicffi[${PYTHON_USEDEP}]
+ dev-python/chardet[${PYTHON_USEDEP}]
+ dev-python/cryptography[${PYTHON_USEDEP}]
+ dev-python/h2[${PYTHON_USEDEP}]
+ dev-python/socksio[${PYTHON_USEDEP}]
+ dev-python/trio[${PYTHON_USEDEP}]
+ dev-python/trustme[${PYTHON_USEDEP}]
+ dev-python/typing-extensions[${PYTHON_USEDEP}]
+ dev-python/uvicorn[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+ if ! use cli; then
+ sed -i -e '/^httpx =/d' pyproject.toml || die
+ fi
+ sed -i -e '/rich/s:,<14::' pyproject.toml || die
+ distutils-r1_src_prepare
+}
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # Internet
+ tests/client/test_proxies.py::test_async_proxy_close
+ tests/client/test_proxies.py::test_sync_proxy_close
+ )
+
+ use cli || EPYTEST_IGNORE+=(
+ tests/test_main.py
+ )
+
+ epytest
+}
+
+pkg_postinst() {
+ optfeature "HTTP/2 support" dev-python/h2
+ optfeature "SOCKS proxy support" dev-python/socksio
+ optfeature "Decoding for brotli compressed responses"
dev-python/brotlicffi
+}
