commit: 6608478f01f481d81c201e4b4eedea64983075c5
Author: David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Sat Mar 25 11:02:44 2023 +0000
Commit: David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Sat Mar 25 11:02:44 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6608478f
dev-libs/link-grammar: add 5.12.3
Signed-off-by: David Seifert <soap <AT> gentoo.org>
dev-libs/link-grammar/Manifest | 1 +
dev-libs/link-grammar/link-grammar-5.12.3.ebuild | 109 +++++++++++++++++++++++
2 files changed, 110 insertions(+)
diff --git a/dev-libs/link-grammar/Manifest b/dev-libs/link-grammar/Manifest
index ca6af74cb118..aaf24a22f083 100644
--- a/dev-libs/link-grammar/Manifest
+++ b/dev-libs/link-grammar/Manifest
@@ -1 +1,2 @@
DIST link-grammar-5.12.0.tar.gz 4688144 BLAKE2B
3ab74bcd23118c1d933895ac5ac8f042448f173234db1528de496e2f4aa88cd9b96d4783e54584f05d8af5bb835fee1f62f039ed883e2b24511198526d334dbd
SHA512
1938e53a2d8bdb5d0c352e9bb7108b280d3c4da890f540f41bdc257eea1ea6de5712f99602fc0f4187654540e1142b5216efb2a8c9957f32ce0dec86d85ec3cb
+DIST link-grammar-5.12.3.tar.gz 4704751 BLAKE2B
a7f0fe39c51ed26ea764d583b38b21cfce6e596c6cd94db6ba47b3606a2b6cd9e56bd6fedeb104dbb345baedae3e144af96999739dda9daa9a9e5886bd98d2f4
SHA512
e0fdb78ec03042119011afea005a62829317fd0bc20afcd94e3f234c9c5252ed9c57d717b75368ac4a63dd8493bd86f551870299925f3b9b95b11915f48d8abe
diff --git a/dev-libs/link-grammar/link-grammar-5.12.3.ebuild
b/dev-libs/link-grammar/link-grammar-5.12.3.ebuild
new file mode 100644
index 000000000000..8a81b91fda91
--- /dev/null
+++ b/dev-libs/link-grammar/link-grammar-5.12.3.ebuild
@@ -0,0 +1,109 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit autotools python-r1 out-of-source
+
+DESCRIPTION="A Syntactic English parser"
+HOMEPAGE="https://www.abisource.com/projects/link-grammar/
https://www.link.cs.cmu.edu/link/";
+SRC_URI="https://www.abisource.com/downloads/${PN}/${PV}/${P}.tar.gz";
+
+LICENSE="LGPL-2.1"
+SLOT="0/5"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="aspell +hunspell python"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# XXX: sqlite is automagic
+# Does not build with >=sci-mathematics/minisat-2, bug #593662
+RDEPEND="
+ dev-db/sqlite:3
+ dev-libs/libpcre2:=
+ aspell? ( app-text/aspell )
+ hunspell? ( app-text/hunspell )
+ python? ( ${PYTHON_DEPS} )
+ !sci-mathematics/minisat"
+DEPEND="${RDEPEND}"
+BDEPEND="
+ dev-lang/swig:0
+ sys-devel/autoconf-archive
+ virtual/pkgconfig"
+
+pkg_setup() {
+ if use aspell && use hunspell; then
+ ewarn "You have enabled 'aspell' and 'hunspell' support, but
both cannot coexist,"
+ ewarn "only hunspell will be built. Press Ctrl+C and set only
'aspell' USE flag if"
+ ewarn "you want aspell support."
+ fi
+}
+
+src_prepare() {
+ default
+ eautoreconf
+}
+
+my_src_configure() {
+ local myconf=(
+ --disable-maintainer-mode
+ --disable-editline
+ # java is hopelessly broken, invokes maven at build time (bug
#806157)
+ --disable-java-bindings
+ --disable-perl-bindings
+ --disable-sat-solver
+ --with-regexlib=pcre2
+ $(use_enable aspell)
+ $(use_enable hunspell)
+ $(usev hunspell
--with-hunspell-dictdir="${EPREFIX}"/usr/share/myspell)
+ )
+
+ econf \
+ --disable-python-bindings \
+ "${myconf[@]}"
+
+ if use python; then
+ python_configure() {
+ econf \
+ --enable-python-bindings \
+ "${myconf[@]}"
+ }
+ python_foreach_impl run_in_build_dir python_configure
+ fi
+}
+
+my_src_compile() {
+ local -x MAIN_BUILD_DIR="${BUILD_DIR}"
+ default
+
+ if use python; then
+ python_compile() {
+ emake -C bindings/python \
+ VPATH="${S}:${MAIN_BUILD_DIR}" \
+
_clinkgrammar_la_DEPENDENCIES="${MAIN_BUILD_DIR}"/link-grammar/liblink-grammar.la
\
+
_clinkgrammar_la_LIBADD="${MAIN_BUILD_DIR}"/link-grammar/liblink-grammar.la
+ }
+ python_foreach_impl run_in_build_dir python_compile
+ fi
+}
+
+my_src_install() {
+ local -x MAIN_BUILD_DIR="${BUILD_DIR}"
+ default
+
+ if use python; then
+ python_install() {
+ emake -C bindings/python \
+ VPATH="${S}:${MAIN_BUILD_DIR}" \
+
_clinkgrammar_la_DEPENDENCIES="${MAIN_BUILD_DIR}"/link-grammar/liblink-grammar.la
\
+
_clinkgrammar_la_LIBADD="${MAIN_BUILD_DIR}"/link-grammar/liblink-grammar.la \
+ DESTDIR="${D}" \
+ install
+ }
+ python_foreach_impl run_in_build_dir python_install
+ fi
+
+ # no static archives
+ find "${ED}" -name '*.la' -delete || die
+}
