[gentoo-commits] repo/gentoo:master commit in: dev-python/django-cacheops/

[Michał Górny]

commit:     782591dc4ba427aa25ec7874cadcf0753b3675e9
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Feb 23 05:39:43 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Feb 23 06:18:06 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=782591dc

dev-python/django-cacheops: Bump to 6.2

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/django-cacheops/Manifest                |  1 +
 .../django-cacheops/django-cacheops-6.2.ebuild     | 72 ++++++++++++++++++++++
 2 files changed, 73 insertions(+)

diff --git a/dev-python/django-cacheops/Manifest 
b/dev-python/django-cacheops/Manifest
index 3deefef610a6..f8370f4d98c3 100644
--- a/dev-python/django-cacheops/Manifest
+++ b/dev-python/django-cacheops/Manifest
@@ -1 +1,2 @@
 DIST django-cacheops-6.1.gh.tar.gz 52972 BLAKE2B 
bdcd045912100ebdfdfd9add23b0df634b029cc2ffe41c351176e327f1e21c90457cfca9e45348dddce60e39fee5c431428ff7f2c954194e4c06c8bc09d78945
 SHA512 
43dcd4f302afee1acf73125aae7c2e2eece560cc6f07f3374391ac54e0438fd59b80a24e65f52bd7aa4978fd8a428939a8d607c7aa4b25f47d68373cfc12772f
+DIST django-cacheops-6.2.gh.tar.gz 55279 BLAKE2B 
9fa05d6701e0cb705a012714f4ef5b98e6a56fe916033567e71256f2425ef844451d98cf7b2dd78023a680e19eab52b2f8cc4100ccf037e3d2e33f814eb47ead
 SHA512 
48e51de2fd13c16a97085b9c6e61833f6c8b0252a0ede9e8a4beaa973e509fe34731804830b0d80926c0ae0f75aef939b7b21368de7ac17053bb1c10c0a7d104

diff --git a/dev-python/django-cacheops/django-cacheops-6.2.ebuild 
b/dev-python/django-cacheops/django-cacheops-6.2.ebuild
new file mode 100644
index 000000000000..9e64deb2d434
--- /dev/null
+++ b/dev-python/django-cacheops/django-cacheops-6.2.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="ORM cache with automatic granular event-driven invalidation for 
Django"
+HOMEPAGE="
+       https://github.com/Suor/django-cacheops/
+       https://pypi.org/project/django-cacheops/
+"
+SRC_URI="
+       https://github.com/Suor/django-cacheops/archive/${PV}.tar.gz
+               -> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+       >=dev-python/django-1.8[${PYTHON_USEDEP}]
+       >=dev-python/redis-2.9.1[${PYTHON_USEDEP}]
+       >=dev-python/funcy-1.8[${PYTHON_USEDEP}]
+       >=dev-python/six-1.4.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+       test? (
+               ${RDEPEND}
+               dev-db/redis
+               dev-python/dill[${PYTHON_USEDEP}]
+               dev-python/mock[${PYTHON_USEDEP}]
+       )
+"
+
+src_prepare() {
+       # Remove test dependent on unpackaged before_after
+       sed -e 's/test_lock/_&/' -i tests/test_extras.py || die
+       distutils-r1_src_prepare
+}
+
+python_test() {
+       local -x DJANGO_SETTINGS_MODULE=tests.settings
+       local -x PYTHONPATH=.
+       django-admin test -v 2 || die
+}
+
+src_test() {
+       local redis_pid="${T}"/redis.pid
+       local redis_port=6379
+
+       einfo "Spawning Redis"
+       einfo "NOTE: Port ${redis_port} must be free"
+       "${EPREFIX}"/usr/sbin/redis-server - <<-EOF || die
+               daemonize yes
+               pidfile ${redis_pid}
+               port ${redis_port}
+               bind 127.0.0.1
+       EOF
+
+       # Run the tests
+       distutils-r1_src_test
+
+       # Clean up afterwards
+       kill "$(<"${redis_pid}")" || die
+}