commit: fdb1f9a826bdc0ca40b830901facbff6461d17a2
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Aug 31 12:46:04 2023 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Aug 31 13:05:26 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fdb1f9a8
dev-python/kombu: Bump to 5.3.2
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/kombu/Manifest | 1 +
dev-python/kombu/kombu-5.3.2.ebuild | 82 +++++++++++++++++++++++++++++++++++++
2 files changed, 83 insertions(+)
diff --git a/dev-python/kombu/Manifest b/dev-python/kombu/Manifest
index 4c904a1b3549..6d592afbb61a 100644
--- a/dev-python/kombu/Manifest
+++ b/dev-python/kombu/Manifest
@@ -1 +1,2 @@
DIST kombu-5.3.1.tar.gz 434284 BLAKE2B
8df6d441d1229fe188584a34cab6d40250dc119a189215ab8ae8ec6660dc25e85166f48786b6b4c2abd56b4eb9e6fdc15a92372078d6f412b728ce45be0a81e5
SHA512
608e70cc66dc19915fd2b40c3b908f3147f60a7c971be1d8bf04f3a18f78999a7a140073ecc9f38ec9aec49c1ef0a6f01fb5f2d27d68fc68bd64aade1924edfa
+DIST kombu-5.3.2.tar.gz 431102 BLAKE2B
d617868a851382055acb44313f928aa2f1458700c29ee008f6eb7226010537bfbda6b306907e4901db1e51300abee969d574842a65f049f50507376103dbc670
SHA512
2960b3a2c8ef067d2cd82c8930ff00ffa8ce17d40a3b73597d274a289dec4ea24a2f250b19f4f02198be8cb5da067b9b45b7d07f4b15632ef96e9919bab739ea
diff --git a/dev-python/kombu/kombu-5.3.2.ebuild
b/dev-python/kombu/kombu-5.3.2.ebuild
new file mode 100644
index 000000000000..53ba0b0d0998
--- /dev/null
+++ b/dev-python/kombu/kombu-5.3.2.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="AMQP Messaging Framework for Python"
+HOMEPAGE="
+ https://github.com/celery/kombu/
+ https://pypi.org/project/kombu/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="examples"
+
+RDEPEND="
+ >=dev-python/py-amqp-5.1.1[${PYTHON_USEDEP}]
+ <dev-python/py-amqp-6.0.0[${PYTHON_USEDEP}]
+ dev-python/vine[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ app-arch/brotli[python,${PYTHON_USEDEP}]
+ >=dev-python/boto3-1.22.2[${PYTHON_USEDEP}]
+ dev-python/hypothesis[${PYTHON_USEDEP}]
+ >=dev-python/msgpack-0.3.0[${PYTHON_USEDEP}]
+ dev-python/pycurl[${PYTHON_USEDEP}]
+ >=dev-python/pymongo-4.1.1[${PYTHON_USEDEP}]
+ dev-python/pytest-freezegun[${PYTHON_USEDEP}]
+ dev-python/zstandard[${PYTHON_USEDEP}]
+ dev-python/pytz[${PYTHON_USEDEP}]
+ >=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
+ >=dev-python/redis-4.2.2[${PYTHON_USEDEP}]
+ dev-python/sqlalchemy[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+ dev-python/sphinx-celery
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # TODO
+
t/unit/transport/test_redis.py::test_Channel::test_connparams_health_check_interval_supported
+ )
+ local EPYTEST_IGNORE=(
+ # obsolete Pyro4
+ t/unit/transport/test_pyro.py
+ # unpackaged azure
+ t/unit/transport/test_azurestoragequeues.py
+ )
+
+ epytest
+}
+
+python_install_all() {
+ if use examples; then
+ docompress -x "/usr/share/doc/${PF}/examples"
+ docinto examples
+ dodoc -r examples/.
+ fi
+ distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+ optfeature "Amazon SQS backend" "dev-python/boto3 dev-python/pycurl"
+ optfeature "Etcd backend" dev-python/python-etcd
+ optfeature "MongoDB backend" dev-python/pymongo
+ optfeature "Redis backend" dev-python/redis
+ optfeature "sqlalchemy backend" dev-python/sqlalchemy
+ optfeature "yaml backend" dev-python/pyyaml
+ optfeature "MessagePack (de)serializer for Python" dev-python/msgpack
+ optfeature "brotli compression" "app-arch/brotli[python]"
+ optfeature "zstd compression" dev-python/zstandard
+}
