commit: 0b7e34b88a6867625fd6bbaf0238166af0251468
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Jul 25 05:53:50 2022 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Jul 25 07:12:20 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0b7e34b8
dev-python/fakeredis: Bump to 1.8.2
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/fakeredis/Manifest | 1 +
dev-python/fakeredis/fakeredis-1.8.2.ebuild | 88 +++++++++++++++++++++++++++++
2 files changed, 89 insertions(+)
diff --git a/dev-python/fakeredis/Manifest b/dev-python/fakeredis/Manifest
index 33738459bc11..71f6b9c42e8c 100644
--- a/dev-python/fakeredis/Manifest
+++ b/dev-python/fakeredis/Manifest
@@ -1 +1,2 @@
DIST fakeredis-py-1.8.1.gh.tar.gz 101586 BLAKE2B
a1b123dd482b9b59f401a855ba95a08f2e744bff5ae4a4f0c12cde8b2a05971043ccb16e92d0adbfeedd3e071fab50f1328ed265c6ac19ecf6932d09bcacd549
SHA512
19e1636895206fa550844a776ba4835c3acbe2eac8fb774716e91d20e0f283b121f42ee11d876e20d798a6df0dcfcc29114c76c839c4946436102b8f83ed3d01
+DIST fakeredis-py-1.8.2.gh.tar.gz 96238 BLAKE2B
17fd75d2ca6e929fbbdab87e9a6450d72006a3dc72a2d81a3f381c1918f2ca12f273468bf8015e80df78e9df393d2f7002b13e12989d108f93beb3287472c0c6
SHA512
6a86c0fa41920f4446b66d4d152850227a23f5a031a80d0d9109117de7252965821dc8d9f022b9fd703f8ed66fad207f6542bd6ee524a54f2053bbcd2ed9965e
diff --git a/dev-python/fakeredis/fakeredis-1.8.2.ebuild
b/dev-python/fakeredis/fakeredis-1.8.2.ebuild
new file mode 100644
index 000000000000..c6cea81c8567
--- /dev/null
+++ b/dev-python/fakeredis/fakeredis-1.8.2.ebuild
@@ -0,0 +1,88 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( pypy3 python3_{8..11} )
+
+inherit distutils-r1
+
+MY_P=fakeredis-py-${PV}
+DESCRIPTION="Fake implementation of redis API for testing purposes"
+HOMEPAGE="
+ https://github.com/dsoftwareinc/fakeredis-py/
+ https://pypi.org/project/fakeredis/
+"
+SRC_URI="
+ https://github.com/dsoftwareinc/fakeredis-py/archive/v${PV}.tar.gz
+ -> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+ >=dev-python/redis-py-4.2[${PYTHON_USEDEP}]
+ >=dev-python/six-1.16.0[${PYTHON_USEDEP}]
+ >=dev-python/sortedcontainers-2.4.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ dev-db/redis
+ dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+ dev-python/pytest-mock[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+ # unpin redis
+ sed -i -e '/redis/s:<[0-9.]*:*:' pyproject.toml || die
+ distutils-r1_src_prepare
+}
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # also lupa
+ test/test_aioredis2.py::test_failed_script_error
+ # TODO
+ "test/test_fakeredis.py::test_set_get_nx[StrictRedis]"
+ "test/test_fakeredis.py::test_lpop_count[StrictRedis]"
+ "test/test_fakeredis.py::test_rpop_count[StrictRedis]"
+ "test/test_fakeredis.py::test_zadd_minus_zero[StrictRedis]"
+ )
+ local EPYTEST_IGNORE=(
+ # these tests fail a lot...
+ test/test_hypothesis.py
+ )
+ local args=(
+ # tests requiring lupa (lua support)
+ -k 'not test_eval and not test_lua and not test_script'
+ )
+ epytest "${args[@]}"
+}
+
+src_test() {
+ local redis_pid="${T}"/redis.pid
+ local redis_port=6379
+ local redis_test_config="
+ daemonize yes
+ pidfile ${redis_pid}
+ port ${redis_port}
+ bind 127.0.0.1
+ "
+
+ einfo "Spawning Redis"
+ einfo "NOTE: Port ${redis_port} must be free"
+ "${EPREFIX}"/usr/sbin/redis-server - <<< "${redis_test_config}" || die
+
+ # Run the tests
+ distutils-r1_src_test
+
+ # Clean up afterwards
+ kill "$(<"${redis_pid}")" || die
+}
