commit: 68bb3f1d83baac69fc704d578d2b7d52addce9ce
Author: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Sat Jul 22 12:27:29 2023 +0000
Commit: Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Sat Jul 22 12:55:52 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=68bb3f1d
dev-python/ijson: add 3.2.3
Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>
dev-python/ijson/Manifest | 1 +
dev-python/ijson/ijson-3.2.3.ebuild | 48 +++++++++++++++++++++++++++++++++++++
2 files changed, 49 insertions(+)
diff --git a/dev-python/ijson/Manifest b/dev-python/ijson/Manifest
index a048e298bb40..dbca4d4b0356 100644
--- a/dev-python/ijson/Manifest
+++ b/dev-python/ijson/Manifest
@@ -1 +1,2 @@
DIST ijson-3.2.2.gh.tar.gz 127965 BLAKE2B
2e20f7cc822406fe3e7eec99c3ef394e42d90b0b518226a7b8eb078763cb8317acb4a28934301116c32a2a9cc37403c2950b18232800485b1ea1206dace7ff23
SHA512
5935071bd0d3eecc39b3c30ca5cb2a959e4d455c57e36414d5c97ba71bbcf1a0b53c8b8afed7551a3a4ac4595294105566c9d7501b35832dd7e46a1bb2151287
+DIST ijson-3.2.3.gh.tar.gz 128266 BLAKE2B
6ee31eb2ded44898f613b1f86147f2a745b9a9c0dc35b9a33eae3fb2c207694ebc96b03a3a53373c8460256ae03cbf1c9eff13a197d88dd6dd28055d25beceaa
SHA512
cfdbf8efce072f00c4b3c61dd8b3f3164fd5ab757ac18783de992fe25e5ecbcdee92fe728f1345a37996625ab2ddfef6859dfdbdca7a7ece8f3d99750a9d60b0
diff --git a/dev-python/ijson/ijson-3.2.3.ebuild
b/dev-python/ijson/ijson-3.2.3.ebuild
new file mode 100644
index 000000000000..f4e7d80ec763
--- /dev/null
+++ b/dev-python/ijson/ijson-3.2.3.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1
+
+MY_P="${P//_p/.post}"
+DESCRIPTION="Iterative JSON parser with a Pythonic interface"
+HOMEPAGE="
+ https://github.com/ICRAR/ijson/
+ https://pypi.org/project/ijson/
+"
+SRC_URI="
+ https://github.com/ICRAR/${PN}/archive/v${PV/_p/.post}.tar.gz
+ -> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+
+DEPEND="
+ dev-libs/yajl
+"
+RDEPEND="
+ ${DEPEND}
+"
+
+distutils_enable_tests pytest
+
+python_compile() {
+ local -x IJSON_BUILD_YAJL2C=1
+ # The extension is broken on PyPy3, probably a bug in PyPy itself.
+ # https://github.com/ICRAR/ijson/issues/101
+ [[ ${EPYTHON} == pypy3 ]] && IJSON_BUILD_YAJL2C=0
+ distutils-r1_python_compile
+}
+
+python_test() {
+ rm -rf ijson || die
+ epytest
+}
