[gentoo-commits] repo/gentoo:master commit in: dev-python/cfn-lint/

[Michał Górny]

commit:     454e82a3c1357ea4602fd0bed03e2b008b783af1
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Dec 21 05:52:35 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Dec 21 06:45:52 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=454e82a3

dev-python/cfn-lint: Disable Python < 3.10

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/cfn-lint/cfn-lint-0.72.5-r1.ebuild | 54 +++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

diff --git a/dev-python/cfn-lint/cfn-lint-0.72.5-r1.ebuild 
b/dev-python/cfn-lint/cfn-lint-0.72.5-r1.ebuild
new file mode 100644
index 000000000000..917b8b87c0f1
--- /dev/null
+++ b/dev-python/cfn-lint/cfn-lint-0.72.5-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="CloudFormation Linter"
+HOMEPAGE="
+       https://github.com/aws-cloudformation/cfn-lint/
+       https://pypi.org/project/cfn-lint/
+"
+SRC_URI="
+       https://github.com/aws-cloudformation/cfn-lint/archive/v${PV}.tar.gz
+               -> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+       >=dev-python/aws-sam-translator-1.55.0[${PYTHON_USEDEP}]
+       dev-python/jsonpatch[${PYTHON_USEDEP}]
+       >=dev-python/jschema_to_python-1.2.3[${PYTHON_USEDEP}]
+       >=dev-python/jsonschema-3.0[${PYTHON_USEDEP}]
+       dev-python/junit-xml[${PYTHON_USEDEP}]
+       dev-python/networkx[${PYTHON_USEDEP}]
+       >dev-python/pyyaml-5.4[${PYTHON_USEDEP}]
+       >=dev-python/requests-2.15.0[${PYTHON_USEDEP}]
+       >=dev-python/sarif_om-1.0.4[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+       # TODO
+       test/unit/module/test_template.py::TestTemplate::test_build_graph
+       # requires git repo
+       
test/unit/module/maintenance/test_update_documentation.py::TestUpdateDocumentation::test_update_docs
+       # Internet
+       
test/unit/module/formatters/test_formatters.py::TestFormatters::test_sarif_formatter
+       
test/unit/module/maintenance/test_update_resource_specs.py::TestUpdateResourceSpecs::test_update_resource_specs_python_2
+       
test/unit/module/maintenance/test_update_resource_specs.py::TestUpdateResourceSpecs::test_update_resource_specs_python_3
+)
+
+src_prepare() {
+       # unpin the deps
+       sed -e 's:~=[0-9.]*::' -i setup.py || die
+       distutils-r1_src_prepare
+}