commit: 90f2d412a5a9e60006d48ff02fffc6dfd484f018
Author: Marek Szuba <marecki <AT> gentoo <DOT> org>
AuthorDate: Sat Jul 8 23:08:33 2023 +0000
Commit: Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Sat Jul 8 23:39:24 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=90f2d412
app-misc/gramps: add 5.1.6
Signed-off-by: Marek Szuba <marecki <AT> gentoo.org>
app-misc/gramps/Manifest | 1 +
app-misc/gramps/gramps-5.1.6.ebuild | 104 ++++++++++++++++++++++++++++++++++++
2 files changed, 105 insertions(+)
diff --git a/app-misc/gramps/Manifest b/app-misc/gramps/Manifest
index c250581b7256..d21cf246dbc7 100644
--- a/app-misc/gramps/Manifest
+++ b/app-misc/gramps/Manifest
@@ -1 +1,2 @@
DIST gramps-5.1.5.tar.gz 17425167 BLAKE2B
f07fcb84c28f1def84c5568da6ac38a78def8657a0ee010163cb7e0899dd94ebb1c851e2c9d207fd9725754363ac7243a66f0de6e0d9708270d2d43c90485212
SHA512
8e36e8da7cfb41cc0c77881993cfc212a15bf9775dad3c8be131889b70360117e023b6837b91dad28fc03198080290a08c8089856c753246ff14c7fc3bca38be
+DIST gramps-5.1.6.tar.gz 17429153 BLAKE2B
fe94d80ff209e1f27ec1cfa533e916514336c1d367435e0a9da4b8309efbc9c047302a67ec24e28237eaead67ff63e76bd1384ac1e3df10e08ae98aca126566b
SHA512
419bbfa54ca3bf33e71fd579c84a56eebe4afc78ccd50c23b2d62869684709ccbf373e8da0e65835d9fc21a29d2d144597d6cf8c425e14c91574535d4b1ab64d
diff --git a/app-misc/gramps/gramps-5.1.6.ebuild
b/app-misc/gramps/gramps-5.1.6.ebuild
new file mode 100644
index 000000000000..35795730b469
--- /dev/null
+++ b/app-misc/gramps/gramps-5.1.6.ebuild
@@ -0,0 +1,104 @@
+# Copyright 2001-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_SINGLE_IMPL=1
+# Sadly, PEP-517 mode breaks both the test suite and the installation of some
of the data files
+DISTUTILS_USE_SETUPTOOLS=no
+PYTHON_COMPAT=( python3_{10..11} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1 xdg-utils
+
+DESCRIPTION="Community genealogy program aiming to be both intuitive and
feature-complete"
+HOMEPAGE="https://gramps-project.org/";
+SRC_URI="https://github.com/gramps-project/${PN}/archive/v${PV}.tar.gz
+ -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="exif geo postscript +rcs +reports spell test"
+
+# Some of the tests fail unless the deprecated BerkeleyDB back-end is enabled.
+RESTRICT="test"
+
+RDEPEND="
+ $(python_gen_cond_dep '
+ dev-python/pycairo[${PYTHON_USEDEP}]
+ >=dev-python/pygobject-3.12:3[cairo,${PYTHON_USEDEP}]
+ dev-python/pyicu[${PYTHON_USEDEP}]
+ exif? ( >=media-libs/gexiv2-0.5[${PYTHON_USEDEP},introspection]
)
+ ')
+ gnome-base/librsvg:2
+ >x11-libs/gtk+-3.14.8:3[introspection]
+ x11-libs/pango[introspection]
+ x11-misc/xdg-utils
+ geo? ( >=sci-geosciences/osm-gps-map-1.1.0 )
+ spell? ( app-text/gtkspell:3[introspection] )
+ rcs? ( dev-vcs/rcs )
+ reports? ( media-gfx/graphviz[postscript?] )
+"
+BDEPEND="test? (
+ $(python_gen_cond_dep '
+ dev-python/jsonschema[${PYTHON_USEDEP}]
+ dev-python/lxml[${PYTHON_USEDEP}]
+ ')
+)"
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-5.1.3-test_locale.patch
+)
+
+distutils_enable_tests setup.py
+
+python_prepare_all() {
+ # Install documentation to the proper location. This can't be done
+ # easily with a patch because we substitute in the ${PF} variable,
+ # and that changes with every revision.
+ sed -i "s:share/doc/gramps:share/doc/${PF}:g" setup.py || die
+ distutils-r1_python_prepare_all
+}
+
+python_configure_all() {
+ DISTUTILS_ARGS=(
+ --resourcepath=/usr/share
+ --no-compress-manpages
+ )
+}
+
+python_test() {
+ # Gramps builds just fine out of tree but it confuses its test suite.
+ # The following at least lets the tests run properly in legacy mode.
+ rm -rf "${S}/build" && ln -s "${BUILD_DIR}" "${S}"/build || \
+ die "Failed to symlink build directory to source directory"
+
+ # Set a sane default locale for the tests which do not explicitly set
one.
+ local -x LC_ALL=C.UTF-8
+
+ esetup.py test || die
+}
+
+# Ugly hack to work around Bug #717922
+python_install() {
+ local DISTUTILS_ARGS=(
+ --resourcepath=/usr/share
+ --no-compress-manpages
+ build
+ )
+ distutils-r1_python_install
+ echo -n "${EPREFIX}/usr/share" >
"${D}$(python_get_sitedir)/gramps/gen/utils/resource-path" || die
+}
+
+pkg_postinst() {
+ xdg_desktop_database_update
+ xdg_icon_cache_update
+ xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+ xdg_desktop_database_update
+ xdg_icon_cache_update
+ xdg_mimeinfo_database_update
+}
