commit: 87d64b1fc47078e8c9c5e7363122d4da97003125
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Feb 14 15:34:06 2023 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Feb 14 16:23:06 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=87d64b1f
dev-python/django: Bump to 3.2.18
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/django/Manifest | 2 +
dev-python/django/django-3.2.18.ebuild | 109 +++++++++++++++++++++++++++++++++
2 files changed, 111 insertions(+)
diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index 818ab848c213..43dd8400ab15 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -1,5 +1,7 @@
DIST Django-3.2.17.checksum.txt 2556 BLAKE2B
f8c7d219a512ecd683f29f1b50625d8c40945f5bc698a564af23355d74ebbfd1ff4b06b399c724d64a0a143510619e960b46cebc023086df332943450161994b
SHA512
52f08df4d50e768e4f10f230fc1877ccb621eb77d179f0978dadc64aad8f9f791835eff9679e11bc0a729ac65eca131680738610cb3c3f0ebc2a8a02819e9a51
DIST Django-3.2.17.tar.gz 9830188 BLAKE2B
93fcda6a7bcaad907bbfb7c4109643637ca4adb41c57a7e71d5dbe1d2c5b3c8b0bfae82df0d6c9045e113cf3d4fc292c55f3968b0300895724daad20d3c03b88
SHA512
8d6d754e81d0ea4a66b0589d70794014614a5dfd44203fd954be94c4241912844942ef82e8234dce2f6318dde362f2eeaee3d6b54a08cc85191f9ab61b5f78f9
+DIST Django-3.2.18.checksum.txt 2563 BLAKE2B
8deb25cdc9f3a859b68925b7c8615bf3bf955f0c5db7558818fc9177c2a5d5f588b848bb15094d5f2d1f9a92693204ddc753ef25411d328e8c7f755f93184b54
SHA512
b5fb24a525c10bbb1f82074b9637e4ddd68ec8bd80c3676f326f4be41a81643cb539c13123447895f6a3639d8938f70f009de31752eb5753ca1dc3dd162d9f92
+DIST Django-3.2.18.tar.gz 9848949 BLAKE2B
cf42d306d506addb43f725d5896be7bba41e37633fab0173d9e0bc76894b7c5a26fa945edb85e33f7b356d1d36b3ea9e7c85b5ec6efda5541639bc425230e8ff
SHA512
dbcf8daa4edf3666bfcb366b09e1c3de12a4176770ab2e6cd22b459ff77aa4cdbd72c445f53e7b23a907f663dc37b07c15d5d0d67e63fdec98eb4832dcc57d6d
DIST Django-4.0.10.checksum.txt 2563 BLAKE2B
1ec93751204e80d75f5f4f15086cfd9aabe65e392359f82edb234f2b86802bd1078e00575379c1956dfca8e6c60ddc6209079ae7e99450aa000b22c3312a89f4
SHA512
67b335f184ce02395efba3a4bec7d8087735ef8816eda70867faf9c02242c11c95f30fc36db6abd30996098dd567ef53f6dd467567c5405f34cb2bff7cd2a23c
DIST Django-4.0.10.tar.gz 10430363 BLAKE2B
d36aefd5d00023e5c4e34dda2b283e9a82d9e3b82576ce00cef7d9b75837ffdbf56327ad21ccefb02b79e8db93f12cf850541f4cb1d01b3dd28bdea0c73cb9d6
SHA512
04d1b207af21067c22c120486ff57ea602b3436adf1871f691735825afb30c3ed62f1cbc98d92fa70e9a818bcf50db70d949ab0c460f48f6027b75df9eba56c7
DIST Django-4.0.9.checksum.txt 2547 BLAKE2B
9e855836f392a88e8502408e60e4ea44609ab3abe60f4e329e3d1e63f885521439a82e03f57f6badfa532c61cc2f3323a118835ea31c4adf55d875e0eedf8c40
SHA512
ee507e7ec42665c3e315c33d18c1fec39c2f10efe809a46f1487cd1652c4ee3c73d351f2a99bc02da736ee1ceee20bae22f2653bef69f40b4cd0b7d76fbb06c8
diff --git a/dev-python/django/django-3.2.18.ebuild
b/dev-python/django/django-3.2.18.ebuild
new file mode 100644
index 000000000000..4790fd42730a
--- /dev/null
+++ b/dev-python/django/django-3.2.18.ebuild
@@ -0,0 +1,109 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..10} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig
+
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="
+ https://www.djangoproject.com/
+ https://github.com/django/django/
+ https://pypi.org/project/Django/
+"
+SRC_URI="
+ https://media.djangoproject.com/releases/$(ver_cut 1-2)/${P^}.tar.gz
+ verify-sig? ( https://media.djangoproject.com/pgp/${P^}.checksum.txt )
+"
+S="${WORKDIR}/${P^}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ >=dev-python/asgiref-3.3.4[${PYTHON_USEDEP}]
+ dev-python/pytz[${PYTHON_USEDEP}]
+ >=dev-python/sqlparse-0.2.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ $(python_gen_impl_dep sqlite)
+ ${RDEPEND}
+ dev-python/docutils[${PYTHON_USEDEP}]
+ dev-python/jinja[${PYTHON_USEDEP}]
+ dev-python/numpy[${PYTHON_USEDEP}]
+ dev-python/pillow[webp,${PYTHON_USEDEP}]
+ dev-python/pyyaml[${PYTHON_USEDEP}]
+ dev-python/selenium[${PYTHON_USEDEP}]
+ dev-python/tblib[${PYTHON_USEDEP}]
+ sys-devel/gettext
+ !!<dev-python/ipython-7.21.0-r1
+ !!=dev-python/ipython-7.22.0-r0
+ )
+ verify-sig? ( >=sec-keys/openpgp-keys-django-20201201 )
+"
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-3.1-bashcomp.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+ if use verify-sig; then
+ cd "${DISTDIR}" || die
+ verify-sig_verify_signed_checksums \
+ "${P^}.checksum.txt" sha256 "${P^}.tar.gz"
+ cd "${WORKDIR}" || die
+ fi
+
+ default
+}
+
+python_prepare_all() {
+ # Fails because of warnings
+ sed -i 's/test_dumpdata_proxy_with_concrete/_&/'
tests/fixtures/tests.py || die
+ # TODO: this suddenly started failing
+ sed -i -e 's:test_custom_fields:_&:' tests/inspectdb/tests.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_test() {
+ # Tests have non-standard assumptions about PYTHONPATH,
+ # and don't work with ${BUILD_DIR}/lib.
+ PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2
||
+ die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+ newbashcomp extras/django_bash_completion ${PN}-admin
+ bashcomp_alias ${PN}-admin django-admin.py
+
+ distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+ optfeature_header "Additional Backend support can be enabled via:"
+ optfeature "MySQL backend support" dev-python/mysqlclient
+ optfeature "PostgreSQL backend support" dev-python/psycopg:2
+ optfeature_header
+ optfeature "GEO Django" "sci-libs/gdal[geos]"
+ optfeature "Memcached support" dev-python/pylibmc
dev-python/python-memcached
+ optfeature "ImageField Support" dev-python/pillow
+ optfeature "Password encryption" dev-python/bcrypt
+ optfeature "High-level abstractions for Django forms"
dev-python/django-formtools
+}
