[gentoo-commits] proj/kde:master commit in: kde-frameworks/kwallet/

[Andreas Sturmlechner]

commit:     ff7686f57253f6110d7b8ab7194cf81f310822b5
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sun Oct  2 21:53:20 2022 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sun Oct  2 22:17:12 2022 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=ff7686f5

kde-frameworks/kwallet: 5.99.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-frameworks/kwallet/kwallet-5.99.0.ebuild | 52 ++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

diff --git a/kde-frameworks/kwallet/kwallet-5.99.0.ebuild 
b/kde-frameworks/kwallet/kwallet-5.99.0.ebuild
new file mode 100644
index 0000000000..ccd08f53d1
--- /dev/null
+++ b/kde-frameworks/kwallet/kwallet-5.99.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.15.5
+inherit ecm frameworks.kde.org optfeature
+
+DESCRIPTION="Framework providing desktop-wide storage for passwords"
+
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="gpg +man"
+
+DEPEND="
+       >=app-crypt/qca-2.3.1
+       dev-libs/libgcrypt:0=
+       >=dev-qt/qtdbus-${QTMIN}:5
+       >=dev-qt/qtgui-${QTMIN}:5
+       >=dev-qt/qtwidgets-${QTMIN}:5
+       =kde-frameworks/kconfig-${PVCUT}*:5
+       =kde-frameworks/kconfigwidgets-${PVCUT}*:5
+       =kde-frameworks/kcoreaddons-${PVCUT}*:5
+       =kde-frameworks/kdbusaddons-${PVCUT}*:5
+       =kde-frameworks/ki18n-${PVCUT}*:5
+       =kde-frameworks/knotifications-${PVCUT}*:5
+       =kde-frameworks/kservice-${PVCUT}*:5
+       =kde-frameworks/kwidgetsaddons-${PVCUT}*:5
+       =kde-frameworks/kwindowsystem-${PVCUT}*:5
+       gpg? ( >=app-crypt/gpgme-1.7.1:=[cxx,qt5] )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="man? ( >=kde-frameworks/kdoctools-${PVCUT}:5 )"
+
+src_configure() {
+       local mycmakeargs=(
+               $(cmake_use_find_package gpg Gpgmepp)
+               $(cmake_use_find_package man KF5DocTools)
+       )
+
+       ecm_src_configure
+}
+
+pkg_postinst() {
+       if [[ -z "${REPLACING_VERSIONS}" ]]; then
+               optfeature "Auto-unlocking after account login" 
kde-plasma/kwallet-pam
+               optfeature "KWallet management" kde-apps/kwalletmanager:5
+               elog "For more information, read 
https://wiki.gentoo.org/wiki/KDE#KWallet";
+       fi
+       ecm_pkg_postinst
+}