commit: 63c92e846af3afc3ec3704ec3716eac25fa7bdab
Author: Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
AuthorDate: Tue Jun 6 17:05:40 2023 +0000
Commit: Anna Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
CommitDate: Tue Jun 6 18:00:37 2023 +0000
URL: https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=63c92e84
app-text/OCRmyPDF: add 14.2.1
Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq.in>
app-text/OCRmyPDF/Manifest | 1 +
app-text/OCRmyPDF/OCRmyPDF-14.2.1.ebuild | 77 ++++++++++++++++++++++++++++++++
2 files changed, 78 insertions(+)
diff --git a/app-text/OCRmyPDF/Manifest b/app-text/OCRmyPDF/Manifest
index f5c8a89e7..b0e2af3e6 100644
--- a/app-text/OCRmyPDF/Manifest
+++ b/app-text/OCRmyPDF/Manifest
@@ -1 +1,2 @@
DIST OCRmyPDF-14.1.0.tar.gz 6508692 BLAKE2B
cb9eb2a782c0640d149047190c5d92a1cf6c183346ae34f0663c26b5d5ddba9bd7c1796c390d805c29443ef04e2d2c1cf7228469d4d3ee4fc0bf7e67214b084d
SHA512
f68049e14416eb9b4a28436935c70b674e8dbe1c529d94c3a0b95e1d56f7b8e785ca29daf1183323510786bb04b2b9e963ff9021d3acab73aff5ff88393eb8d3
+DIST OCRmyPDF-14.2.1.tar.gz 6510184 BLAKE2B
db107170e5c7c8caac2518c9ec8b8fd24e3362ab257f9d2c601c90f2dd614ba08fdd389561def151188a72493c7cd7ae2e24d6cf20458661470ad4f8505ab17a
SHA512
68a834325f2154e8fc8eccc1276dfca7fa04a44c5144f1d20b331bbf91625d5826f13652c05a433390b5cc5f9a821797ab0d8e7b0c05bcf5f7350b2077ed48ff
diff --git a/app-text/OCRmyPDF/OCRmyPDF-14.2.1.ebuild
b/app-text/OCRmyPDF/OCRmyPDF-14.2.1.ebuild
new file mode 100644
index 000000000..59dfdfe0a
--- /dev/null
+++ b/app-text/OCRmyPDF/OCRmyPDF-14.2.1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 2020-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 optfeature shell-completion
+
+DESCRIPTION="OCRmyPDF adds an OCR text layer to scanned PDF files"
+HOMEPAGE="https://github.com/ocrmypdf/OCRmyPDF";
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="CC-BY-SA-2.5 CC-BY-SA-4.0 MIT MPL-2.0 ZLIB"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+ >=app-text/ghostscript-gpl-9.50
+ >=app-text/pdfminer-20201018[${PYTHON_USEDEP}]
+ >=app-text/tesseract-4.1.1[jpeg,tiff,png,webp]
+ >=dev-python/coloredlogs-14.0[${PYTHON_USEDEP}]
+ >=dev-python/deprecation-2.1.0[${PYTHON_USEDEP}]
+ >=dev-python/packaging-20[${PYTHON_USEDEP}]
+ >dev-python/pikepdf-5.0.1[${PYTHON_USEDEP}]
+ >=dev-python/pillow-8.2.0[lcms,${PYTHON_USEDEP}]
+ >=dev-python/pluggy-0.13.0[${PYTHON_USEDEP}]
+ >=dev-python/reportlab-3.5.66[${PYTHON_USEDEP}]
+ >=dev-python/tqdm-4[${PYTHON_USEDEP}]
+ >=media-gfx/img2pdf-0.3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ dev-python/setuptools-scm[${PYTHON_USEDEP}]
+ test? (
+ app-text/tessdata_fast[l10n_de,l10n_en]
+ >=app-text/unpaper-6.1
+ dev-python/hypothesis[${PYTHON_USEDEP}]
+ dev-python/pytest-helpers-namespace[${PYTHON_USEDEP}]
+ >=dev-python/python-xmp-toolkit-2.0.1[${PYTHON_USEDEP}]
+ media-libs/exempi:2
+ >=media-libs/jbig2enc-0.29
+ media-libs/libxmp
+ >=media-gfx/pngquant-2.5
+ )
+"
+
+EPYTEST_IGNORE=(
+ # useless test
+ tests/test_completion.py
+)
+
+distutils_enable_tests pytest
+
+distutils_enable_sphinx docs \
+ dev-python/sphinx-issues \
+ dev-python/sphinx-rtd-theme
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+src_prepare() {
+ distutils-r1_src_prepare
+ sed -e "/-n auto/d" -i pyproject.toml || die
+}
+
+src_install() {
+ distutils-r1_src_install
+ newbashcomp misc/completion/ocrmypdf.bash "${PN,,}"
+
+ dofishcomp misc/completion/ocrmypdf.fish
+}
+
+pkg_postinst() {
+ optfeature "JBIG2 optimization support" media-libs/jbig2enc
+ optfeature "image cleaning support" app-text/unpaper
+ optfeature "PNG optimization support" media-gfx/pngquant
+}
