commit: f3ae0804dfee895e5a94cf1c20c7ad2acbd30cd3
Author: Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Wed Jan 18 23:25:20 2023 +0000
Commit: Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Thu Jan 19 01:15:01 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f3ae0804
dev-python/pyopengl: enable py3.11
Needs to be in ~arch because of pygame.
Signed-off-by: Sam James <sam <AT> gentoo.org>
dev-python/pyopengl/pyopengl-3.1.6-r1.ebuild | 53 ++++++++++++++++++++++++++++
1 file changed, 53 insertions(+)
diff --git a/dev-python/pyopengl/pyopengl-3.1.6-r1.ebuild
b/dev-python/pyopengl/pyopengl-3.1.6-r1.ebuild
new file mode 100644
index 000000000000..1c19aea56637
--- /dev/null
+++ b/dev-python/pyopengl/pyopengl-3.1.6-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_REQ_USE="tk?"
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1 virtualx
+
+MY_PN="PyOpenGL"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Python OpenGL bindings"
+HOMEPAGE="http://pyopengl.sourceforge.net/ https://pypi.org/project/PyOpenGL/";
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv
~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="tk"
+
+RDEPEND="
+ media-libs/freeglut
+ virtual/opengl
+ x11-libs/libXi
+ x11-libs/libXmu
+ tk? ( dev-tcltk/togl )
+"
+DEPEND="
+ ${RDEPEND}
+"
+
+# The tests need an X server with the GLX extension. Software rendering
+# under Xvfb works but only with llvmpipe, not softpipe or swr.
+BDEPEND="
+ test? (
+ dev-python/numpy[${PYTHON_USEDEP}]
+ dev-python/pygame[${PYTHON_USEDEP},opengl,X]
+ !prefix? (
+ media-libs/mesa[llvm]
+ x11-base/xorg-server[-minimal,xorg]
+ )
+ )
+"
+
+distutils_enable_tests pytest
+
+src_test() {
+ virtx distutils-r1_src_test
+}
