commit: 035d0d76709af717f39b0491ce5f9672612f9a27
Author: Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Tue Jul 19 01:07:06 2022 +0000
Commit: Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue Jul 19 01:07:21 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=035d0d76
dev-python/PySDL2: add 0.9.12
Signed-off-by: Sam James <sam <AT> gentoo.org>
dev-python/PySDL2/Manifest | 1 +
dev-python/PySDL2/PySDL2-0.9.12.ebuild | 66 ++++++++++++++++++++++++++++++++++
2 files changed, 67 insertions(+)
diff --git a/dev-python/PySDL2/Manifest b/dev-python/PySDL2/Manifest
index d604a9de88f7..dddcf0dee0dd 100644
--- a/dev-python/PySDL2/Manifest
+++ b/dev-python/PySDL2/Manifest
@@ -1 +1,2 @@
DIST PySDL2-0.9.11.tar.gz 736026 BLAKE2B
ebf5a98958681cc61155aeffdb67ca9d1aeef8143ca876b63772ce95b7bf23cc5708a01cfa83d3128d4fe20c2b714bf2f1e7dc64454c7d063590c55cfc236f24
SHA512
4e3383ef64f4f164d60a69a5a2c6ea153269b45661c9bba988d4c44a5cce7195cec0d29384d1855e9c9d507af2608bc808b9885449aea61c5ee51fc2d4f4af6f
+DIST PySDL2-0.9.12.tar.gz 741668 BLAKE2B
82f1f63f0b637981a8e98966f34d721495764630f9f0f95e0f6fd4c428d8adf0a31c540f0dcc36da24f073b3485cdb4987e0deb79d7df484ed05bad93c17a2ed
SHA512
e4dd5b11a8e1082751bc45b9a18c1c3f7ff977091a35c35965f93b1946f634ea096ba94088404153c712c42cf3b4a8876c9ae05496def51b296be55c31b3b59b
diff --git a/dev-python/PySDL2/PySDL2-0.9.12.ebuild
b/dev-python/PySDL2/PySDL2-0.9.12.ebuild
new file mode 100644
index 000000000000..e6dabf07cdbd
--- /dev/null
+++ b/dev-python/PySDL2/PySDL2-0.9.12.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python (ctypes) bindings for SDL2 libraries"
+HOMEPAGE="
+ https://github.com/py-sdl/py-sdl2/
+ https://pypi.org/project/PySDL2/
+"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
+
+LICENSE="|| ( public-domain CC0-1.0 ZLIB )"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+# Optional deps:
+# - dev-python/numpy,
+# - dev-python/pillow,
+# - media-libs/sdl2-* (loaded dynamically via ctypes).
+#
+# If a reverse dependency needs the specific module, it should
+# explicitly depend on the optional module in question. You also
+# probably need to explicitly require some media-libs/libsdl2 flags.
+RDEPEND="media-libs/libsdl2"
+
+# Require all of SDL2 libraries and at least the most common subsystems
+# for better test coverage.
+DEPEND="
+ test? (
+ dev-python/numpy[${PYTHON_USEDEP}]
+ dev-python/pillow[${PYTHON_USEDEP}]
+ media-libs/libsdl2[joystick,sound,video]
+ media-libs/sdl2-gfx
+ media-libs/sdl2-image[gif,jpeg,png,tiff,webp]
+ || (
+ media-libs/sdl2-mixer[flac]
+ media-libs/sdl2-mixer[midi]
+ media-libs/sdl2-mixer[mod]
+ media-libs/sdl2-mixer[mp3]
+ media-libs/sdl2-mixer[opus]
+ )
+ media-libs/sdl2-ttf
+ )"
+
+EPYTEST_DESELECT=(
+ # Both tests fail and seem machine-dependent?
+ sdl2/test/sdlttf_test.py::test_TTF_SetFontSize
+ sdl2/test/sdlttf_test.py::test_TTF_SetFontSizeDPI
+)
+
+distutils_enable_tests pytest
+
+src_test() {
+ # from .travis.yml
+ local -x SDL_VIDEODRIVER=dummy
+ local -x SDL_AUDIODRIVER=dummy
+ local -x SDL_RENDER_DRIVER=software
+
+ distutils-r1_src_test
+}
