commit: 08be88cfe406b3950137f03fe871abd8eaa98699
Author: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Jul 11 18:24:25 2023 +0000
Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Jul 11 19:21:30 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=08be88cf
media-sound/kid3: add 3.9.4
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
media-sound/kid3/Manifest | 1 +
media-sound/kid3/kid3-3.9.4.ebuild | 100 +++++++++++++++++++++++++++++++++++++
2 files changed, 101 insertions(+)
diff --git a/media-sound/kid3/Manifest b/media-sound/kid3/Manifest
index 93466b386a18..434651b6a269 100644
--- a/media-sound/kid3/Manifest
+++ b/media-sound/kid3/Manifest
@@ -1 +1,2 @@
DIST kid3-3.9.3.tar.xz 1820640 BLAKE2B
ea030328d88f583e88959e7536f4e3e086354befc40395700fac8314a1e7c3da7a2f9a614ff9ad98491d9ec4d8b24ead05a2214b94f55786a5e493c1a585056c
SHA512
f40c7eaa186eb7d3163635286a8ad89bf6b29dce851b4fadc0814eec7759ed7fbac37e4596365bac4df93c5b655a7e943f8414e7c8f661b29aea7bde5367ed73
+DIST kid3-3.9.4.tar.xz 1834140 BLAKE2B
7a429b763bf4b0a275f9ba41dd0af314d564bcc8963093fefc10499e3e0e567d838515983b23cf9dfd5121adecce63b83d2179abca7904345d5b9f15a3c87aee
SHA512
28fe76ab6101202445d419c1a8a1bc4dfe31c9924fb6d28203ff9c0d2926b20e3a10a5f8b10e9193ff889e93100ce8bc6663baa29cfdecd5ec9dfb3445489348
diff --git a/media-sound/kid3/kid3-3.9.4.ebuild
b/media-sound/kid3/kid3-3.9.4.ebuild
new file mode 100644
index 000000000000..2bc1178b0bb1
--- /dev/null
+++ b/media-sound/kid3/kid3-3.9.4.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+inherit cmake kde.org python-any-r1 xdg
+
+DESCRIPTION="Simple tag editor based on Qt"
+HOMEPAGE="https://kid3.kde.org/";
+
+if [[ ${KDE_BUILD_TYPE} != live ]]; then
+ SRC_URI="mirror://kde/stable/${PN}/${PV}/${P}.tar.xz"
+ KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-2+"
+SLOT="5"
+IUSE="acoustid flac kde mp3 mp4 +mpris +taglib test vorbis"
+
+REQUIRED_USE="flac? ( vorbis )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ dev-qt/qtcore:5
+ dev-qt/qtdeclarative:5
+ dev-qt/qtgui:5
+ dev-qt/qtmultimedia:5
+ dev-qt/qtnetwork:5
+ dev-qt/qtwidgets:5
+ dev-qt/qtxml:5
+ sys-libs/readline:=
+ acoustid? (
+ media-libs/chromaprint:=
+ media-video/ffmpeg:=
+ )
+ flac? (
+ media-libs/flac:=[cxx]
+ media-libs/libvorbis
+ )
+ kde? (
+ kde-frameworks/kconfig:5
+ kde-frameworks/kconfigwidgets:5
+ kde-frameworks/kcoreaddons:5
+ kde-frameworks/kio:5
+ kde-frameworks/kwidgetsaddons:5
+ kde-frameworks/kxmlgui:5
+ )
+ mp3? ( media-libs/id3lib )
+ mp4? ( media-libs/libmp4v2 )
+ mpris? ( dev-qt/qtdbus:5 )
+ taglib? ( >=media-libs/taglib-1.9.1 )
+ vorbis? (
+ media-libs/libogg
+ media-libs/libvorbis
+ )
+"
+DEPEND="${RDEPEND}
+ test? ( dev-qt/qttest:5 )
+"
+BDEPEND="${PYTHON_DEPS}
+ dev-qt/linguist-tools:5
+ kde? ( kde-frameworks/extra-cmake-modules:5 )
+"
+
+pkg_setup() {
+ use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+ # overengineered upstream build system
+ cmake_src_prepare
+ # applies broken python hacks, bug #614950
+ cmake_comment_add_subdirectory doc
+
+ sed -e "/^ *find_package.*QT NAMES/s/Qt6 //" \
+ -i CMakeLists.txt || die # ensure Qt5 build
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DBUILD_WITH_QT6=OFF
+ -DWITH_CHROMAPRINT=$(usex acoustid)
+ -DWITH_DBUS=$(usex mpris)
+ -DWITH_FLAC=$(usex flac)
+ -DWITH_ID3LIB=$(usex mp3)
+ -DWITH_MP4V2=$(usex mp4)
+ -DWITH_TAGLIB=$(usex taglib)
+ -DBUILD_TESTING=$(usex test)
+ -DWITH_VORBIS=$(usex vorbis)
+ )
+
+ if use kde ; then
+ mycmakeargs+=( "-DWITH_APPS=KDE;CLI" )
+ else
+ mycmakeargs+=( "-DWITH_APPS=Qt;CLI" )
+ fi
+
+ cmake_src_configure
+}
