commit: 1f8aed72990485211e0c3414d145eb3e05707c98
Author: Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Fri Nov 11 03:49:01 2022 +0000
Commit: Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Nov 11 03:49:01 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1f8aed72
media-libs/sdl-sound: add 1.0.3_p20220525
Upstream aren't making releases anymore (since a long time ago!) for the 1.0.x
branch but are kindly doing backports, so let's make a snapshot.
Signed-off-by: Sam James <sam <AT> gentoo.org>
media-libs/sdl-sound/Manifest | 1 +
.../sdl-sound/sdl-sound-1.0.3_p20220525.ebuild | 72 ++++++++++++++++++++++
2 files changed, 73 insertions(+)
diff --git a/media-libs/sdl-sound/Manifest b/media-libs/sdl-sound/Manifest
index a8a30855b2b2..3e2fb92fe0ca 100644
--- a/media-libs/sdl-sound/Manifest
+++ b/media-libs/sdl-sound/Manifest
@@ -1 +1,2 @@
DIST SDL_sound-1.0.3.tar.gz 1127100 BLAKE2B
6fff5ea22ae82f9692a51910d5415288d5a1ebc1c463b2c741f9ee9fabeabb385de12f781d4f40aaf0628598824758376c51b442f434d77d96d0376379908ff6
SHA512
3e60671777d804e6104d7d441f4a29866492c9412040eea3fd2283c0914a0a1ebc550260631c2bf500e7d982e05a6f9feeda81e9eeef8257303750c1be582824
+DIST sdl-sound-1.0.3_p20220525.tar.gz 1044804 BLAKE2B
f82f7649bd411290d12ec6b6a4879e0f6a5a155b764b307b087ce2cad5b81dc0ac6fed674c666f470201e5aab5182d9e0c4b6f0d9fc94e9d4bc61d7dacd61cdd
SHA512
0f4923e8234334c65697c1d9453a66b05aafd859b1586d9ed26005d93f4a27175b06a77616f09e450b586d0f21c7a1d76761de0fe5f1b144d444e6a2379055b5
diff --git a/media-libs/sdl-sound/sdl-sound-1.0.3_p20220525.ebuild
b/media-libs/sdl-sound/sdl-sound-1.0.3_p20220525.ebuild
new file mode 100644
index 000000000000..59d4ac776545
--- /dev/null
+++ b/media-libs/sdl-sound/sdl-sound-1.0.3_p20220525.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Check stable-1.0 branch for possible backports/new snapshots
+
+inherit multilib-minimal
+
+SDL_SOUND_COMMIT="2076a4f555f95ed28dead5e28ee8e57cc74e425f"
+
+MY_PN=${PN/sdl-/SDL_}
+DESCRIPTION="Simple Direct Media Layer Mixer Library"
+HOMEPAGE="https://github.com/icculus/SDL_sound";
+SRC_URI="https://github.com/icculus/SDL_sound/archive/${SDL_SOUND_COMMIT}.tar.gz
-> ${P}.tar.gz"
+S="${WORKDIR}"/${MY_PN}-${SDL_SOUND_COMMIT}
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86 ~x64-macos"
+IUSE="flac mikmod modplug mp3 speex static-libs vorbis"
+
+RDEPEND="
+ >=media-libs/libsdl-1.2.15-r4[${MULTILIB_USEDEP}]
+ flac? ( >=media-libs/flac-1.2.1-r5:=[${MULTILIB_USEDEP}] )
+ mikmod? ( >=media-libs/libmikmod-3.2.0[${MULTILIB_USEDEP}] )
+ modplug? ( >=media-libs/libmodplug-0.8.8.4-r1[${MULTILIB_USEDEP}] )
+ mp3? ( media-sound/mpg123[${MULTILIB_USEDEP}] )
+ speex? (
+ >=media-libs/speex-1.2_rc1-r1[${MULTILIB_USEDEP}]
+ >=media-libs/libogg-1.3.0[${MULTILIB_USEDEP}]
+ )
+ vorbis? ( >=media-libs/libvorbis-1.3.3-r1[${MULTILIB_USEDEP}] )
+"
+
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+multilib_src_configure() {
+ local myeconfargs=(
+ # TODO: make this optional or switch unconditionally?
+ --disable-sdl2
+ --enable-aiff
+ --enable-au
+ --enable-midi
+ --enable-raw
+ --enable-shn
+ --enable-voc
+ --enable-wav
+ $(use_enable flac)
+ $(use_enable mikmod)
+ $(use_enable modplug)
+ $(use_enable mp3 mpg123)
+ $(use_enable speex)
+ $(use_enable static-libs static)
+ $(use_enable vorbis ogg)
+ )
+
+ ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install() {
+ emake DESTDIR="${D}" install
+}
+
+multilib_src_install_all() {
+ einstalldocs
+
+ if ! use static-libs ; then
+ find "${ED}" -name '*.la' -delete || die
+ fi
+}
