commit: 68e77ff0aaa1d29a3891684e4abef6911ff4bd71
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Apr 11 16:40:27 2023 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Apr 11 17:25:36 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=68e77ff0
dev-python/httpx: Bump to 0.24.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/httpx/Manifest | 1 +
dev-python/httpx/httpx-0.24.0.ebuild | 82 ++++++++++++++++++++++++++++++++++++
2 files changed, 83 insertions(+)
diff --git a/dev-python/httpx/Manifest b/dev-python/httpx/Manifest
index 5ab15debe0a2..6c08d80a66a7 100644
--- a/dev-python/httpx/Manifest
+++ b/dev-python/httpx/Manifest
@@ -1 +1,2 @@
DIST httpx-0.23.3.gh.tar.gz 2163546 BLAKE2B
96903669ca9d22cbb85bd322a407aa2b6799b5f8bfce277a763248ac2d65d60b85c0c71f24af99098eaca585f8136d9db687d6d0ab8cf2347d3c6fe28222def0
SHA512
d4f051578de63e677492727c466d44858c31d1b85441621667d4aeaec5cd2ebd0257a1db115f1b4d77d563359dfc81c2cd1221c0cc66c891b461fa1f4e8a5aee
+DIST httpx-0.24.0.gh.tar.gz 2167376 BLAKE2B
261298dcb65b22c4b188b03a7f650ed2527c8dd3b70d2d21f38f199ff465b107cf034140b349961da19894abdb287ceafb7997dbcc8a4e89b0e319b21121d024
SHA512
52ccd285cee6032c604160484520522957fdfb4735385bf68d594574b4525b89ea007eb71a653cdf01381610f350c8120c36422e0fda91c39dad437f5cb3f486
diff --git a/dev-python/httpx/httpx-0.24.0.ebuild
b/dev-python/httpx/httpx-0.24.0.ebuild
new file mode 100644
index 000000000000..d260ae5f49cd
--- /dev/null
+++ b/dev-python/httpx/httpx-0.24.0.ebuild
@@ -0,0 +1,82 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 python3_{9..11} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Fully-featured HTTP client which provides sync and async APIs"
+HOMEPAGE="
+ https://www.python-httpx.org/
+ https://github.com/encode/httpx/
+ https://pypi.org/project/httpx/
+"
+SRC_URI="
+ https://github.com/encode/httpx/archive/${PV}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+ dev-python/certifi[${PYTHON_USEDEP}]
+ <dev-python/httpcore-0.18[${PYTHON_USEDEP}]
+ >=dev-python/httpcore-0.15[${PYTHON_USEDEP}]
+ dev-python/idna[${PYTHON_USEDEP}]
+ dev-python/sniffio[${PYTHON_USEDEP}]
+ cli? (
+ =dev-python/click-8*[${PYTHON_USEDEP}]
+ =dev-python/pygments-2*[${PYTHON_USEDEP}]
+ dev-python/rich[${PYTHON_USEDEP}]
+ )
+"
+BDEPEND="
+ dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
+ test? (
+ dev-python/anyio[${PYTHON_USEDEP}]
+ dev-python/brotlicffi[${PYTHON_USEDEP}]
+ dev-python/cryptography[${PYTHON_USEDEP}]
+ dev-python/h2[${PYTHON_USEDEP}]
+ dev-python/socksio[${PYTHON_USEDEP}]
+ dev-python/trio[${PYTHON_USEDEP}]
+ dev-python/trustme[${PYTHON_USEDEP}]
+ dev-python/typing-extensions[${PYTHON_USEDEP}]
+ dev-python/uvicorn[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+ if ! use cli; then
+ sed -i -e '/^httpx =/d' pyproject.toml || die
+ fi
+ sed -i -e '/rich/s:,<14::' pyproject.toml || die
+ distutils-r1_src_prepare
+}
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # Internet
+ tests/client/test_proxies.py::test_async_proxy_close
+ tests/client/test_proxies.py::test_sync_proxy_close
+ )
+
+ use cli || EPYTEST_IGNORE+=(
+ tests/test_main.py
+ )
+
+ epytest
+}
+
+pkg_postinst() {
+ optfeature "HTTP/2 support" dev-python/h2
+ optfeature "SOCKS proxy support" dev-python/socksio
+ optfeature "Decoding for brotli compressed responses"
dev-python/brotlicffi
+}
