commit: 422d6ebc82393376a4e03926a49b85e721c26977
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Aug 22 03:08:29 2023 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Aug 22 03:08:29 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=422d6ebc
dev-python/tox: Bump to 4.10.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/tox/Manifest | 1 +
dev-python/tox/tox-4.10.0.ebuild | 84 ++++++++++++++++++++++++++++++++++++++++
2 files changed, 85 insertions(+)
diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index 9f1669b2786c..b9b281c2586f 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -1,4 +1,5 @@
DIST tox-3.28.0.gh.tar.gz 309472 BLAKE2B
9896411426f6aebb3efa468c01696ecc5f17ec3e67825672d0efc74c1b1468bc8b8d9c14b6177c181750ba4b9a5e77d616068dd83e21f5641acfc8e2a271cc1f
SHA512
64816754e6800661bb564c5c7d21c4139522d540a04fafe3c4591d596072d48d1cbe0ee2abee9c8faf3d5007774f5371431b5a7a8f49912bc879c7b168aab2ca
+DIST tox-4.10.0.tar.gz 174296 BLAKE2B
8369108d8fe4b64e0089bc9ea38c7d858b71fc2ea8d250ec8562fd408715d8461c5a212289f4a37c29e6a566088d821696cf869335a10c3ca5bd00e14e2b21d1
SHA512
c634fea5ab2989f2528107c75e7a1e4e328e8f5780d5fe6a3fda25e5c3d56e095db435cd5566231f3bc8e2d20d3b3e7a0e1b9be8de5a32e4b3602ed26f02f3b9
DIST tox-4.5.1.tar.gz 170137 BLAKE2B
38ab00eb577e66211db0ecf8931087a8c5a14f8219eb7ebecb7be9938221d1c680edc09a38a5c72b9ec63825d4cbb2d4fd9157a52aed8cdb0d22a1c1bbb70cba
SHA512
75d495d6dba134c3fe537fc190c1f428ff188ee67c346911c02ee151a8369425b22956eea52be5d434735e1590edce57b3487d5f4b277022bf8cfe8bf4660cf8
DIST tox-4.5.2.tar.gz 170336 BLAKE2B
1dcd2bbd7d153dbf0ac7bb48cdd1826d5fb915b7ef6d30a943138e06bb5d82d67db551f8c6d0342a5a81d91ddfd7da6ad8272fc016eaea27bcd4d69f6be9c605
SHA512
44a6c9821975205258402eaaa2010a0acde98190c77db0361da6c67d793de90871786fe2d78c6c9ee83100d7399e1eac857e2edaf94c64c81fb535ff871a363c
DIST tox-4.6.0.tar.gz 170401 BLAKE2B
ae9decd66677fc4e0422687dcd166a27df2f5617c4dbad1d99762542e0d7e1cbcb27892fce74217f85d3e93176475fa39a22a6dd99ccf141a12832862b436a02
SHA512
465db889630d1aa36329b41cf91537e7ca27fe0901b77b8b24d180ab854f2b7c062ae62bdcc931a33235b617e7c709d9290f0769b133b5cd40e398aea9a8d918
diff --git a/dev-python/tox/tox-4.10.0.ebuild b/dev-python/tox/tox-4.10.0.ebuild
new file mode 100644
index 000000000000..4a3b369c1b46
--- /dev/null
+++ b/dev-python/tox/tox-4.10.0.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{10..11} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+ https://tox.readthedocs.io/
+ https://github.com/tox-dev/tox/
+ https://pypi.org/project/tox/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390
~sparc ~x86"
+
+RDEPEND="
+ >=dev-python/cachetools-5.3.1[${PYTHON_USEDEP}]
+ >=dev-python/chardet-5.2[${PYTHON_USEDEP}]
+ >=dev-python/colorama-0.4.6[${PYTHON_USEDEP}]
+ >=dev-python/filelock-3.12.2[${PYTHON_USEDEP}]
+ >=dev-python/packaging-23.1[${PYTHON_USEDEP}]
+ >=dev-python/platformdirs-3.10[${PYTHON_USEDEP}]
+ >=dev-python/pluggy-1.2[${PYTHON_USEDEP}]
+ >=dev-python/pyproject-api-1.5.3[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+ ' 3.{9..10})
+ >=dev-python/virtualenv-20.24.3[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ >=dev-python/hatch-vcs-0.3[${PYTHON_USEDEP}]
+ test? (
+ >=dev-python/build-0.10[${PYTHON_USEDEP}]
+ >=dev-python/distlib-0.3.6[${PYTHON_USEDEP}]
+ >=dev-python/flaky-3.7[${PYTHON_USEDEP}]
+ >=dev-python/psutil-5.9.5[${PYTHON_USEDEP}]
+ >=dev-python/pytest-mock-3.11.1[${PYTHON_USEDEP}]
+ >=dev-python/pytest-xdist-3.3.1[${PYTHON_USEDEP}]
+ >=dev-python/re-assert-1.1[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/time-machine-2.10[${PYTHON_USEDEP}]
+ ' 'python*')
+ )
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+ # devpi_process is not packaged, and has lots of dependencies
+ cat > "${T}"/devpi_process.py <<-EOF || die
+ def IndexServer(*args, **kwargs): raise NotImplementedError()
+ EOF
+
+ local -x PYTHONPATH=${T}:${PYTHONPATH}
+ local EPYTEST_DESELECT=(
+ # Internet
+
tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+ )
+ local EPYTEST_IGNORE=(
+ # requires devpi*
+ tests/test_provision.py
+ )
+
+ [[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+
'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit-True-True]'
+
'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements-True-True]'
+
'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[constraints-True-True]'
+
'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit+requirements-True-True]'
+
'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_indirect-True-True]'
+
'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_constraints_indirect-True-True]'
+ )
+
+ epytest
+
+ # tox leaves a *humonogous* tempdir which easily leads to ENOSPC
+ # when running in parallel with other packages
+ rm -r "${T}"/pytest* || die
+}
