commit: 79ce09ea0211f531ddaea315f98e91f1e52d8f9a
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Jan 2 14:04:54 2023 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Jan 2 14:54:10 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=79ce09ea
dev-python/httpx: Bump to 0.23.2
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/httpx/Manifest | 1 +
dev-python/httpx/httpx-0.23.2.ebuild | 87 ++++++++++++++++++++++++++++++++++++
2 files changed, 88 insertions(+)
diff --git a/dev-python/httpx/Manifest b/dev-python/httpx/Manifest
index faf9becb250c..3cf6f61a1bba 100644
--- a/dev-python/httpx/Manifest
+++ b/dev-python/httpx/Manifest
@@ -1 +1,2 @@
DIST httpx-0.23.1.gh.tar.gz 2161798 BLAKE2B
ee01771377bbfebbc4a9346280c8d59508c78295e61b6f9d60a07099e44dfb0fc208d37b68f511bbbacb48438cf6daa73ef82d7a7ae75470409c8346ddad0ad5
SHA512
3fe280b6d3cb1a12bdd502e7bd432588375f9cebfcd9e071acb6e851866a56d84a715428599a297f5df43d73997b2a0c02ba1a12b3e32d292b2051161a350751
+DIST httpx-0.23.2.gh.tar.gz 2163739 BLAKE2B
fe89a162749e8710f6392ce3a2eb887a4ee0053270ad4ce20cb74d6fb4e70a14c800755ea2b32166f11e3dcb74a3c7d50a3e3a0644fa489a89f9f65050b826a4
SHA512
49b0b8cd3ba3f4c18fcfaab5e9ac52bfacb80241aa2b8452542a274a4b203ef6b35d936ad7f9a0b1e0d9857b1394a4e388572676cd288c8fb20f78a6df3ada4c
diff --git a/dev-python/httpx/httpx-0.23.2.ebuild
b/dev-python/httpx/httpx-0.23.2.ebuild
new file mode 100644
index 000000000000..090ec1fbe2b8
--- /dev/null
+++ b/dev-python/httpx/httpx-0.23.2.ebuild
@@ -0,0 +1,87 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 python3_{8..11} )
+
+inherit distutils-r1 optfeature # docs
+
+DESCRIPTION="Fully-featured HTTP client which provides sync and async APIs"
+HOMEPAGE="
+ https://www.python-httpx.org/
+ https://github.com/encode/httpx/
+ https://pypi.org/project/httpx/
+"
+SRC_URI="
+ https://github.com/encode/httpx/archive/${PV}.tar.gz
+ -> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390
~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+ dev-python/certifi[${PYTHON_USEDEP}]
+ <dev-python/httpcore-0.17[${PYTHON_USEDEP}]
+ >=dev-python/httpcore-0.15[${PYTHON_USEDEP}]
+ >=dev-python/rfc3986-1.3[${PYTHON_USEDEP}]
+ dev-python/sniffio[${PYTHON_USEDEP}]
+ cli? (
+ =dev-python/click-8*[${PYTHON_USEDEP}]
+ =dev-python/pygments-2*[${PYTHON_USEDEP}]
+ <dev-python/rich-13[${PYTHON_USEDEP}]
+ )
+"
+BDEPEND="
+ dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
+ test? (
+ dev-python/brotlicffi[${PYTHON_USEDEP}]
+ dev-python/cryptography[${PYTHON_USEDEP}]
+ dev-python/h2[${PYTHON_USEDEP}]
+ dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+ dev-python/pytest-trio[${PYTHON_USEDEP}]
+ dev-python/socksio[${PYTHON_USEDEP}]
+ dev-python/trio[${PYTHON_USEDEP}]
+ dev-python/trustme[${PYTHON_USEDEP}]
+ dev-python/typing-extensions[${PYTHON_USEDEP}]
+ dev-python/uvicorn[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+ if ! use cli; then
+ sed -i -e '/^httpx =/d' pyproject.toml || die
+ fi
+ sed -i -e '/rfc3986/s:,<2::' pyproject.toml || die
+ distutils-r1_src_prepare
+}
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # Internet
+ tests/client/test_proxies.py::test_async_proxy_close
+ tests/client/test_proxies.py::test_sync_proxy_close
+ )
+ local EPYTEST_IGNORE=(
+ # TODO: package multipart
+ tests/test_multipart.py
+ )
+
+ use cli || EPYTEST_IGNORE+=(
+ tests/test_main.py
+ )
+
+ epytest
+}
+
+pkg_postinst() {
+ optfeature "HTTP/2 support" dev-python/h2
+ optfeature "SOCKS proxy support" dev-python/socksio
+ optfeature "Decoding for brotli compressed responses"
dev-python/brotlicffi
+}
