commit: 50ec6b06fccc685b3a6c0e6f302f673b6a598738
Author: Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Thu Aug 24 16:17:24 2023 +0000
Commit: Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Thu Aug 24 16:19:41 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=50ec6b06
net-dns/unbound: add 1.18.0_rc1
Signed-off-by: Sam James <sam <AT> gentoo.org>
net-dns/unbound/Manifest | 2 +
net-dns/unbound/unbound-1.18.0_rc1.ebuild | 214 ++++++++++++++++++++++++++++++
2 files changed, 216 insertions(+)
diff --git a/net-dns/unbound/Manifest b/net-dns/unbound/Manifest
index 4676299dc02b..8cb2c73995b7 100644
--- a/net-dns/unbound/Manifest
+++ b/net-dns/unbound/Manifest
@@ -4,3 +4,5 @@ DIST unbound-1.17.0.tar.gz 6235060 BLAKE2B
611c1b96ff84e6dd8f7a592135cc17f416cd8
DIST unbound-1.17.0.tar.gz.asc 833 BLAKE2B
8b77a16fa1287af7c12720cce0b45c1ab49f691a0516674d28009d5da8c71d5d56a9518e16fb752c2db58dc835223d55ff863bfc03971aa408eb0f65a65600bf
SHA512
e1567f088bdf0a96dbdcf365deccb72f42319b9b29510d5d9aefbe66df054446d3dcdfcc54826046af6e4f751aa518798b968685611b1b7f1860f66a96e32a57
DIST unbound-1.17.1.tar.gz 6244773 BLAKE2B
c2dec1608e28302da33ee72144bb8eb16cdff2e949e548f9ea5edb10b370e396085de641446b1f94daeb96a48a02f9361ebae69f72f3d449575fe3ce93dcdb5b
SHA512
10dd4c3aff77f1c0d19eb3c66956ed6ef1aae19e827d0b3259dc75d9de28dedd41862982a299e67ee07e17fb52058b4beee9d4b1d3bb0a3f633b9ba5b864d168
DIST unbound-1.17.1.tar.gz.asc 833 BLAKE2B
d78338da7ca590ef29403b24c271edf8f2eb026ad1f74ba9646f5539e41c6770e172133e1f1dbf1f31623d8f5828f78b8cc3a86bb72f1d6591967c98a994726b
SHA512
d663c2ebf9ba4420eb6cd351378d646ac4c9e88bd69913dc1c862a326e98329496a901c86b857f2c157c0401a289ff91e5ac83911477cb9894156c6d959b2b80
+DIST unbound-1.18.0rc1.tar.gz 6305462 BLAKE2B
52de64e7b2670d8288d34c6dc277e10dc3913d6ee372b88547c931170425b7f640303748f766c556571cd56842fa14a281f3e648660f1df313b52f242dc9fac6
SHA512
0069b82a10aed1abb18b97311b8e817af2f83c74bfe69d202b69facaea9145a9a474a88091eac6a33237aa35a8d016a19e370c49e32cf63ba19f1da5f6bd98eb
+DIST unbound-1.18.0rc1.tar.gz.asc 833 BLAKE2B
46e39bebcf2a41bfc91708cd31381fec0fce566618792ad7a4c5df0c5c2beff4e9cbd8f8234256a98a4444595d99759a247d55c026a0f46131636e1040b2f3f1
SHA512
86dda4b62facd17639c70b483f841fe84e2296fd450a9b6f5fbd2d99a2c0f1c0a5e4fd68142415e713d7b3be999714f54a51e407acbddfebf032a8ef1a1d1b9b
diff --git a/net-dns/unbound/unbound-1.18.0_rc1.ebuild
b/net-dns/unbound/unbound-1.18.0_rc1.ebuild
new file mode 100644
index 000000000000..d5c98a2f3951
--- /dev/null
+++ b/net-dns/unbound/unbound-1.18.0_rc1.ebuild
@@ -0,0 +1,214 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/unbound.net.asc
+inherit autotools flag-o-matic multilib-minimal python-single-r1 systemd
verify-sig
+
+MY_P=${PN}-${PV/_/}
+DESCRIPTION="A validating, recursive and caching DNS resolver"
+HOMEPAGE="https://unbound.net/ https://nlnetlabs.nl/projects/unbound/about/";
+SRC_URI="
+ https://nlnetlabs.nl/downloads/unbound/${MY_P}.tar.gz
+ verify-sig? ( https://nlnetlabs.nl/downloads/unbound/${MY_P}.tar.gz.asc
)
+"
+S="${WORKDIR}"/${MY_P}
+
+LICENSE="BSD GPL-2"
+SLOT="0/8" # ABI version of libunbound.so
+if [[ ${PV} != *_rc* ]] ; then
+ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~mips ~ppc ~ppc64 ~riscv ~x86"
+fi
+IUSE="debug dnscrypt dnstap +ecdsa ecs gost +http2 python redis selinux
static-libs systemd test +tfo threads"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+RESTRICT="!test? ( test )"
+
+# Note: expat is needed by executable only but the Makefile is custom
+# and doesn't make it possible to easily install the library without
+# the executables. MULTILIB_USEDEP may be dropped once build system
+# is fixed.
+DEPEND="
+ acct-group/unbound
+ acct-user/unbound
+ >=dev-libs/expat-2.1.0-r3[${MULTILIB_USEDEP}]
+ >=dev-libs/libevent-2.0.21:0=[${MULTILIB_USEDEP}]
+ >=dev-libs/openssl-1.0.1h-r2:0=[${MULTILIB_USEDEP}]
+ dnscrypt? ( dev-libs/libsodium:=[${MULTILIB_USEDEP}] )
+ dnstap? (
+ dev-libs/fstrm[${MULTILIB_USEDEP}]
+ >=dev-libs/protobuf-c-1.0.2-r1:=[${MULTILIB_USEDEP}]
+ )
+ ecdsa? (
+ dev-libs/openssl:0[-bindist(-)]
+ )
+ http2? ( net-libs/nghttp2:=[${MULTILIB_USEDEP}] )
+ python? ( ${PYTHON_DEPS} )
+ redis? ( dev-libs/hiredis:= )
+ systemd? ( sys-apps/systemd )
+"
+BDEPEND="
+ virtual/pkgconfig
+ python? ( dev-lang/swig )
+ test? (
+ net-libs/ldns[examples(-)]
+ dev-util/splint
+ app-text/wdiff
+ )
+ verify-sig? ( sec-keys/openpgp-keys-unbound )
+"
+RDEPEND="
+ ${DEPEND}
+ net-dns/dnssec-root
+ selinux? ( sec-policy/selinux-bind )
+"
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-1.5.7-trust-anchor-file.patch
+ "${FILESDIR}"/${PN}-1.6.3-pkg-config.patch
+ "${FILESDIR}"/${PN}-1.10.1-find-ar.patch
+)
+
+pkg_setup() {
+ use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+ default
+
+ eautoreconf
+
+ # Required for the python part
+ multilib_copy_sources
+}
+
+src_configure() {
+ [[ ${CHOST} == *-darwin* ]] || append-ldflags -Wl,-z,noexecstack
+ multilib-minimal_src_configure
+}
+
+multilib_src_configure() {
+ local myeconfargs=(
+ $(multilib_native_use_enable debug)
+ $(multilib_native_use_enable gost)
+ $(multilib_native_use_enable dnscrypt)
+ $(multilib_native_use_enable dnstap)
+ $(multilib_native_use_enable ecdsa)
+ $(multilib_native_use_enable ecs subnet)
+ $(multilib_native_use_enable redis cachedb)
+ $(multilib_native_use_enable static-libs static)
+ $(multilib_native_use_enable systemd)
+ $(multilib_native_use_with python pythonmodule)
+ $(multilib_native_use_with python pyunbound)
+ $(multilib_native_use_with threads pthreads)
+ $(multilib_native_use_with http2 libnghttp2)
+ $(multilib_native_use_enable tfo tfo-client)
+ $(multilib_native_use_enable tfo tfo-server)
+
+ --disable-flto
+ --disable-rpath
+ --enable-event-api
+ --enable-ipsecmod
+
+ --with-libevent="${ESYSROOT}"/usr
+ $(multilib_native_usex redis
--with-libhiredis="${ESYSROOT}/usr" --without-libhiredis)
+
+ --with-pidfile="${EPREFIX}"/run/unbound.pid
+ --with-rootkey-file="${EPREFIX}"/etc/dnssec/root-anchors.txt
+ --with-ssl="${ESYSROOT}"/usr
+ --with-libexpat="${ESYSROOT}"/usr
+
+ #
http://unbound.nlnetlabs.nl/pipermail/unbound-users/2011-April/001801.html
+ # $(use_enable debug lock-checks)
+ # $(use_enable debug alloc-checks)
+ # $(use_enable debug alloc-lite)
+ # $(use_enable debug alloc-nonregional)
+ )
+
+ econf "${myeconfargs[@]}"
+}
+
+multilib_src_install() {
+ emake DESTDIR="${D}" install
+ systemd_dounit contrib/unbound.service
+ systemd_dounit contrib/unbound.socket
+}
+
+multilib_src_install_all() {
+ use python && python_optimize
+
+ newinitd "${FILESDIR}"/unbound-r1.initd unbound
+ newconfd "${FILESDIR}"/unbound-r1.confd unbound
+
+ systemd_newunit "${FILESDIR}"/unbound_at.service "[email protected]"
+ systemd_dounit "${FILESDIR}"/unbound-anchor.service
+
+ dodoc doc/{README,CREDITS,TODO,Changelog,FEATURES}
+
+ # bug #315519
+ dodoc contrib/unbound_munin_
+
+ docinto selinux
+ dodoc contrib/selinux/*
+
+ exeinto /usr/share/${PN}
+ doexe contrib/update-anchor.sh
+
+ # Create space for auto-trust-anchor-file...
+ keepdir /etc/unbound/var
+ fowners root:unbound /etc/unbound/var
+ fperms 0770 /etc/unbound/var
+ # ... and point example config to it
+ sed -i \
+ -e '/#
auto-trust-anchor-file:/s,/etc/dnssec/root-anchors.txt,/etc/unbound/var/root-anchors.txt,'
\
+ "${ED}/etc/unbound/unbound.conf" \
+ || die
+
+ # Used to store cache data
+ keepdir /var/lib/${PN}
+ fowners root:unbound /var/lib/${PN}
+ fperms 0770 /var/lib/${PN}
+
+ find "${ED}" -name '*.la' -delete || die
+ if ! use static-libs ; then
+ find "${ED}" -name "*.a" -delete || die
+ fi
+}
+
+pkg_postinst() {
+ if [[ ! -f "${EROOT}/etc/unbound/unbound_control.key" ]]; then
+ einfo "Trying to create unbound control key ..."
+ if ! unbound-control-setup &>/dev/null ; then
+ ewarn "Failed to create unbound control key!"
+ fi
+ fi
+
+ if [[ ! -f "${EROOT}/etc/unbound/var/root-anchors.txt" ]]; then
+ einfo ""
+ einfo "If you want unbound to automatically update the
root-anchor file for DNSSEC validation"
+ einfo "set 'auto-trust-anchor-file:
${EROOT}/etc/unbound/var/root-anchors.txt' in ${EROOT}/etc/unbound/unbound.conf"
+ einfo "and run"
+ einfo ""
+ einfo " su -s /bin/sh -c '${EROOT}/usr/sbin/unbound-anchor -a
${EROOT}/etc/unbound/var/root-anchors.txt' unbound"
+ einfo ""
+ einfo "as root to create it initially before starting unbound
for the first time after enabling this."
+ einfo ""
+ fi
+
+ # Our user is not available on prefix
+ use prefix && return
+
+ local _perm_check_testfile=$(mktemp --dry-run
"${EPREFIX}"/etc/unbound/var/.pkg_postinst-perm-check.XXXXXXXXX)
+ su -s /bin/sh -c "touch ${_perm_check_testfile}" unbound &>/dev/null
+ if [[ $? -ne 0 ]]; then
+ ewarn "WARNING: unbound user cannot write to
\"${EPREFIX}/etc/unbound/var\"!"
+ ewarn "Run the following commands to restore default
permission:"
+ ewarn ""
+ ewarn " chown root:unbound ${EPREFIX}/etc/unbound/var"
+ ewarn " chmod 0770 ${EPREFIX}/etc/unbound/var"
+ else
+ # Cleanup -- no reason to die here!
+ rm -f "${_perm_check_testfile}"
+ fi
+}
