commit: 9d8e220ce1b1213e60a26c617c9bfa7ca7edbf1d
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu May 11 16:00:14 2023 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu May 11 17:58:01 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9d8e220c
dev-python/mypy: Bump to 1.3.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/mypy/Manifest | 1 +
dev-python/mypy/mypy-1.3.0.ebuild | 67 +++++++++++++++++++++++++++++++++++++++
2 files changed, 68 insertions(+)
diff --git a/dev-python/mypy/Manifest b/dev-python/mypy/Manifest
index cfe0d7da169e..ebd9c51bb6ee 100644
--- a/dev-python/mypy/Manifest
+++ b/dev-python/mypy/Manifest
@@ -1 +1,2 @@
DIST mypy-1.2.0.gh.tar.gz 2815323 BLAKE2B
d5cdc1bb31d797c49daf5ea0427fdceaf59a131d02a687dc5e72796a03824bff923c6942c6f01ca44025fe153fea02fdaee3959317fda0d4c562c45638e8c380
SHA512
5bee7a5ae4ac608cb3b3855c0ad100ea6ba512900aa557a153e1ae5f8e779125a8ef61103a81a9584b0585a6d4eea78c3585af61fa62986f984ac2b63e6b89b6
+DIST mypy-1.3.0.gh.tar.gz 2823529 BLAKE2B
0f1b4b6178ef9308fa6aeda494092229ebe07095c032b83fffd28be851608a3dc92ae4924ea64d87318155bf9d99bf16e17e2603f39fc915463455db520d6138
SHA512
1ab0e667bd019ea6804c70c775c2bfb454231ca2426b2b78b5c91672f7f20fd1195ee481a688d9b6238c3b5f6dc9a7aa5466c7405ce71dd6f78c489a43670fc0
diff --git a/dev-python/mypy/mypy-1.3.0.ebuild
b/dev-python/mypy/mypy-1.3.0.ebuild
new file mode 100644
index 000000000000..3ff1a529547c
--- /dev/null
+++ b/dev-python/mypy/mypy-1.3.0.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Optional static typing for Python"
+HOMEPAGE="
+ https://www.mypy-lang.org/
+ https://github.com/python/mypy/
+ https://pypi.org/project/mypy/
+"
+SRC_URI="
+ https://github.com/python/mypy/archive/v${PV}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86"
+
+# stubgen collides with this package: https://bugs.gentoo.org/585594
+RDEPEND="
+ !dev-util/stubgen
+ >=dev-python/psutil-4[${PYTHON_USEDEP}]
+ >=dev-python/typed-ast-1.4.0[${PYTHON_USEDEP}]
+ <dev-python/typed-ast-2[${PYTHON_USEDEP}]
+ >=dev-python/typing-extensions-3.10[${PYTHON_USEDEP}]
+ >=dev-python/mypy_extensions-1.0.0[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ dev-python/tomli[${PYTHON_USEDEP}]
+ ' pypy3 python3_{8..10})
+"
+BDEPEND="
+ test? (
+ >=dev-python/attrs-18.0[${PYTHON_USEDEP}]
+ >=dev-python/filelock-3.3.0[${PYTHON_USEDEP}]
+ >=dev-python/lxml-4.4.0[${PYTHON_USEDEP}]
+ >=dev-python/pytest-6.1.0[${PYTHON_USEDEP}]
+ >=dev-python/pytest-xdist-1.18[${PYTHON_USEDEP}]
+ >=dev-python/py-1.5.2[${PYTHON_USEDEP}]
+ >=dev-python/typed-ast-1.4.0[${PYTHON_USEDEP}]
+ >=dev-python/virtualenv-16.0.0[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_sphinx docs/source \
+ dev-python/furo
+distutils_enable_tests pytest
+
+# this requires packaging a lot of type stubs
+export MYPY_USE_MYPYC=0
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # the majority of them require Internet (via pip)
+ mypy/test/testpep561.py
+ )
+ # Some mypy/test/testcmdline.py::PythonCmdlineSuite tests
+ # fail with high COLUMNS values
+ local -x COLUMNS=80
+ epytest -n "$(makeopts_jobs)"
+}
